Color de fila de un datagrid !

Alguien sabe como cambiarle el color de fondo a una celda de un dataGrid ..?

saludos

Hola

Si es en una celda en particular, podes usar itemRenderder junto con alguna condicion, para poner de fondo un color u otro...

Estas usando Flex o Flash cs3???

Saludos

Uso Flex, pero estoy mirando, las functiones drawRowBackground, updateDisplayList, a ver que les puedo sacar....

saludos

Bueno aqui pongo como lo eh solucionado...

Primero que todo hago una clase llamada myDataGrid que extiende de mx.controls.Datagrid y la situo en la misma carpeta del proyecto Flex, (la puedes poner donde quieras y despues especificar en el package de la clase la ruta.)

MyDataGrid.as

Código :

package { 

  import mx.controls.DataGrid;
  public class myDataGrid extends DataGrid {

  }
}

y dentro de ella sobre-escribimos el metodo drawRowBackground que no es mas que el metodo en el datagrid que se encarga de pintar el fondo de la celda..

Código :

package { 
    import mx.collections.ArrayCollection;
    import mx.controls.DataGrid;
    import flash.display.Sprite;

  public class myDataGrid extends DataGrid {
       override protected function drawRowBackground(s:Sprite,rowIndex:int,y:Number,height:Number,color:uint,dataIndex:int):void  
        {  
         var dp:ArrayCollection = dataProvider as ArrayCollection;
         var item:Object;
                          
         if( dataIndex < dp.length ) item = dp.getItemAt(dataIndex);
         if( item != null && item.price < 20 ) color = 0xFF8800;
         else color = 0xFFFFFF;
         
         super.drawRowBackground(s,rowIndex,y,height,color,dataIndex);  
         } 
  }
}

Desmenuzando un poco este codigo..
var dp:ArrayCollection = dataProvider as ArrayCollection; --> Creamos un arrayCollection dp que le pasaremos el contenido del dataProvider del Grid en cuestion [el mismo.]
var item:Object; --> Una variable objet para almacenar temporalmente el contenido de la fila
if( dataIndex < dp.length ) item = dp.getItemAt(dataIndex); --> Aqui le añado el contenido de la fila actual a item SI el dataIndex [indice de la fila actual] es menor que el largo del arrayCollection dp que es la copia del dataProvider. (el # de filas de un datagrid no es = al numero de elementos del dataProvider!)
if( item != null && item.price < 20 ) color = 0xFF8800; --> Aqui digo que si item que es el que contiene los valores de la fila actual no es null y ademas el campo price <20 la variable color sera un naranja claro..
else color = 0xFFFFFF; --> Si no la variable color sera blanca...

super.drawRowBackground(s,rowIndex,y,height,color,dataIndex); --> Aqui invocamos al metodo drawRowBackground de la superclase... (dataGrid)... dentro de los parametros que se le pasa..

Bien ahora abrimos nuestro proyecto Flex. y creamos el siguiente script que nos llena un arrayCollection provisional ..

Código :

<mx:Script>
   <![CDATA[
      import mx.collections.ArrayCollection;
      [Bindable] public var f:ArrayCollection = new ArrayCollection();
      
      function a()
      {
         var h:Object = new Object();
         for(var i:int=0;i<10;i++)
         {
            h = {};
            h["products"] = "Judias_"+i.toString();
            h["price"] = 10*i;
            f.addItem(h);
         }
      }
   ]]>
</mx:Script>

Ahora insertamos nuestro GRID (myDataGrid)...

Código :

<local:myDataGrid dataProvider="{ f }" >
   <local:columns>
      <mx:DataGridColumn headerText="Column 1" dataField="products"/>
      <mx:DataGridColumn headerText="Column 2" dataField="price"/>
   </local:columns>
</local:myDataGrid>

Ejecutamos y listo...


espero les sea de ayuda ....

Es de mucha ayuda, yo también así lo hago y con Flex 2, creo que es la opción mas decente. Deberías pasar esto a tip.


saludos

Como paso esto a tips ???, es que nunca eh hecho uno y no se como es el mecanismo.... !!

saludos

Joris Van Spilbergen escribió:

Simplemente escribe un artículo como un nuevo tema en el foro "Tips". Pasado un rato aparecerá en portada.

Saludos

Y para que esto funcione local:myDataGrid, como hay que agregarlo?
xmlns:local="myDataGrid.as"

o como?

Hola!, por casualidad saben hacer esto en un combobox de flash con as3? Muchas gracias! Saludos.
m