Como obtener automaticamente el codigo de un filtro realizad

Citar

Escrito el 07 Dic 2008 11:54 am

Como obtener automaticamente el codigo de un filtro realizado en flash en la diseño???

Cuando uno aplica un filtro, no con actionscript, sino en flash en diseño, hay alguna forma de automaticamente obtener el codigo en actionscript???

Caso de que no se pueda, hay alguien que sepa donde puede haber un flash ya hecho que de el codigo como este de swish:

http://www.swishzone.com/products/max/demos/swf/Filter_Effect_Generator.swf

Saludos!!!

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 08 Dic 2008 08:00 pm

hola, bueno, no te entiendo esa parte de obtener el codigo del filtro en AS, te refieres a obtener una funcion formateada inversa al filtro aplicado, o te refieres a obtener los valores que estan en el filtro para luego mediante codigo puedas usarlos

bueno, supon que tienes un movielcip llamado clip_mc, el cual en timpo de diseño le pones uno o varios filtros ColorMatrixFilter o filtro de ajuste de color(brillo, contraste, saturacion y matiz), ok, entonces intenta esto:

Código :

import flash.filters.ColorMatrixFilter;

var filtros:Array = clip_mc.filters;


for( var i:Number = 0; filtros[i] != undefined; i++ )
{
   if( filtros[i] instanceof ColorMatrixFilter )
   {
      var matrix:Array = filtros[i].matrix;
      var salida:String = "new ColorMatrixFilter([";
      for( var j:Number = 0; matrix[j] != undefined; j++ )
      {
         salida += matrix[j] + ",";
      }
      salida = salida.substring(0,salida.length-1) + "]);";
      trace(salida);
   }

dime si eso es parecido a lo que necesitas, suerte.-

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 09 Dic 2008 03:22 am

Muy bueno, ok!!!

He probado, eso si, con otro filtro, con GradientBevelFilter, y ahi no me sale de momento... Si sabes como se hace en el caso de otros filtros, te lo agradeceria, muy bueno el codigo...

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 09 Dic 2008 05:51 am

hola, bueno, si es masomenos lo que necesitas, entonces tendiramos que poner una seccion para cada filtro posible, por ejemplo, para el fultro BlurFilter, el constructor es del tipo new BlurFilter( blurX, blurY, quiality ), entonces se obtienen esas tres propiedades y se construlle el string, bueno, dejame elaborar el codigo completo para cada uno de los filtros y lo publicare en este post, o en algun ejemplo o tip o algo asi lo que mas se acomode, alguien me puede decir si lo mejor sera publicarlo en un tip o en un ejemplo, o mejor en este post, porque bueno ese codigo puede ser util para muchas otras cosas, nos vemos pronto.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 09 Dic 2008 07:53 am

Hola LongeVie, anduve buscando, y parece que como dices no se puede hacer de forma tan automatica como en ColorMatrixFilter... Hay que hacerlo como dices, sacando cada parte de cada filtro una por una...

Hay una clase de google que lo tiene mas o menos hecho al parecer:

http://tweener.googlecode.com/svn/trunk/as2/caurina/transitions/properties/FilterShortcuts.as

// ----------------------------------------------------------------------------------------------------------------------------------
// filters

/**
* Splits the _filter, _blur, etc parameter into specific filter variables
*
* @param p_value BitmapFilter A BitmapFilter instance
* @return Array An array containing the .name and .value of all new properties
*/
public static function _filter_splitter (p_value:BitmapFilter):Array {
var nArray:Array = new Array();
if (p_value instanceof BevelFilter) {
nArray.push({name:"_Bevel_angle", value:BevelFilter(p_value).angle});
nArray.push({name:"_Bevel_blurX", value:BevelFilter(p_value).blurX});
nArray.push({name:"_Bevel_blurY", value:BevelFilter(p_value).blurY});
nArray.push({name:"_Bevel_distance", value:BevelFilter(p_value).distance});
nArray.push({name:"_Bevel_highlightAlpha", value:BevelFilter(p_value).highlightAlpha});
nArray.push({name:"_Bevel_highlightColor", value:BevelFilter(p_value).highlightColor});
nArray.push({name:"_Bevel_knockout", value:BevelFilter(p_value).knockout});
nArray.push({name:"_Bevel_quality", value:BevelFilter(p_value).quality});
nArray.push({name:"_Bevel_shadowAlpha", value:BevelFilter(p_value).shadowAlpha});
nArray.push({name:"_Bevel_shadowColor", value:BevelFilter(p_value).shadowColor});
nArray.push({name:"_Bevel_strength", value:BevelFilter(p_value).strength});
nArray.push({name:"_Bevel_type", value:BevelFilter(p_value).type});
} else if (p_value instanceof BlurFilter) {
nArray.push({name:"_Blur_blurX", value:BlurFilter(p_value).blurX});
nArray.push({name:"_Blur_blurY", value:BlurFilter(p_value).blurY});
nArray.push({name:"_Blur_quality", value:BlurFilter(p_value).quality});
} else if (p_value instanceof ColorMatrixFilter) {
nArray.push({name:"_ColorMatrix_matrix", value:ColorMatrixFilter(p_value).matrix});
} else if (p_value instanceof ConvolutionFilter) {
nArray.push({name:"_Convolution_alpha", value:ConvolutionFilter(p_value).alpha});
nArray.push({name:"_Convolution_bias", value:ConvolutionFilter(p_value).bias});
nArray.push({name:"_Convolution_clamp", value:ConvolutionFilter(p_value).clamp});
nArray.push({name:"_Convolution_color", value:ConvolutionFilter(p_value).color});
// .matrix
nArray.push({name:"_Convolution_divisor", value:ConvolutionFilter(p_value).divisor});
nArray.push({name:"_Convolution_matrixX", value:ConvolutionFilter(p_value).matrixX});
nArray.push({name:"_Convolution_matrixY", value:ConvolutionFilter(p_value).matrixY});
nArray.push({name:"_Convolution_preserveAlpha", value:ConvolutionFilter(p_value).preserveAlpha});
} else if (p_value instanceof DisplacementMapFilter) {
nArray.push({name:"_DisplacementMap_alpha", value:DisplacementMapFilter(p_value).alpha});
nArray.push({name:"_DisplacementMap_color", value:DisplacementMapFilter(p_value).color});
nArray.push({name:"_DisplacementMap_componentX", value:DisplacementMapFilter(p_value).componentX});
nArray.push({name:"_DisplacementMap_componentY", value:DisplacementMapFilter(p_value).componentY});
nArray.push({name:"_DisplacementMap_mapBitmap", value:DisplacementMapFilter(p_value).mapBitmap});
nArray.push({name:"_DisplacementMap_mapPoint", value:DisplacementMapFilter(p_value).mapPoint});
nArray.push({name:"_DisplacementMap_mode", value:DisplacementMapFilter(p_value).mode});
nArray.push({name:"_DisplacementMap_scaleX", value:DisplacementMapFilter(p_value).scaleX});
nArray.push({name:"_DisplacementMap_scaleY", value:DisplacementMapFilter(p_value).scaleY});
} else if (p_value instanceof DropShadowFilter) {
nArray.push({name:"_DropShadow_alpha", value:DropShadowFilter(p_value).alpha});
nArray.push({name:"_DropShadow_angle", value:DropShadowFilter(p_value).angle});
nArray.push({name:"_DropShadow_blurX", value:DropShadowFilter(p_value).blurX});
nArray.push({name:"_DropShadow_blurY", value:DropShadowFilter(p_value).blurY});
nArray.push({name:"_DropShadow_color", value:DropShadowFilter(p_value).color});
nArray.push({name:"_DropShadow_distance", value:DropShadowFilter(p_value).distance});
nArray.push({name:"_DropShadow_hideObject", value:DropShadowFilter(p_value).hideObject});
nArray.push({name:"_DropShadow_inner", value:DropShadowFilter(p_value).inner});
nArray.push({name:"_DropShadow_knockout", value:DropShadowFilter(p_value).knockout});
nArray.push({name:"_DropShadow_quality", value:DropShadowFilter(p_value).quality});
nArray.push({name:"_DropShadow_strength", value:DropShadowFilter(p_value).strength});
} else if (p_value instanceof GlowFilter) {
nArray.push({name:"_Glow_alpha", value:GlowFilter(p_value).alpha});
nArray.push({name:"_Glow_blurX", value:GlowFilter(p_value).blurX});
nArray.push({name:"_Glow_blurY", value:GlowFilter(p_value).blurY});
nArray.push({name:"_Glow_color", value:GlowFilter(p_value).color});
nArray.push({name:"_Glow_inner", value:GlowFilter(p_value).inner});
nArray.push({name:"_Glow_knockout", value:GlowFilter(p_value).knockout});
nArray.push({name:"_Glow_quality", value:GlowFilter(p_value).quality});
nArray.push({name:"_Glow_strength", value:GlowFilter(p_value).strength});
} else if (p_value instanceof GradientBevelFilter) {
// .alphas (array)
nArray.push({name:"_GradientBevel_angle", value:GradientBevelFilter(p_value).strength});
nArray.push({name:"_GradientBevel_blurX", value:GradientBevelFilter(p_value).blurX});
nArray.push({name:"_GradientBevel_blurY", value:GradientBevelFilter(p_value).blurY});
// .colors (array)
nArray.push({name:"_GradientBevel_distance", value:GradientBevelFilter(p_value).distance});
nArray.push({name:"_GradientBevel_quality", value:GradientBevelFilter(p_value).quality});
// .ratios(array)
nArray.push({name:"_GradientBevel_strength", value:GradientBevelFilter(p_value).strength});
nArray.push({name:"_GradientBevel_type", value:GradientBevelFilter(p_value).type});
} else if (p_value instanceof GradientGlowFilter) {
// .alphas (array)
nArray.push({name:"_GradientGlow_angle", value:GradientGlowFilter(p_value).strength});
nArray.push({name:"_GradientGlow_blurX", value:GradientGlowFilter(p_value).blurX});
nArray.push({name:"_GradientGlow_blurY", value:GradientGlowFilter(p_value).blurY});
// .colors (array)
nArray.push({name:"_GradientGlow_distance", value:GradientGlowFilter(p_value).distance});
nArray.push({name:"_GradientGlow_knockout", value:GradientGlowFilter(p_value).knockout});
nArray.push({name:"_GradientGlow_quality", value:GradientGlowFilter(p_value).quality});
// .ratios(array)
nArray.push({name:"_GradientGlow_strength", value:GradientGlowFilter(p_value).strength});
nArray.push({name:"_GradientGlow_type", value:GradientGlowFilter(p_value).type});
} else {
// ?
trace ("Tweener FilterShortcuts Error :: Unknown filter class used");
}
return nArray;
}

Que puede ayudar...

Deberia de haber un flash tambien como ese de swiss, para poder ir experimentando con filtros, y luego salvando el codigo ya en actionscript, encapsulado en una funcion por ejemplo, para un facil reuso, y salvarlo por ejemplo en un xml, que pueda asi hacerse automatica la cuestion, pues creo que xml es la unica opcion si queremos exportar al disco duro desde flash algo de codigo, salvarlo...

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 09 Dic 2008 07:56 am

En cuanto a un software que vaya adonde flash guarda los presets de los filtros y los salve en actionscript, ese ya lo tengo en realidad casi listo, esta hecho como un 99%, me falta solo una tonteria con el parametro strength que flash en los preset los guarda como % de 0 a 1000, y hay que ponerlo equivalente a de 0 a 255, es una utilidad tonta para poder salvar todos los presets que tenga alguien por ahi encapslados en una funcion que luego se puede aplicar de forma ams comoda que poner un objeto o clip y aplicarle luego el preset, que es algo como primitivo, lo interesante es tener en codigo...

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 09 Dic 2008 09:07 am

ok ok, entonces vamos a hacer un script que recibe un movieclip como parametro y regresa un string que representa todos los filtros, el codigo que has puesto puede ayudarme pero lo tengo que chekar, y comparar con la ayuda de flash, que es en donde vienen todos los filtros, por cierto, el script que pusiste, tampoco lo hace de forma "tan automatica" como mencionas, bueno, te lo tengo mañana publicado en este post, porke aki ya es de madrugada y tengo que dormir, nos vemos pronto

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 09 Dic 2008 07:19 pm

Hola, aqui esta el codigo final, con todos los filtros posibles, utilice un poco tu script pero termine modificandolo del todo, entonces cree esto que como salida final retorna una declaracion in line del array de filtros, que si se quiere utilizar de nuevo basta con filters=[ ] donde [ ] es la cadena obtenida, tambien encontre problemas con este tipo de declaracion con el filtro DisplacementMapFilter, ya que la cadena pbtenida de un filtro DisplacementMapFilter, no establece en varios casos, el filtro original, ya que BitmapData, no siempre es un Bitmap creado con tres parametros, por lo general es creado a partir de una imagen o con un createGradientBitmap, bueno, espero que lo disfrutes, ciao!

Código :

import flash.geom.Point;
import flash.display.BitmapData;
import flash.filters.*;

//Output obtenido de una prueba
//[(new BevelFilter(-13,294.999476592732,3381759,1,16711680,1,61,61,10,3,"full",true)),(new GradientGlowFilter(5,131.999908050586,[16777215,0],[0,1],[0,255],9,9,0.77734375,3,"outer",false))]
trace( flitersToString(clip_mc.filters) )

function flitersToString( p_value:Array ):String
{
   return "[" + arrayToString( p_value ) + "]";
}

function filterToString( p_value:BitmapFilter ):String
{
   return "new "+ filterTypeToString( p_value ) +"("+ arrayToString( filterToArray( p_value ) ) +")";
}

function filterTypeToString( p_value:BitmapFilter ):String
{
   if (p_value instanceof BevelFilter) 
   {
      return "BevelFilter";
   } 
   else if (p_value instanceof BlurFilter)
   {
      return "BlurFilter";
   } 
   else if (p_value instanceof ColorMatrixFilter) 
   {
      return "ColorMatrixFilter";
   } 
   else if (p_value instanceof ConvolutionFilter) 
   {
      return "ConvolutionFilter";
   }
   else if (p_value instanceof DropShadowFilter) 
   {
      return "DropShadowFilter";
   } 
   else if (p_value instanceof GlowFilter) 
   {
      return "GlowFilter";
   }
   else if (p_value instanceof GradientBevelFilter) 
   {
      return "GradientBevelFilter";
   } 
   else if (p_value instanceof GradientGlowFilter) 
   {
      return "GradientGlowFilter";
   }
   else if (p_value instanceof DisplacementMapFilter) 
   {
      return "DisplacementMapFilter";
   }
}

function filterToArray( p_value:BitmapFilter ):Array 
{
   var nArray:Array = new Array();
   if (p_value instanceof BevelFilter) 
   {
      nArray.push(BevelFilter(p_value).distance);
      nArray.push(BevelFilter(p_value).angle);
      nArray.push(BevelFilter(p_value).highlightColor);
      nArray.push(BevelFilter(p_value).highlightAlpha);
      nArray.push(BevelFilter(p_value).shadowColor);      
      nArray.push(BevelFilter(p_value).shadowAlpha);
      nArray.push(BevelFilter(p_value).blurX);
      nArray.push(BevelFilter(p_value).blurY);
      nArray.push(BevelFilter(p_value).strength);
      nArray.push(BevelFilter(p_value).quality);
      nArray.push(BevelFilter(p_value).type);
      nArray.push(BevelFilter(p_value).knockout);      
   } 
   else if (p_value instanceof BlurFilter)
   {
      nArray.push(BlurFilter(p_value).blurX);
      nArray.push(BlurFilter(p_value).blurY);
      nArray.push(BlurFilter(p_value).quality);
   } 
   else if (p_value instanceof ColorMatrixFilter) 
   {
      nArray.push(ColorMatrixFilter(p_value).matrix);
   } 
   else if (p_value instanceof ConvolutionFilter) 
   {
      nArray.push(ConvolutionFilter(p_value).matrixX);
      nArray.push(ConvolutionFilter(p_value).matrixY);
      nArray.push(ConvolutionFilter(p_value).matrix);
      nArray.push(ConvolutionFilter(p_value).divisor);
      nArray.push(ConvolutionFilter(p_value).bias);
      nArray.push(ConvolutionFilter(p_value).preserveAlpha);
      nArray.push(ConvolutionFilter(p_value).clamp);
      nArray.push(ConvolutionFilter(p_value).color);
      nArray.push(ConvolutionFilter(p_value).alpha);
   }
   else if (p_value instanceof DropShadowFilter) 
   {
      nArray.push(DropShadowFilter(p_value).distance);
      nArray.push(DropShadowFilter(p_value).angle);
      nArray.push(DropShadowFilter(p_value).color);
      nArray.push(DropShadowFilter(p_value).alpha);
      nArray.push(DropShadowFilter(p_value).blurX);
      nArray.push(DropShadowFilter(p_value).blurY);
      nArray.push(DropShadowFilter(p_value).strength);
      nArray.push(DropShadowFilter(p_value).quality);
      nArray.push(DropShadowFilter(p_value).inner);
      nArray.push(DropShadowFilter(p_value).knockout);
      nArray.push(DropShadowFilter(p_value).hideObject);
   } 
   else if (p_value instanceof GlowFilter) 
   {
      nArray.push(GlowFilter(p_value).color);
      nArray.push(GlowFilter(p_value).alpha);
      nArray.push(GlowFilter(p_value).blurX);
      nArray.push(GlowFilter(p_value).blurY);
      nArray.push(GlowFilter(p_value).strength);
      nArray.push(GlowFilter(p_value).quality);
      nArray.push(GlowFilter(p_value).inner);
      nArray.push(GlowFilter(p_value).knockout);   
   }
   else if (p_value instanceof GradientBevelFilter) 
   {
      nArray.push(GradientBevelFilter(p_value).distance);
      nArray.push(GradientBevelFilter(p_value).angle);
      nArray.push(GradientBevelFilter(p_value).colors);
      nArray.push(GradientBevelFilter(p_value).alphas);
      nArray.push(GradientBevelFilter(p_value).ratios);
      nArray.push(GradientBevelFilter(p_value).blurX);
      nArray.push(GradientBevelFilter(p_value).blurY);
      nArray.push(GradientBevelFilter(p_value).strength);
      nArray.push(GradientBevelFilter(p_value).quality);
      nArray.push(GradientBevelFilter(p_value).type);
      nArray.push(GradientBevelFilter(p_value).knockout);
   } 
   else if (p_value instanceof GradientGlowFilter) 
   {
      nArray.push(GradientGlowFilter(p_value).distance);
      nArray.push(GradientGlowFilter(p_value).angle);
      nArray.push(GradientGlowFilter(p_value).colors);
      nArray.push(GradientGlowFilter(p_value).alphas);
      nArray.push(GradientGlowFilter(p_value).ratios);
      nArray.push(GradientGlowFilter(p_value).blurX);
      nArray.push(GradientGlowFilter(p_value).blurY);
      nArray.push(GradientGlowFilter(p_value).strength);
      nArray.push(GradientGlowFilter(p_value).quality);
      nArray.push(GradientGlowFilter(p_value).type);
      nArray.push(GradientGlowFilter(p_value).knockout);
   }
   else if (p_value instanceof DisplacementMapFilter) 
   {
      //BitMapData
      nArray.push(DisplacementMapFilter(p_value).mapBitmap);
      //Point
      nArray.push(DisplacementMapFilter(p_value).mapPoint);
      nArray.push(DisplacementMapFilter(p_value).componentX);
      nArray.push(DisplacementMapFilter(p_value).componentY);
      nArray.push(DisplacementMapFilter(p_value).scaleX);
      nArray.push(DisplacementMapFilter(p_value).scaleY);
      nArray.push(DisplacementMapFilter(p_value).mode);
      nArray.push(DisplacementMapFilter(p_value).color);
      nArray.push(DisplacementMapFilter(p_value).alpha);   
   }
   return nArray;
}

function arrayToString( arr:Array ):String
{
   var salida:String = "";
   for( var i:Number = 0; arr[i] != undefined; i++ )
    {
      if( arr[i] instanceof Array )
      {
         salida += "[" + arrayToString(arr[i]) + "]" ;
      }
      else if( arr[i] instanceof BitmapData )
      {
         salida += "(new BitmapData(" + arr[i].width + "," + arr[i].height + "," + arr[i].transparent + "))";
      }
      else if( arr[i] instanceof Point )
      {
         salida += "(new Point(" + arr[i].x + "," + arr[i].y + "))";
      }
      else if( arr[i] instanceof BitmapFilter )
      {
         salida += "(" + filterToString( arr[i] ) + ")";
      }
      else if( typeof(arr[i]) == "string" )
      {
         salida += "\"" + arr[i] + "\"";
      }
      else
      {
         salida += arr[i];
      }
      salida += ",";
   }
   return salida.substring( 0, salida.length - 1 );
}

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 10 Dic 2008 09:49 pm

Eres un hacha!!!

Bueno, he andado liado, ando en varias cosas, con la crisis jeje, ya se sabe...

Por cierto, aparte, y no te asustes, yo soy astrologo, y quizas de los unicos 10 que dijomos de esta crisis y cuando seria, con bastante precision, y ufff, aun no hemos visto nada... En mi web principal tienes videos incluso hechos hace muchos años avisando de cuando empezaria la gran crisis, a partir de Junio 2008 empezaba segun las posciones planetarias, y asi ha sido:

www.astrodreams.com/flashweb/newweb.htm

Si te interesa un osftware de astrologia, te lo regalo por la buena onda que tienes, aunque mi programa, Zodiac, es en realidad muy tecnico... Por cierto, yo soy en realidad un esceptico, me costo 19 años el creerme que algo habia de cierto en Astrologia, pues la verdad es que en el mundo de la astrologia alucinan bastante, son un caos, pero si se mira a fondo, es casi imposible que no haya algo, la prueba es los miles - google no los pone todos, pero debe de haber entre 3 y 5000 mensajes en mi foro sobre la crisis del 2010, y muchos comentando que empezaria en Junio 2008 a verse claramente, y como es que hemos acertado tanto??? Causalidad??? No creo en casualidades muy fuertes jeje... Aqui hay un resumen de los mensajes en mi foro sobre el 2010, todo empezara, lo gordo, en 2010, y en verano 2010, el climax primero, pues esta crisis dura hasta 2018... Aun solo se ha visto como un 10% de todo lo que tiene que venir:

www.2010supercrisis.com

Ok, despues de esta disertacion sobre mi profesion principal, thanks!!! Mirare luego tu codigo, que seguro funcionara superior!!!, y me viene muy bien!!! Y, otra cosa, una idea que creo muy buena y como eres bueno programando, pues mira, hay un filon en flash en hacer sitios web como los de template monster:

http://www.templatemonster.com/

Pero con un exe que los personalize...!!!!!!!!!!!!!!!!!!! O sea, ahora ya se hacen sitios que se configuran con XML, pero escribir ese xml o manejarlo es pesado, hace falta un exe, que por ejemplo haga esto:

Imagina que el flash es una galeria de imagenes, hace falta un exe en el que se puedan escoger del disco duro las imagenes, que salve un thumb de cada una, organice todo en unos subdirectorios del flash, por ejemplo, el flash reside en un directorio, pues las galerias organizarlas creando subdrectorios "gallery1", "gallery2", "gallery3", etc...

Luego que se puedan poner los textos de los menus, etc, y que, para rematar, el software tenga un subprograma FTP para subir la galeria completa a la web, y, si se quiere, se puede ofrecer servicio de hosting o similar, que tambien puede ser economicamente bueno... Es que yo, la astrologia vende poco, y tengo que buscar otras cosas jeje...

Un abrazo, gracias por el codigo, a ver si esta noche puedo probarlo... Me falta aun esa tonteria del software para converir los filter presets ya salvados a actionscript y que los save en un archivo, pues con el codigo de este tema que has puesto se puede sacar los filtros aplicados a un movieclip, pero con el software se pueden salar de un plumazo todos los filter presets salvados previamente, no ir cargandolos y convirtiendolos, sino directamente con un boton salvar en un archivo con funciones diferentes para cada preset, todos los que se tengan de todos los flash, flash 8, cs3, etc... Si sabes visual basic te puedo pasar el codigo si quieres, esta listo del todo casi,solo mi falta de tiempo y que flashden me ha dicho que softwares no quieren poner a la venta, pero es que si se quiere buscar los presets previamente salvados, como flash no tienen acceso al disco duro, no es posible hacerlo en flash, hace falta hacerlo en un exe que tenga acceso al disco duro y directorios...

Un saludo, que opinas de lo de personalizar flash con un exe, dejaria muy sencillo el hacer una web, y se podria vender muy bien... La idea no se la doy a cualquiera ehhhh, jeje...!!! Por la buena onda tuya en el codigo la he soltado, pues creo que es muy buena...!!!

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 10 Dic 2008 11:15 pm

Una pregunta tonta si tienes tiempo, como se crea un timeline con codigo actionscript???

Por ejemplo, lago simple, yo creo un createEmptyMovieCLip y quiero que tenga 4 frames, en cada cual habra otro movieclip al que le subo una imagen a cada uno, quizas sea muy simple, pero como se hace??? He andado buscando y no encuentro, quizas es que sea muy simple, pero no se bien, no creo que sea con new Tween, pues eso es para transformaciones, solo neceisto crear un movieclip, y dentro de el 4 frames a las que les creo un movieclip a cada una, y lueog puedo moverme en ello con gotoAndStop o gotoAndPlay, peor como se hace eso con actionscript, si me lo dices me haras un gran favor...

No se si estoy abusando de tu paciencia...

Un abrazo...!!! Gracias de antemano y si tienes tiempo...

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 11 Dic 2008 01:46 am

Bueno mi querido astrologo, debo decir que soy un esceptico, en realidad, cuando lo amerita, me proclamo en contra de todo esoterismo, profecias, vaticinios o destinos zodiacales, aunque, en la mayoria de los casos, solo me hago de la vista gorda y sigo mi propio camino, pero bueno, la idea que tienes sobre un exe que desarrollas me resultaria interesante si no estuviese desarrollando en este momento una idea similar pero para la web, la he nombrado Manejador de Contenidos Flash, la estoy desarrollando en PHP, ASP.net y Flash, idea que a su vez surgio de un programa que hice para una empresa para la que trabaje, en otras palabras, mi sistema hace lo que prende hacer el tuyo, pero este esta instalado sobre un servidor y no se descarga, se corre directamente en un Explorador de Internet, aun estoy desarrollandolo y me ha costado casi medio año ya, toda la informacion es guardada en XML y en una plantilla base, se le carga ese XML y automaticamente lo representa en una pagina web navegable en su totalidad en flash, lo que significa que tu sistema y el mio en cierto modo, algun dia competiran, pero no seriamos grandes rivales, hay muchas tecnologias para crear paginas web, frameworks, flash mismo, tiene al poderoso GAIA y mas, el unico pro que yo le veo a mi sistema es que es tan facil de usar que un diseñador de primer año podria desarrollar toda una web, con efectos solo logrables atraves de programacion, pero en realidad mi sistema presenta muchas limitantes debido a que es web y los recursos debeb subirse al servidor, entonces se podria decir que mi sistema tambien es de hosting, estas limitantes me tomaran varias versiones resolver, aun asi, al dia de hoy yo ya tengo competencia pues se de varias empresas que hacen algo parecido a lo que hago, y ellos tienen progrmas muy avanzados, aun asi, confio en que la forma de vender este sistema sera lo que le gane clientes, bueno, sera coincidencia que hacemos cosas similares, y soy bueno en VB tambien, asi que te deseo la mejor de las suertes y pronostico que nos ira bien.

Respondiendo tu pregunta de hacer una timeLine, no hay una forma de hacer fotogramas que no se programe, osea uno tendira que crear una especie de clase llamada LINEATIEMPO, que se comporte de forma en que lo hace la linea de tiempo de flash, en donde ademas de CAPAS y FOTOGRAMAS estos tendiran objetos asignados que desaparecen y aparecen dependiendo de sus tiempo de vida en los fotogramas y se superponene dependiendo de la capa en la que este, no es dificil programa eso, en realidad tendirasmo problemas cuando quicieramos poner cosas mas dificiles como seria timelines anidadas, vez que cada movieclip tiene una timeline y ademas tambien en las timeline se pueden hacer interpolaciones, y al verdad quedaria una cosa muy compleja, ademas si quicieras representar eso en XML tambien costaria un poco de trabajo, segun yo por codigo, no hay forma de situar un movieclip en un fotograma, amenos que el codigo este en dicho fotograma.

espero haber sido claro, seguire pensando en una solucion y a lo mejro te publico el codigo aqui. nos vemos.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 11 Dic 2008 05:30 am

Curioso que estes haciendo tambien algo parecido, aunque mas complejo lo tuyo por lo que veo... La idea en esencia es muy similar, casi igual, lo que ru a traves de la web...

En realidad es una idea evidente que no se porque no se ha hecho aun, pero bueno, ne informatica hay que llegar primero, sino... Adios... jeje...

Lo de esceptico, bueno, yo tambien lo era, y ahora soy un ultra completo enormenete convencido, es imposible tantas casualidades... No es posible que no haya algo que emiten o lo que sea, pero influyen los planetas, de eso no tengo ninguna duda... Fijate los proximos dias, habra mucho lios, violencia, nada del otro mundo, pero si se notara, ya se esta notando de hecho... Es Marte activando, y ese es un broncas total...

No voy a darte la tabarra, pero solo te digo que si algun dia tienes tiempo y curiosidad, profundiza en el tema y no te fies de la panda de alucinados que hay en el tema, basate solo en angulos y posiciones planetarias - completamente precisas y medibles -, y te llevaras una sorpresa... Aunque no queda mucho tiempo, las influencias van como por oleadas, ahora estamos en la recogida de la primera ola de la crisis, a partir de mediados de enero empezara la segunda ola, que tendra su climax como por Septiembre de 2009...

Y lo gordo de verdad, el show en si, comienza en 2010, pues ahi se complicara con conflictos belicos, con Iran casi seguro, y en 2010 habra un verdadero bajon, un aumento exponencial de la crisis en si, y muy duro... NO son profecias, esto es como el hombre del tiempo, las posiciones planetarias son perfectamente predecibles y medibles, y uno tiene como una imagen del meteosat, cuando Saturno y PLuton se pongan a 90º vistos desde la tierra, que sera en 2010, esos son los reyes del conflicto... Pero aun habra ams, en 2012 Urano y PLuton - causantes en realidad de lo que estamos viendo ya -, haran los primeros 90º exactos, y ahi sera mas gordo aun, peor Verano de 2010 es un climax de conflictos y crisis economica...

Si quieres ver una prediccion increible, y totalmente comprobable, Barbault, este no es un alucinado, y por posiciones, no por musas, ya comento en 1955 que la Guerra Fria terminaria en 1988-1989, y en 1973 afino mas y comento - muy conocido, tiene libros, revistas, de todo, hasta documentales le han hecho en Francia - y comento que el final de la Guerra Fria seria probablemente entre Septiembre y Noviembre de 1989, el muro cayo el 9 de Noviembre de 1989:

http://www.andrebarbault.com/histoire_prevision_esp.htm

Pero bueno, ya te he dado tabarrra suficiente jeje... Gracias por lo del timeline, ya decia yo que no encontraba como, y asi no pierdo tiempo en buscar, se maneja de otra forma si se crea todo con actionscript, ok, me ayuda muhco el saber que por ahi no busque...!!!

Piensa tambien - te veo buen programador, yo es que ya tengo casi 50 años y se nota, ya uno va perdiendo eficiencia -, pero piensa tambien en hacer templates como los de template monster, personalizables via un exe de VB, es mas sencillo que lo que estas haciendo, y tiene mucha salida tambien, creo yo... SI alguien compra un template de esos y lo puede personalizar en 2 patadas y subirlo a una web, y se le ofrece - aparte - un buen servicio de hosting, eso seguro que agrada y tene salida, bueno, eso creo jeje...

Si en algo te puedo ser util, dimelo no mas, mi email principal es [email protected] ...

Un saludo!!!

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 11 Dic 2008 06:56 am

orales, 50, a los 50 quiciera seguir desarrollando y creando cosas padres, aunke sea por hobbie o por lo que sea, bueno, no tienes messenger verdad, ok, pues si tienes razón, lo tuyo es mucho mas sencillo de usar y se ve con mucha mejor presentacion, porque un template tiene diseño ya incluido, entonces uno no tendria que ser nisiquiera diseñador, solamente tendria que tener buen gusto,

, en mi sistema, las cosas se crean con templates, pero estos son muy sencillos, a lo mejor luego contrato algunos diseñadoraes para que me hagan templates mas padres, porque los mios difieren mucho de los de monster. Estamos en contacto.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 12 Dic 2008 04:30 am

Bueno, te paso el programa:

www.astrodreams.com/downloadflashfilters.htm

Y por mensaje privado te envio el codigo!!!

Ya probe tu codigo, va fenomeno!!!

Cualquier cosa ya sabes!!!

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Citar

Escrito el 12 Dic 2008 05:13 am

Gracias amigo, nos vemos pronto.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino

Envíale un mensaje privado Web

En un lugar, re moto.

@Maximo_O

Citar

Escrito el 20 Dic 2008 07:18 am

Bueno, repuesto y mejorado, daba un error si no se tenia Flash CS3, ahora funciona en FLash 8, CS3 y CS4, en WIndows XP y Vista, Chequeado:

How work the Software:
www.astrodreams.com/flashfilterpresets/convert_flash_filters_presets_to_actionscript.jpg

The Software:
www.astrodreams.com/flashfilterpresets/convert_flash_filters_presets_to_actionscript117release.rar

He intentado ponerlo en www.FLashDen.net , pero no els gustan los exe, pero es imposible acceder al disco duro en FLash, no hay otra forma para convertir los filter presets salvados que mediante un exe...

Saludos LongeVie!!! Y todo el que pase por aqui...

Por Javier Reinoso

52 de clabLevel

Envíale un mensaje privado Email

Como obtener automaticamente el codigo de un filtro realizad

Escribe una respuesta rapida