Como declaro una variable que peuda ser accedida desde varios xmlm

Hola amigos, estoy intentando declarar unas variables "globales" , y ya he intentado con static, public ... y siemrpe me dice Access of undefined property "nombre de la variable"... como le hagoooooooooo!

BuenAS:

Puedes crearte una clase Singleton (patrón Singleton), VariablesGlobales.as:

Código ActionScript :

package
{
   public class VariablesGlobales
   {
      //--------------------------------------------------------------------------
      //
      //  Variables publicas
      //
      //--------------------------------------------------------------------------
      public var miVariable:Number;
      
      //--------------------------------------------------------------------------
      //
      //  Variables privadas
      //
      //--------------------------------------------------------------------------
      private static var instance:VariablesGlobales;
      private static var allowInstantiation:Boolean;
      
      public static function getInstance():VariablesGlobales
      {
         if (instance == null) {
            allowInstantiation = true;
            instance = new VariablesGlobales();
            allowInstantiation = false;
         }
         return instance;
      }
      
      public function VariablesGlobales()
      {
         if (!allowInstantiation) {
            throw new Error("Error al instanciar: Utiliza VariablesGlobales.getInstance() en lugar de new.");
         }
      }
    }
}

y accederías, por ejemplo, a la variable miVariable:

Código ActionScript :

var config:VariablesGlobales = VariablesGlobales.getInstance();            
config.miVariable = 10;

Pero si lo que quieres es obtener valores desde distintos ptos de tu aplicación (distintos mxml en tu caso), crea una clase, por ejemplo, VariablesGlobalesEstaticas.as:

Código ActionScript :

package
{
   public class VariablesGlobalesEstaticas
   {
      public static var miPrimerValor:Number;
      public static var miSegundoValor:Number;
   }
}

y accederías a sus valores:

Código ActionScript :

var valor1:Number = VariablesGlobalesEstaticas.miPrimerValor;
var valor2:Number = VariablesGlobalesEstaticas.miSegundoValor;

Un saludo.