OK, no es molestia
te explico aqui la funcion con pseudocodigo y comentarios
Código ActionScript :
/*clip es un MovieClip, como sabras, cada MovieClip, tiene un papa, osea, un MovieClip padre
que es quien los contiene, y el super papa de todos se llama "_root", si habias escuchado hablar de el no?
bueno, entonces clip tiene hermanos; sus hermanos, son hijos de su papa, obvio; en el caso que tu
planteas, un Señor, que llamaremos "scope", tiene (maxim_camps) de hijos, cada hijo lo ha nombrado
"missatge" mas el momento en que nacio, osea, el cuarto hijo se llama "missatge4" y el treintavo hijo
se llama "missatge30" y asi sucesivamente, bueno, cada hijo tiene una maldicion, que si lo tocan, se
mueren sus hermanos, osea, se mueren todos los hijos de su papa(scope) excepto el que ha sido tocado,
su papa tambien tiene otros hijos con otras esposas, tiene otros hijos llamados "logo", "header", "clip_usado"
pero, a esos hijos no les afecta la maldicion. la madicion se llama "eliminartodos_menos" y recibe como
parametro, el hijo que fue tocado, hijo que no morira a causa de la maldicion. Como te explique
todos lo hijos que deben morir por la maldicion tienen un nombre que incia con las 8 letras "missatge", los que
no cumplan con esa regla, no moriran a causa de la maldicion.
*/
//FUNCION Elimina_a_todos_menos( (a este)MovieClip )
function eliminartodos_menos( clip:MovieClip ):Void
{
//clip es el hijo maldito
// (scope) es igual a (el PAPA de el hijo maldito )
var scope:MovieClip = clip._parent;
// POR CADA (hijo) PERTENECIENTE A (scope)
for( var i:String in scope )
{
// SI (ese hijo de scope) ES DIFERENTE DE (el hijo maldito) Y (el nombre) ES IGUAL A (missatge)
if( scope[i] != clip && i.substr(0,8) == "missatge" )
{
//Debe morir, muajajaja
// (ese hijo de scope) ES REMOVIDO
scope[i].removeMovieClip();
}
}
}
Ahora veamos el nacimiento de los chamacos
Código ActionScript :
//Es señor scope estaba muy activo esa noche
for (j=0; j<=maxim_camps; j++) {
//Aqui this, se refiere a el PAPA de todos "los hermanos missatge"
attachMovie("missatge","missatge"+j,this.getNextHighestDepth(),{_x:310, _y:((j+1)*35)});
this["missatge"+j].de_usuari_missatge_txt.text = de_usuari_array[j];
this["missatge"+j].titol_missatge_txt.text = titol_array[j];
this["missatge"+j].estat_missatge_txt.text = estat_array[j];
this["missatge"+j].data_hora_missatge_txt.text = data_array[j];
//Aqui es donde los hijos de this(el señor scope de la otra funcion), adquieren la maldicion
//(este hijo de scope) CUANDO ES TOCADO ENTONCES...
this["missatge"+j].onPress = function() {
//todos mis hermanos mueren menos yo, soy tan infeliz.
/*OJO, aqui this se refere a otro enfoque, onPress es una funcion dentro de un hijo missatge
si dentro de esta funcion usamos this, this se refiere al dueño de la funcion, osea el hijo missatge,
NO al papa, el señor scope.*/
//Ejecutamos la funcion "eliminartodos_menos" la cual se encuentra en el nivel de mi padre, y me toma
//a mi como su parametro, pues soy "el unico hermano missatge" que no debe morir.
this._parent.eliminartodos_menos(this);
};
}
me he divertido. Suerte.
no te voy a tomar por tontito, pero las "funciones" son conceptos basicos, mi funcion elminatodos_menos(clip), elimina todos los clips, menos el clip pasado como parametro, no hay mas ciencia, si eso ya lo sabias, entonces tu problema es con el operador de acceso "this" de ese si puedes encontrar mucho en clab, lo explican muy bien, usa el buscador. 