Escalar imagen con diagramación liquida

Hola, estoy intentando hacer un sitio flash con diagranacion liquida, he adelantado bastante pero tengo un inconveniente, estoy utilizando una imagen de fondo y si bien ya puedo redimensionarla al tamaño del alto y ancho del navegador, cuando la ventana del mismo no se mueve de forma proporcional tanto en el eje x como el eje y, la imagen de fondo se distorciona, esto se debe a que la programacion que estoy usando esta hecha para que el MovieClip (la imagen) se adapte tanto al ancho como alto del escenario, supongo que lo que debo hacer es que este MovieClip se escale proporcionalmete según se acomode la ventana del navegador... no se como hacerlo o por lo cual pido ayuda.

De antemao gracias!!

Acá dejó un link de ejemplo para que se entienda lo que quiero que suceda con mi página:
http://www.us-paris.com/

y las lieas que estoy usando...

Código ActionScript :

import flash.display.StageScaleMode;
import flash.display.StageAlign;
import flash.events.Event;

stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

stage.addEventListener (Event.RESIZE, redimencionar);

fs2_btn.addEventListener(MouseEvent.CLICK, completaEscalando);

function completaEscalando(event:MouseEvent):void {
   stage.scaleMode =StageScaleMode.SHOW_ALL;
   stage.displayState=StageDisplayState.FULL_SCREEN;
}

redimencionar (null);


function redimencionar(event:Event):void {
   var sw:Number = stage.stageWidth;
     var sh:Number = stage.stageHeight;
   My_Clip.width = sw
   My_Clip.height = sh;
}

Pero eso supone que el usuario escala el browser proporcionalmente ... ¿que pasa si lo achata por ejemplo?

Jorge

al achatar el navegador la imagen se achata, se deforma.

gracias!!

Ya, ¿pero que es lo que quieres que pase?

Jorge

quiero que mi imagen no se deforme al mover el navegador, ya que con el codigo que tengo se esta deformando

Te propongo una solución para reescalar tu imagen.

En este caso, lo que vas a evitar es "deformarla" generando un reencuadre de la misma.
Aquí te dejo la función (puede mejorarse, pero es una idea).

Código ActionScript :

function escalarImagen(clip) { 
         var img_prop:Number; 
         if (stage.stageHeight/stage.stageWidth>clip.height/clip.width) { 
            img_prop      = clip.width/clip.height; 
            clip.height      = stage.stageHeight; 
            clip.width      = stage.stageHeight*img_prop; 
            clip.y          = (clip.height - stage.stageHeight)/-2; 
         } else { 
            img_prop      = clip.height/clip.width; 
            clip.width      = stage.stageWidth; 
            clip.height      = stage.stageWidth*img_prop; 
            clip.y          = (clip.height - stage.stageHeight)/-2; 
         } 
         clip.x             = -(clip.width - stage.stageWidth) / 2; 
      }

Saludos.
Leo.

Muchisimas gracias Leo!! es justo lo que deseaba, funciona muy bien!! fue muy emocionante compilar y ver que el clip se comportó como yo quería.

Saludos!!!

Andrés.