Ayuda con galeria snippet, no muestra en otro swf externo

Citar

Escrito el 13 Feb 2009 09:59 pm

Hola tengo este problema y espero me ayuden tengo el archivo snippet.swf como asi lo llamé quiero llamarlo como un swf externo, hacia un principal.swf;
Desde este principal.swf lo llama a snippet.swf, con
_root.mc_cont_body.loadMovie("snnipet.swf");
pero no carga la galeria, pude darme cuenta que al snnipet.swf si lo jala por que a este le puse unas lineas com si fuesen marcos, y por ende en principal.swf; si se muestra los marcos , pero no la galeria.

Espero me ayuden gracias.

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 13 Feb 2009 10:16 pm

Casi seguro es un problema de rutas. Ten en cuenta que si cargas la galeria desde otro SWF, las rutas hacia las imñagenes deben ser desde el padre.

Por esedeerre

132 de clabLevel

Envíale un mensaje privado Web

MadRid

@esedeerre

Citar

Escrito el 13 Feb 2009 10:28 pm

Claro eso me fije, pero no creo que sea eso, por que todos los archivos estan dentro de una misma carpeta.

gracias de todos modos

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 14 Feb 2009 02:03 am

mmm, esta muy raro, efectivamente estaba diseñado para que pudiera se jalado desde otras swf, intenta jalarlo mejor de este modo:

Código ActionScript :

var cargador:MovieClipLoader = new MovieClipLoader();
cargador.loadClip( "snippet.swf", _root.mc_cont_body );

Nota: no se si el nombre correcto sea "snippet.swf" o "snnipet.swf"

Espero funcione, Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 14 Feb 2009 04:17 am

Gracias por tu respuesta, ya se cual es el problema :
1.- el archivo index.swf mide 880x600 y el snippet.swf mide 390x360, en realidad si esta cargando y funcionado la galeria, el problema es la ubicacion en la que aparece, se suponde que el mc_body_contenedor se le coloca en una coordenada a gusto del que diseña y por ende ahi debe de cargar el snippet.swf, pero este aparee de la mitad hacia abajoo quisas mas y de igual manera a de la mitad hacia un costado en index.swf, es por eso que no se visualiza en index.swf (es como si estuviese volando el snippet.swf)

espero me ayuden por favor.

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 14 Feb 2009 01:11 pm

ha, bueno tu problema mayor es por que se usa dentro del snipet Stage, para ubicar los componentes, cambia stage.width por 390 y Stage.height por 360 que son las medidas estandar de tu swf snippet, con estege se basa en las medidas del nuevo Stage donde se carga. Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 17 Feb 2009 06:28 pm

gracias brother, ese era el problema, ahora funciona bien.
Thanks !!!

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 19 Feb 2009 04:51 pm

Hola tengo una pequeña duda y no la pude resolver, no se si se pueda mostrar la primera imagen grande de los thumbs automatico.
espero me ayuden

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 19 Feb 2009 06:58 pm

La funcion OnLoad del XML se cambia por esta, en donde se simula que se presiona la primer imagen.

Código ActionScript :

lista_xml.onLoad = function( ok:Boolean ):Void 
{   
   if( ok )//Si se cargo correctamente   
   {   
      crearImagenes();
      galeria.miniaturas.mc_0.bound_mc.onRelease();
   }   
   else trace("No se pudo cargar el XML");   
};

Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 19 Feb 2009 09:04 pm

Gracias por tu ayuda, si funciona

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 21 Feb 2009 07:31 pm

Hola aqui nuevamente teniendo un problema y no consigo solucionarlo:
En vez de la barra horizontal que se utiliza para mover los thumbs, se podria hacer que desaparesca la barra horizontal y solo al pasar por encima de los thumbs se pueda hacer que se mueva;y oviamente al darle click a cada uno muestre la imagen grande.
gracias por la respuesta de antemano

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 22 Feb 2009 09:26 am

pues primero tendrias que borrar la parte de la scroll.

Aqui un codigo que te puede servir:

Código ActionScript :

this.createEmptyMovieClip("pic_mc", this.getNextHighestDepth()); 
pic_mc.beginFill(0xFF0000); 
pic_mc.moveTo(0, 0); 
pic_mc.lineTo(640, 0); 
pic_mc.lineTo(640, 480); 
pic_mc.lineTo(0, 480); 
pic_mc.lineTo(0, 0); 
pic_mc.endFill(); 
 
this.createEmptyMovieClip("mask_mc", this.getNextHighestDepth()); 
mask_mc.beginFill(0xFF33DD, 50); 
mask_mc.moveTo(0, 0); 
mask_mc.lineTo(320, 0); 
mask_mc.lineTo(320, 240); 
mask_mc.lineTo(0, 240); 
mask_mc.lineTo(0, 0); 
mask_mc.endFill(); 
 
mask_mc._x = Stage.width/2 - mask_mc._width/2; 
mask_mc._y = Stage.height/2 - mask_mc._height/2; 
 
function Mover(x,y, aceleracion) 
{  
   pic_mc.onEnterFrame = function() 
   {
   this._x += (x-this._x)/aceleracion; 
   this._y += (y-this._y)/aceleracion;  
    
      if (Math.abs(x-this._x)<0.5 && Math.abs(x-this._y)<0.5 ) {  
      this._x = x; 
      this._y = y;
      delete this.onEnterFrame;  
      }  
   };  
} 
 
var mouseListener:Object = new Object(); 
mouseListener.onMouseMove = function() 
{ 
   if (mask_mc.hitTest(_xmouse, _ymouse, true)) 
   {  
      var point:Object = {x:mask_mc._xmouse, y:mask_mc._ymouse}; 
    mask_mc.globalToLocal(point);    
   Mover(-point.x, mask_mc._y, 5); 
   updateAfterEvent(); 
} 
}; 
 
Mouse.addListener(mouseListener);

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 23 Feb 2009 03:37 am

Bueno agradesco tu ayuda, probe con el codigo que me distes pero :cry:

no me sale... abuuuu
aqui esta el codigo que lo puse een el swf las dienciones de este es: 390x350
Ayudame Please

Código :

//--Definir variables inciales --// 
var lista_xml:XML = new XML();
lista_xml.ignoreWhite = true;
var cargador_mcl:MovieClipLoader = new MovieClipLoader();
cargador_mcl.addListener(this);

var slideColor:Number = 0xcccccc;//Color del slider 
var slideClip:String = "Slider_id";//id de la biblioteca del slider 
var img_w:Number = 70;//Ancho de las imagenes   
var img_h:Number = 50;//Alto de las imagenes   
var img_n:Number = 5;//Numero de imagenes que se mostraran   
var img_s:Number = 8;//Separacion entre las imagenes   
var gal_x:Number = Stage.width=0;//Posicion en X de la galeria   
var gal_y:Number = Stage.height=293;//Posicion en Y de la galeria    
var url_target:String = "_self";//Target donde se cargan las urls 
var lienzo_bln:Boolean = true;//Cargar el contenido en un Lienzo 
var lnz_x:Number = 0;//Posicion en X del Lienzo ///////////
var lnz_y:Number = -35;//Posicion en Y del Lienzo ///////////
var lnz_w:Number = Stage.width=390;//Ancho del Lienzo ///////////
var lnz_h:Number = Stage.height=350;// Alto del Lienzo ///////////

//-- Crear la galeria --//   
var galeria:MovieClip = this.createEmptyMovieClip("galeria", 120);
galeria.createEmptyMovieClip("miniaturas",0);
galeria.createEmptyMovieClip("mascara",1);
setArea(galeria.mascara,(img_w+img_s)*img_n,img_h);
galeria.miniaturas.setMask(galeria.mascara);
galeria._x = this.gal_x;
galeria._y = this.gal_y;

//-- Crear el lienzo --//  
var lienzo:MovieClip;
if (lienzo_bln) {
   //Creamos los clips 
   lienzo = this.createEmptyMovieClip("lienzo", 119);
   lienzo.createEmptyMovieClip("bound_mc",0);
   lienzo.createEmptyMovieClip("inner_mc",1);
   //Creamos un TextField donde se despliega el porcentaje cargado 
   lienzo.createTextField("texto_txt",2,lnz_w/2-50,lnz_h/2-11,100,22);
   //Le damos formato 
   var format:TextFormat = new TextFormat();
   format.align = "center";
   format.bold = true;
   format.font = "Verdana";
   format.color = 0xc6c6c6;
   format.size = 10;
   lienzo.texto_txt.setNewTextFormat(format);
   lienzo.texto_txt.selectable = false;
   //Dibujamos los limites 
   setArea(lienzo.bound_mc,lnz_w,lnz_h);
   //Posicionamos 
   lienzo._x = lnz_x;
   lienzo._y = lnz_y;
   //Funcion para cargar imagenes 
   this.cargarLienzo = function(url:String):Void  {
      this.cargador_mcl.loadClip(url,this.lienzo.inner_mc);
   };
}
//-- Crear ScrollBar --//    
//Creamos el slider desde la biblioteca 
var slider:MovieClip = galeria.attachMovie(slideClip, "slider", 2);
//Si no fue creado 
if (slider == undefined) {
   //Lo creamos 
   slider = galeria.createEmptyMovieClip("slider", 2);
   //Lo dibujamos 
   setArea(slider,this.img_w*2,8,slideColor,100);//Ancho y Alto 
}
//Variables    
slider.owner = this;
//Posicionamos 
slider._y = this.img_h+5;
//Declaramos eventos 
slider.onPress = function(Void):Void  {
   //Al presionar incia el arrastre 
   this.startDrag(false,0,this._y,this._parent.mascara._width-this._width-this.owner.img_s,this._y);
};
slider.onRelease = slider.onReleaseOutside=function (Void):Void {
   //Al soltar se detiene el arrastre 
   this.stopDrag();
};
slider.onEnterFrame = function(Void):Void  {
   //Calculos para recorrer las miniaturas respecto a la posicion de scrollBar 
   this._parent.miniaturas._x = this._x/(this._parent.mascara._width-this._width)*(this._parent.miniaturas._width-(this._parent.mascara._width-this._parent._parent.img_s))*-1;
};

//-- Carga XML --//   
lista_xml.onLoad = function(ok:Boolean):Void  {
   if (ok) {
      crearImagenes();
      galeria.miniaturas.mc_0.bound_mc.onRelease();
   } else {
      trace("No se pudo cargar el XML");
   }
};
lista_xml.load("lista.xml");

//-- Crear las imagenes --//   
function crearImagenes(Void):Void {
   //Variables auxiliares   
   var aux:MovieClip;
   var img_aux:String;
   var url_aux:String;
   for (var i:Number = 0, l:Number = lista_xml.firstChild.childNodes.length; i<l; i++) {
      //Creamos la miniatura 
      aux = this.crearImagen(i);
      //Parseo de XML 
      url_aux = lista_xml.firstChild.childNodes[i].attributes.url_xml;
      img_aux = lista_xml.firstChild.childNodes[i].attributes.nom_xml;
      //Si existe la url entonces 
      if (url_aux != undefined && url_aux != "") {
         aux.bound_mc.url = url_aux;
         //al presionar 
         aux.bound_mc.onRelease = function(Void):Void  {
            this._parent.presionado(this.url);
         };
      }
      //Cargamos la miniatura    
      cargador_mcl.loadClip(img_aux,aux.thumb_mc);
   }
}
function crearImagen(index:Number):MovieClip {
   //Creamamos los clips 
   var clip:MovieClip = this.galeria.miniaturas.createEmptyMovieClip("mc_"+index, index);
   clip.createEmptyMovieClip("bound_mc",1);
   clip.createEmptyMovieClip("thumb_mc",0);
   clip.owner = this;
   clip.selected = false;

   //Posicion 
   clip.index = i;
   clip._x = (this.img_w+this.img_s)*index;

   //Fondo transparente del boton     
   //setArea( clip.bound_mc, img_w, img_h ); 
   setArea( clip.bound_mc, img_w, img_h, 0x000000, 50 ); 

   //Funcion que colorea el clip bound_mc, si se esta seleccionado 
   clip.setSelected = function(aux:Boolean) {
      if (aux) {
         this.owner.setArea(this.bound_mc,this.bound_mc._width,this.bound_mc._height,this.owner.slideColor,20);
         //todos los demas los colocamos en false 
         for (var i in this._parent) {
            if (this._parent[i].selected) {
               this._parent[i].setSelected(false);
               break;
            }
         }
      } else {
         setArea(this.bound_mc,this.bound_mc._width,this.bound_mc._height);
      }
      this.selected = aux;
   };
   //Funcion invocada cuando se presiona el clip bound_mc 
   clip.presionado = function(url:String) {
      //Si se usa lienzo 
      if (this.owner.lienzo_bln) {
         //Nos colocamos seleccionados 
         this.setSelected(true);
         //Cargamos la imagen en el Lienzo 
         this.owner.cargarLienzo(url);
      } else {
         //Cargamos la url en el navegador 
         getURL(url, this.owner.url_target);
      }
   };
   return clip;
}
//-- Eventos del Cargador --// 
function onLoadInit(target:MovieClip):Void {//Clip accesible 
   //Centramos la imagen 
   target._x = (target._parent.bound_mc._width-target._width)/2;
   target._y = (target._parent.bound_mc._height-target._height)/2;
   //Efecto fadeIn( _alpha 0 -> 100 ) 
   target._alpha = 0;
   target.onEnterFrame = function(Void) {
      if ((this._alpha += 10)>=100) {
         delete this.onEnterFrame;
      }
   };
}
function onLoadComplete(target:MovieClip):Void {//Clip cargado 
   //Desaparece el cargador 
   lienzo.texto_txt.text = "";
}
function onLoadProgress(target:MovieClip, l:Number, t:Number):Void {//Clip cargandose 
   //Si se esta cargando el lienzo 
   if (target == lienzo.inner_mc) {
      //Desplegamos el porcentaje cargado 
      lienzo.texto_txt.text = "Cargando... "+Math.floor(l/t*100);
   }
}
//-- Utilerias --//  
function setArea(clip:MovieClip, w:Number, h:Number, color:Number, alpha:Number):Void {
   //Dibujamos un cuadrado 
   clip.clear();
   clip.beginFill(color ? color : 0,alpha ? alpha : 0);
   clip.moveTo(0,0);
   clip.lineTo(w,0);
   clip.lineTo(w,h);
   clip.lineTo(0,h);
   clip.endFill();
}

Gracias por tu ayuda.

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 23 Feb 2009 06:57 am

Y, ¿el codigo que te pase, donde lo aplicaste? o ¿donde te fallò?

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 23 Feb 2009 07:03 am

Claro el codido lo reemplace por too esto:

Código :

//-- Crear ScrollBar --//    
//Creamos el slider desde la biblioteca 
var slider:MovieClip = galeria.attachMovie(slideClip, "slider", 2);
//Si no fue creado 
if (slider == undefined) {
   //Lo creamos 
   slider = galeria.createEmptyMovieClip("slider", 2);
   //Lo dibujamos 
   setArea(slider,this.img_w*2,8,slideColor,100);//Ancho y Alto 
}
//Variables    
slider.owner = this;
//Posicionamos 
slider._y = this.img_h+5;
//Declaramos eventos 
slider.onPress = function(Void):Void  {
   //Al presionar incia el arrastre 
   this.startDrag(false,0,this._y,this._parent.mascara._width-this._width-this.owner.img_s,this._y);
};
slider.onRelease = slider.onReleaseOutside=function (Void):Void {
   //Al soltar se detiene el arrastre 
   this.stopDrag();
};
slider.onEnterFrame = function(Void):Void  {
   //Calculos para recorrer las miniaturas respecto a la posicion de scrollBar 
   this._parent.miniaturas._x = this._x/(this._parent.mascara._width-this._width)*(this._parent.miniaturas._width-(this._parent.mascara._width-this._parent._parent.img_s))*-1;
};

pero cuendo lo ejecuto muestra los thums pero no hay navegcion de derecha a izquierda,
aun costado aparece "pic.mc" y "mask.mc", pero en diferentes possiones caada uno, trate de alinearlos pero no pude; tal vez si serias tan amable de explicar mejor el codigo gracias.

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 23 Feb 2009 07:09 am

lo que te pase era un ejemplo, para que lo entendieras y aplicaras la funcionalidad al script, no era para copiar y pegar, como el snippet. No te mal-acostumbres, no es sano. intenta hacerlo, no es dificil.

Es cierto que la parte del slider se "borra", en el ejemplo que te puse, se crean dos clips, uno que funcionaria como el area donde funciona el movimiento de mouse(mask_mc) y otro que es el que se mueve(pic_mc), es obvio que no usaras esos nombres, deberas usar los que tenemos. El clip que se mueve es: galeria.miniaturas y el clip donde funciona el movimiento del mouse es: galeria.mascara. Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 23 Feb 2009 07:15 am

Ayaa ya te entendi, pero esta parte es la k me travo:

Código :

this.createEmptyMovieClip("pic_mc", this.getNextHighestDepth());  
pic_mc.beginFill(0xFF0000);  
pic_mc.moveTo(0, 0);  
pic_mc.lineTo(640, 0);  
pic_mc.lineTo(640, 480);  
pic_mc.lineTo(0, 480);  
pic_mc.lineTo(0, 0);  
pic_mc.endFill();  
  *********************
this.createEmptyMovieClip("mask_mc", this.getNextHighestDepth());  
mask_mc.beginFill(0xFF33DD, 50);  
mask_mc.moveTo(0, 0);  
mask_mc.lineTo(320, 0);  
mask_mc.lineTo(320, 240);  
mask_mc.lineTo(0, 240);  
mask_mc.lineTo(0, 0);  
mask_mc.endFill();

por que le pones varias lines a pic_mc y mask.mc.line, la primera color, las otras ubicacion y tamaño; pero las demas??

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 23 Feb 2009 07:19 am

miguel_fox escribió:

Ayaa ya te entendi, pero esta parte es la k me travo:

Código :

this.createEmptyMovieClip("pic_mc", this.getNextHighestDepth());  
pic_mc.beginFill(0xFF0000);  
pic_mc.moveTo(0, 0);  
pic_mc.lineTo(640, 0);  
pic_mc.lineTo(640, 480);  
pic_mc.lineTo(0, 480);  
pic_mc.lineTo(0, 0);  
pic_mc.endFill();  
  *********************
this.createEmptyMovieClip("mask_mc", this.getNextHighestDepth());  
mask_mc.beginFill(0xFF33DD, 50);  
mask_mc.moveTo(0, 0);  
mask_mc.lineTo(320, 0);  
mask_mc.lineTo(320, 240);  
mask_mc.lineTo(0, 240);  
mask_mc.lineTo(0, 0);  
mask_mc.endFill();

por que le pones varias lines a pic_mc y mask.mc.line, la primera color, las otras ubicacion y tamaño; pero las demas??

Ese ejemplo es resultado de otro post en el que participe, esa parte del codigo solo es para crear los "cuadrados", eso no le prestes atencion, lo verdaderamente importante son la funcion Mover y el listener del Mouse.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 23 Feb 2009 07:38 am

ok gracias lo voy a revisar.

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 23 Feb 2009 07:39 am

Me parece perfecto, si tienes resultados satisfactorios, los publicas y le podemos agregar eso al script. Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 23 Feb 2009 08:44 am

Pues ya lo logre, voy a publicar los resultados; asi que no era tan facil como pensaba, ademas se tenia que usar un poco de algebra, pero al final, resulto.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 23 Feb 2009 09:30 am

Version 1.8a.0.23.clab

Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 24 Feb 2009 06:45 am

Hola bueno otra vez con problemas:
probe la nueva galeria y funciona perfecto, el problema es cuando lo cargo desde un swf externo.

snippet.swf mide 390x350 y el gallery.swf de donde lo llamo es 860x425 alli esta el problema, ya que cuando lo llamo oviamente cambie el tamaño de los thumbs y el mumero que se muestraran; entonces al cargarlos los thumbs solo se mueven de derecha a izquierda y no viceversa, entonces al igual que el otro dia cambie en snippet.swf el tamaño del "stage" y nada, sigue igual.
pero si a gallery.swf le pongo el mismo tamaño de snippet.swf osea 390x350 ahi si funciona muy bien.
espero me ayudes.
pd: al realizar los cambios de stage y el tamaño de las thumbsocurre este problema

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 24 Feb 2009 07:51 am

No me explico el problema, entonces los thumbs se mueven para la dercha, pero ya no se pueden regresar hacia la izquierda?

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 24 Feb 2009 03:47 pm

asi es amigo, ademas trate de colocarlos en una ubicacaion navegable pero nada; este mismo problema se dio con la version anterior que me ayudastes la vez pasada, y se soluciono cuando le cambie el "stage" pero ahora no le doy con la solucion.

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 24 Feb 2009 06:27 pm

Estuve analizando el codigo y cuando pongo el snippet.swf y el gallery.swf de las mismas dimenciones de tamaño por ejempllo 880x535 y la ubicacion del "mc_cont" donde llamo a snippet.swf en la posicion de x=0 y y=0 ahi si funciona bien las galeryas; pero si el "mc_cont" pongo por ejemplo x=200 y y=350 u otras ubicacion la galeria no funciona y y sale los errores que te comente. espero me ayudes

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 24 Feb 2009 07:50 pm

Ok, trabajare en eso

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 26 Feb 2009 08:44 am

Problema solucionado, aqui la correccion:

Código ActionScript :

      //Si el mouse esta sobre la galeria de miniaturas 
      //if ( galeria.bounds_mc.hitTest( _xmouse, _ymouse, true ))  Esta linea ya no sirve.
      if ( galeria.bounds_mc.hitTest( _root._xmouse, _root._ymouse, true ))  //Esta es la buena

Suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 26 Feb 2009 05:53 pm

Si funciona xd !!!
Thanks

Por miguel_fox

31 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 05 Abr 2010 04:09 pm

Hola Amigo! Esta galeria es excelente! Ahora me preguntaba si es posible cargar en el lienzo en vez de un JPG un SWF.
Se puede hacer? Que aparezcan las miniaturas tal como estan ( diferentes JPG) pero que al seleccionarlas carguen determinado swf.
Agradezco mucho la ayuda!
Saludos!

Por anibrimo84

29 de clabLevel

Envíale un mensaje privado Web

Venezuela

Ayuda con galeria snippet, no muestra en otro swf externo

Escribe una respuesta rapida