Duda al guardar imagen en el servidor

Hola, estoy desarrollando una aplicación en la que los usuarios puedan hacer un dibujo en flash y luego este dibujo se guarda en un servidor. Todo funciona bien, excepto que en el script para guardar la imagen al sevidor hay un navigateToURL que cuando guarda la imagen me abre una ventana con la url de la imagen y si comento esa linea no salta la ventana pero no guarda la imagen en servidor ¿Como podría evitar que saltase esa ventana, pero que la imagen se guarde en el servidor? este es el script que utilizo:

Código ActionScript :

private function saveHandler(e:MouseEvent):void
      {
         canvas.overlay = null;
         //creamos un Bitmap del lienzo
         var canvasBmp:BitmapData = new BitmapData(521,213);
         canvasBmp.draw(canvas);

         var myEncoder:JPGEncoder = new JPGEncoder(100);
         var byteArray:ByteArray = myEncoder.encode(canvasBmp);

         canvasBmp.dispose();

         _fileRef = new FileReference();
         _fileRef.save(byteArray, "dibujo.jpg");
         var header:URLRequestHeader = new URLRequestHeader("Content-type","application/octet-stream");
         var myDate:Date = new Date();
         var timeNow:Number = myDate.getTime();
         timeNow.toString();
         var saveJPG:URLRequest = new URLRequest("savejpg.php?nombre=images/dibujo_"+myDate+".jpg");
         saveJPG.requestHeaders.push(header);
         saveJPG.method = URLRequestMethod.POST;
         saveJPG.data = byteArray;
         //****************************************
         navigateToURL(saveJPG, "_blank");
         //****************************************
      }

y este es el php:

Código PHP :

<?php
if (isset($GLOBALS["HTTP_RAW_POST_DATA"]))
{
   // get bytearray
   $jpg = $GLOBALS["HTTP_RAW_POST_DATA"];

   // add headers for download dialog-box
   header('Content-Type: image/jpeg');
   $nombreArchivo = $_GET['nombre'];
   $manejadorArchivo = fopen($nombreArchivo, 'w') or die("No se pudo escribir archivo");
   fwrite($manejadorArchivo,$jpg);
   fclose($manejadorArchivo);
}
?>

gracias!!

No uses navigateToURL, usa algo así:

Código ActionScript :

var saveJPG:URLRequest = new   URLRequest("savejpg.php?nombre=images/dibujo_"+myDate+".jpg"); 
         saveJPG.requestHeaders.push(header); 
         saveJPG.method = URLRequestMethod.POST
         saveJPG.data = data 
         var loader:URLLoader = new URLLoader()
         loader.dataFormat = URLLoaderDataFormat.BINARY                  loader.addEventListener(Event.COMPLETE, dataOnLoad)
                loader.load(saveJPG)

Lo hice medio de memoria, puede que de algún error, pero esa es la idea

Jorge

Gracias Jorge, he puesto el código que me has dicho y le he cambiado algunas cosas para que no me diese errores y a quedado así:

Código ActionScript :

var saveJPG:URLRequest = new URLRequest("savejpg.php?nombre=images/dibujo_" + myDate + ".jpg");
         saveJPG.requestHeaders.push(header);
         saveJPG.method = URLRequestMethod.POST;
         saveJPG.data = byteArray;

         var urlLoader:URLLoader = new URLLoader();
         urlLoader.addEventListener(Event.COMPLETE, sendComplete);
         urlLoader.load(saveJPG);

pero sigue sin subir la imagen al servidor

Quiza sendToURL te sirva. Supongo que el ejemplo te guiara un poco.

Tienes que quitar el header del PHP y asegurarte que PHP tiene derechos de escritura sobre la carpeta a la que quieras copiarlo

Jorge

Eso ya lo había echo, pero aún así no sube la imagen.

Pon la URL donde lo estás haciendo y le echo un ojo

Jorge

http://www.pixeld.es/pruebas/dibujo/

Muchas gracias!

Sale un Security Sandbox Violation al abrirse la ventana de guardar ... ¿Estás usando algún elemento o script de otro dominio?

Jorge

utilize las herramientas de dibujo ,lo guarde y lo acabo de abrir !! oo
muy buena aplicacion..eventualmente tendre q hacer algo asi ..descargar un documento al pc del servidor

=)

solisarg escribió:

einnn? pues que yo sepa no, esta es una aplicación que se llama graffiti drawing app y la estoy modificando para que se suban los dibujos al servidor. Así que no se si hay algun script que provoque ese SSV. Que es lo que causa que aparezca ese SSV. Quiero decir, si antes guardaba las imágenes, porque ahora no las guarda si solo he añadido/cambiado un trozo de script?

Gracias.

Al final lo he conseguido, usando sendToURL como dijo Acreonte, la imagen se guarda perfectamente sin abrir otra ventana. Pero con sendToURL no obtengo respuesta del servidor en caso de fallo o exito en la carga, así que he probado con URLRequest:

Código ActionScript :

private function anadirHandler(e:MouseEvent):void
      {
         var canvasBmp:BitmapData = new BitmapData(606,516);
         canvasBmp.draw(canvas);
         var myEncoder:JPGEncoder = new JPGEncoder(100);
         var byteArray:ByteArray = myEncoder.encode(canvasBmp);

         canvasBmp.dispose();
         var header:URLRequestHeader = new URLRequestHeader("Content-type","application/octet-stream");

         var myDate:Date = new Date  ;
         var timeNow:Number = myDate.getTime();
         timeNow.toString();
            /* esto funciona pero no obtengo respuesta de exito/fallo en la carga.
         var saveJPG:URLRequest = new URLRequest("savejpg.php?nombre=images/dibujo_" + myDate + ".jpg");
         saveJPG.requestHeaders.push(header);
         saveJPG.method = URLRequestMethod.POST;
         saveJPG.data = byteArray;
         sendToURL(saveJPG);
         */
            var request:URLRequest = new URLRequest("savejpg.php?nombre=images/dibujo_" + myDate + ".jpg");
         request.data = byteArray;
         request.method = URLRequestMethod.POST;
         var loader:URLLoader = new URLLoader();
         loader.dataFormat = URLLoaderDataFormat.VARIABLES;
         try
         {
            loader.load(request);
            trace("Su imagen ha sido guardada");
            showSaveMessage(msg);
         }
         catch (e:Error)
         {
             mensaje_mc.texto_txt.text = "Error al guardar su dibujo";
         }
      }

Pero utilizando URLRequest vuelve el fallo de antes:

escribió:

¿porque me sale el error con URLRequest si con sendToURL se guarda perfectamente?

¿El swf y el PHP que guarda el dibujo están en el mismo dominio?

Jorge

Si, eso es lo extraño!!

El draw también tiene restricciones de dominio, si por ejemplo cargas una imagen de otro dominio y le quieres hacer un bitmap.draw te da error de seguridad ... ¿no hay ninguna imagen que quieras dibujar que esté en otro dominio?

Jorge

Pues tengo todos los archivos en la misma carpeta del sevidor, excepto en la que guardo los dibujos que esta en una carpeta dentro de esa misma carpeta. Me resulta extraño que sea por el draw, porque cuando lo hacia con sendToURL(); se guardaba y no daba ese error...

Alguien sabe por que pasa esto?

Al final lo he conseguido.

Gracias a todos!

Y cual era el problema?

Jorge

Creo que era el script que estaba utilizando. Al final lo que utilicé fue URLRequest para enviar los datos y URLLoader para recibir la respuesta del servidor:

Código ActionScript :

//********************************
//guardar imagen en servidor
//************************************
//Url del archivo PHP que va a codificar la imagen
var url:String = "http://www.midominio.com/guardar.php"
var codificador:PNGEncoder;

guardar_btn.addEventListener(MouseEvent.CLICK,serverHandler);
function serverHandler(e:MouseEvent):void
{
        mensaje_mc.visible = true;
   mensaje_mc.texto_txt.text = "Codificando imagen para su envio...";
   //Creo los contenedores para enviar datos y recibir respuesta
   var enviar:URLRequest = new URLRequest(url);
   var recibir:URLLoader = new URLLoader();

   var bmd:BitmapData = new BitmapData(700,500);
    bmd.draw(canvas);
   //Creo la variable que va a ir dentro de enviar, con los campos que tiene que recibir el PHP.
   var variables:URLVariables = new URLVariables();
   //Creo el campo imgen, pasando primero el bitmap a un bytearray, y después codificandolo a Base64
   variables.imagen = Base64.encodeByteArray(PNGEncoder.encode(bmd));
   //Indico el método por el que se va a enviar la información.
   enviar.method = URLRequestMethod.POST;
   enviar.data = variables;

   //Añado listeners a recibir, para un posible error y una respuesta.
   recibir.addEventListener(Event.COMPLETE,Respuesta);
   recibir.addEventListener(IOErrorEvent.IO_ERROR,HayError);
   recibir.load(enviar);
   mensaje_mc.texto_txt.text = "Esperando conversión del archivo...";
   //al recibir una respuesta del PHP
   function Respuesta(event:Event){
         trace(event.target.data);
           mensaje_mc.texto_txt.text = ("Tu imagen se ha guardado");
   }
   //cuando no se puede cargar el PHP
   function HayError(event:IOErrorEvent):void {
          mensaje_mc.texto_txt.text = ("Error al cargar el dibujo");
   }
}

Y así funcionó.

Gracias por vuestra ayuda!!