Error AS3 Acceso a una propiedad TweenLite no definida!!!

Hola me sale el siguiente erro al compilar un tutorial que estoy intentando hacer, si lo ejecuto si modificar el .fla funciona si lo intento ejecutar dentro del programa con control+enter me da error: 1120 Acceso a una propiedad TweenLite no definida, yo he seguido todos los pasos del tutorial, os pego el codigo.
Gracias!!.

Código ActionScript :

package
{
   import gs.*;
   import gs.easing.*;
   import flash.display.*;
   import flash.events.*;
   
   public class PhotoPanelsFINISHED extends MovieClip
   {
      private var inFocus:MovieClip;
      
      public function PhotoPanelsFINISHED():void
      {
         setupClips();
         addEventListener(Event.ENTER_FRAME, loop);
      }
      
      private function setupClips():void
      {
         var len:int = con.numChildren;
         
         for(var i:int=0; i<len; i++)
         {
            var mc:MovieClip = MovieClip(con.getChildAt(i));
            mc.buttonMode = true;
            mc.loc = [mc.x, mc.y];
            mc.addEventListener(MouseEvent.ROLL_OVER, onOver);
            mc.addEventListener(MouseEvent.ROLL_OUT, onOut);
            mc.addEventListener(MouseEvent.CLICK, onClick);
         }
      }
      
      private function onOver(e:MouseEvent):void
      {
         var mc:MovieClip = MovieClip(e.currentTarget);
         if(mc != inFocus)
            TweenLite.to(mc.enlarge, 0.2, {
                           alpha:1
                      });
      }
      
      private function onOut(e:MouseEvent):void
      {
         var mc:MovieClip = MovieClip(e.currentTarget);
         if(mc != inFocus)
            TweenLite.to(mc.enlarge, 0.2, {
                           alpha:0
                      });
      }
      
      private function onClick(e:MouseEvent):void
      {
         var mc:MovieClip = MovieClip(e.currentTarget);
         
         if(inFocus == null)
         {
            scaleUp(mc);
         }
         
         else if(inFocus == mc)
         {
            TweenLite.to(inFocus, 0.5, {
                         scaleX:1,
                        scaleY:1,
                        x:inFocus.loc[0],
                        y:inFocus.loc[1],
                        ease:Expo.easeInOut,
                        onComplete:function(){inFocus=null;}
                   });
         }
         
         else
         {
            TweenLite.to(inFocus, 0.5, {
                         scaleX:1,
                        scaleY:1,
                        x:inFocus.loc[0],
                        y:inFocus.loc[1],
                        ease:Expo.easeInOut,
                        onComplete:scaleUp,
                        onCompleteParams:[mc]
                   });
         }
      }
      
      private function scaleUp(mc:MovieClip):void
      {
         inFocus = mc;
         con.addChild(mc);
         mc.enlarge.alpha = 0;
         TweenLite.to(mc, 0.5, {
                         scaleX:3,
                        scaleY:3,
                        x:0,
                        y:0,
                        ease:Expo.easeInOut
                   });
      }
      
      private function loop(e:Event):void
      {
         var distx:Number = mouseX / 650;
         var disty:Number = mouseY / 450;
         TweenLite.to(con, 2, {
                         rotationY:(-70 + (140*distx)),
                        rotationX:(70 - (140*disty)),
                        ease:Expo.easeOut
                   });
      }
   }
}

Mira que tengas estas carpetas:

import gs.*;
import gs.easing.*;

En la primera carpeta (gs por GreenShock) tienes que tener TweenLite

Jorge

No tengo ninguna carpeta, lo que hay es un archivo .as que contiene ese codigo y dentro del flash hace referencia a ese archivo llamando a la clase.
Por favor espero un ayudita!!! gracias

Bájate Tweenlite de http://www.greensock.com/tweenlite/

Jorge

Muchas gracias, ya me he bajado de la pagina la carpeta greensock as3, me viene varias carpetas y archivos, lo importante supongo que es el archivo compilado swc greensock, y despues la carpeta com, dentro hay otra carpeta com/greensock, y dentro esta tweenlite, con varios archivos mas en .as y varios carpetas mas, como iria la ubicacion de mi proyecyo .fla para que me rule, eske ahora lo pongo y me dice que el nombre del paquete com.greensock no contiene la ubicacion del archivo y es un error en la linea 1 de archivo TwenLite.as

Código ActionScript :

/**
 * VERSION: 11.35
 * DATE: 2010-04-21
 * AS3 (AS2 version is also available)
 * UPDATES AND DOCUMENTATION AT: http://www.TweenLite.com
 **/
package com.greensock {
   import com.greensock.core.*;
   import com.greensock.plugins.*;
   
   import flash.display.*;
   import flash.events.*;
   import flash.utils.*;

la ubicacion de mi proyecto .fla esta en la misma carpeta que tweenlite, nose muy bien como se importan los archivos, es la primera vez que lo hago y estoy siendo bastante torpe, sorry, bueno muchas gracias por tu tiempo, saludos.

Busca la carpeta gs y ponla justo debajo de tu fla, así estas dos líneas pueden funcionar

import gs.*;
import gs.easing.*;

Jorge

Muchas gracias, por tu ayuda jorge, te debo una jejejeje.