Cambiar el tamaño de un texto en Flash con ActionScript 2

Hace poco estaba realizando una pequeña aplicación en flash, y necesitaba poder cambiar el tamaño del texto. Así que hice este pequeño trozo de código (AS 2.0) que comparto con ustedes, a lo mejor le sirve a alguien :

1. Arrastren un componente ComboBox al escenario, y pónganle nombre de instancia "combo"
   
2. Creen un texto dinámico, y como nombre de instancia "texto_txt"
   
3. Luego coloquen el siguiente código en el primer fotograma de su .fla :
   

Código :

 
var texto:String = "Este es el texto";

// indicamos que el texto permita etiquetas html
texto_txt.html = true;

// aqui colocamos el texto con la etiqueta font 
//y el valor de la primera opcion del comboBox 
texto_txt.htmlText = "<font size='"+combo.value+"'>"+texto+"</font>";


// creamos un array con los distintos tamaños
// que vamos a tener para agregar al comboBox  
var tamano:Array = new Array("12", "16", "20", "25", "30");

// agregamos los datos del array al comboBox
combo.dataProvider = tamano;

// creamos un listener para que se realice el cambio de tamaño del texto
var cambia = new Object();

// función que se activa cuando se cambie el valor del combobox
cambia.change = function(evt) {
   trace(combo.value);
   texto_txt.htmlText = "<font size='"+combo.value+"'>"+texto+"</font>";
};
combo.addEventListener('change', cambia); 

Un uso práctico sería colocarlo en una web para la gente que no pueda leer el texto en un tamaño pequeño, yo lo veo como una herramienta de gran utilidad, espero que le sirva a alguien.

PD: si alguien lo puede pasar a AS 3.0, sería genial, yo no lo hago porque no se mucho


Quizás le interesen también :

• Texto con scroll a dos columnas
  
• Efectos de texto y bordeados en ActionScript
  
• Personalizar los componentes de Flash
  
• Tutorial del componente ComboBox
  

nice si lo amplis un poco lo puedes poner como tip

No importa si esta como tip, con que le sirva a alguien es suficiente

Aquí pase el código a AS 3.0, me ayude de un tip de Carlos.Yañez sobre un visor de fuentes para poder lograrlo, arrastren un componente comboBox al escenario y pónganle nombre de instancia combo, luego arrastren un componente ColorPicker e instancienlo como txt_color, creen un texto dinámico, y pónganle de nombre de instancia texto_txt y en el primer fotograma pegan el código:

Código :

import fl.events.ColorPickerEvent;
import fl.data.DataProvider;
//
// el array para los datos del comboBox
var tamano:Array = [
{label:"10", data:"10"},
{label:"12", data:"12"},
{label:"14", data:"14"},
{label:"16", data:"16"},
{label:"18", data:"18"},
{label:"20", data:"20"},
];
// creamos un objeto textFormat
var format:TextFormat = new TextFormat();
//
// aquí está el listener que llamará a la función que se encarga de
//cambiar de color
txt_color.addEventListener(ColorPickerEvent.CHANGE,cambia_color);
function cambia_color(event:ColorPickerEvent):void {
   format.color = event.target.selectedColor;
   texto_txt.setTextFormat(format);
}
// se agregan los datos del array al comboBox
combo.dataProvider = new DataProvider(tamano);
// listener que llamará a la función  que se encarga de cambiar el tamaño
combo.addEventListener(Event.CHANGE, setFont);
function setFont(event:Event):void {
   format.size = combo.selectedItem.data;
   texto_txt.setTextFormat(format);
}
var texto:String = "Este es el texto";
texto_txt.text = texto; 

No se porque no pude mostrar el ejemplo directamente, asique aca les dejo el link:
ejemplo

muy buen aporte, me viene de lujo para un proyecto