Etiquetas para puntero del mouse...

Quizás esto sea fácil o no lo se... como la mayoría soy novato... quisiera saber si hay una forma para que cuando pase el puntero del mouse sobre una objeto de instancia de pelicula o boton en Flash, quisiera que saliera una pequeña etiqueta a un lado del puntero del mouse, como un "helper" con una palabra que ayude al usuario a identificar el objeto, como esos sistemas comerciales que aparece un pequeño rectangulo amarillo y dentro de el una o dos palabras en fuente muy pequeña para indicar de que se trata el botón o el objeto seleccionado cuando solo estos tienen un simbolo o dibujo sin más información...

Espero haber sido claro y gracias...

mm lo que se me ocurre es que hagas esto:
1)crea un texto estatico..luego apreta f8 y lo convertis en mc y pones antes de aceptar...avanzado ....
y donde dice exportar para actionscrpit ponbes que si y le pones como nombre de vinculacion mensaje...luego aceptas y lo dejas en la biblioteca....y lo sacas del escenario
2)en el escenario creas un boton y le pones de nombre de instancia = boton
3)pones en el primer fotograma este codigo:

Código ActionScript :

//al pasar el mouse sobre el boton se crea un mc vacio que contendra el mensaje
boton.onRollOver=function(){
   _root.createEmptyMovieClip("contenedor", this.getNextHighestDepth);
   contenedor.attachMovie("mensaje", "mensaje_mc", 2);
//le damos las coordenadas que van a hacer iguales a las del boton pero un poco mas
   contenedor._x=boton._x+30;
   contenedor._y=boton._y+20;
}
//al sacar el mosue del boton se irá el mensaje
boton.onRollOut=function(){
   removeMovieClip(contenedor);
}

saludos

Eso que deseas hacer se llama tooltip

Un código muy viejo que utilicé para un proyecto pero de seguro te servirá, lo mejor es hacer una clase, pero eso te lo dejaría para estudio propio. en el primer frame de tu película sitúa este código:

Código ActionScript :

import flash.geom.ColorTransform;
import flash.geom.Transform;

//-------------------------------------------Funcion de los tooltips 
function createToolTip(texto:String):Void {

   //---Estilo del tooltip 
   var toolTipStyle:TextFormat = new TextFormat();
   toolTipStyle.font = "Arial";
   toolTipStyle.bold = true;
   toolTipStyle.size = 10;
   toolTipStyle.color = 0x000000;

   var tooltip:MovieClip = _root.createEmptyMovieClip("tooltip", _root.getNextHighestDepth());

   tooltip.createEmptyMovieClip("fondo",1);
   tooltip.createTextField("texto",2,0,0,0,0);

   //---Texto 
   with (tooltip.texto) {
      autoSize = true;
      selectable = false;
      text = texto;
      setTextFormat(toolTipStyle);
      sharpness = -200;
   }
   var ancho:Number = tooltip._width;
   var alto:Number = tooltip._height;

   //---Fondo 
   with (tooltip.fondo) {

      beginFill(0xFFFFCC,100);
      moveTo(-2,-1);
      lineTo(ancho + 2,-1);
      lineTo(ancho + 2,alto + 1);
      lineTo(-2,alto + 1);
      endFill();

   }
   //---Sombra 
   var colorTrans:ColorTransform = new ColorTransform();
   colorTrans.rgb = 0x000000;

   var sombra:MovieClip = tooltip.fondo.duplicateMovieClip("sombra", 0, {_x:2, _y:2});

   var trans:Transform = new Transform(sombra);
   trans.colorTransform = colorTrans;

   sombra._alpha = 50;

   tooltip._x = _root._xmouse + 15;
   tooltip._y = _root._ymouse + 10;


   tooltip.onMouseMove = function():Void  {
      this._x = _root._xmouse + 15;
      this._y = _root._ymouse + 10;
      updateAfterEvent();
   };
}

//-------------------------------------------Funcion de borrar los tooltips 
function removeToolTip():Void {
   _root.tooltip.removeMovieClip();
}

cuando quieras que al pasar por encima de un MovieClip aparezca un tooltip y que al salir desaparezca, utiliza lo siguiente:

Suponiendo que en la escena hay un MovieClip con nombre de instancia "boton"

Código ActionScript :

boton.onRollOver = function():Void{ 
    
   createToolTip("Esto es una prueba"); 
    
} 
 
boton.onRollOut = function():Void{ 
    
   removeToolTip(); 
    
}