fototeca con actionscript

mi duda es como cambiar la direccion o la ruta de las imagenes de manera que se puedan abrir en otro equipo sin internet y sin tener que subir mis archivos a una pagina y pues esta fototeca se ve muy bien y me gustaria poder editar el codigo pero no encuentro la forma de hacer que abra mis archivos desde la carpeda en donde se encuentra el archivo flash .fla suponiendo que se encuentre en /mis documentos como le hago para que abra las imagenes de /mis documentos/nombre de la imagen.jpg
es con actionscript
ayuda porfavor

Código ActionScript :

_global.SW = Stage.width;
_global.SH = Stage.height;
_global.SWsur2 = SW / 2;
_global.SHsur2 = SH / 2;
Stage.scaleMode = "exactFit";
//----------------------------------------------
MovieClip.prototype.rectangle_arrondi_ombre = function(larg, haut, rayon, epais, couleur, transp) {
   var mc = this.createEmptyMovieClip("rectangle_arrondi", 10000);
   mc.onLoad = function() {
      with (this) {
         for (var i = 6; i > 0; i -= .5) {
            lineStyle(2 * i, 0x000000, 40 - i * 6);
            moveTo(larg + i, rayon * .7 + 5 * i);
            lineTo(larg + i, haut - rayon + 2 * i);
            curveTo(larg, haut, larg - rayon + 2 * i, haut + i);
            lineTo(rayon * .7 + 5 * i, haut + i);
         }
         moveTo(rayon, 0);
         //-------------------
         lineStyle(epais, 0x000000, 100);
         beginFill(couleur, transp);
         moveTo(rayon, 0);
         lineTo(larg - rayon, 0);
         curveTo(larg, 0, larg, rayon);
         lineTo(larg, haut - rayon);
         curveTo(larg, haut, larg - rayon, haut);
         lineTo(rayon, haut);
         curveTo(0, haut, 0, haut - rayon);
         lineTo(0, rayon);
         curveTo(0, 0, rayon, 0);
         endFill();
      }
   };
   mc.onLoad();
};
//----------------------------------------------
_root.createEmptyMovieClip("cadre", -1111);
cadre._x = 2;
cadre._y = 2;
cadre.rectangle_arrondi_ombre(SW - 4, SH - 4, SW / 20, 2, 0x996633, 10);
//----------------------------------------------
MovieClip.prototype.chargement_jpg = function(jpg, couleur, larg, haut) {
   var cible = this.dest;
   cible._alpha = 0;
   cible.loadMovie(jpg);
   var id = setInterval(function (mc) {
      var d = mc["dest"];
      if (d._width > 0) {
         clearInterval(id);
         d.memw = d._width;
         d.memh = d._height;
         d.proportion = (d._width / d._height);
         d._width = Math.floor(mc._w0 * 2);
         d._height = Math.floor(mc._h0 * 2);
         d._alpha = 99;
         with (d) {
            lineStyle(4, 0x444444, 80);
            moveTo(this._x + memw + 1, this._y - 1);
            lineTo(this._x + memw + 1, this._y + memh + 1);
            lineTo(this._x - 1, this._y + memh + 1);
            lineStyle(4, 0xaaaaaa, 80);
            lineTo(this._x - 1, this._y - 1);
            lineTo(this._x + memw + 1, this._y - 1);
         }
         // --------------------
         mc._alpha = 99;
         mc._width = mc._w0;
         mc._height = mc._h0 * 1.5;
         mc.onPress = cliquer;
         // mc.onRelease = relacher;
         // mc.onReleaseOutside = relacher;
         //--------------------
      } else {
         var pourcent = (d.getBytesLoaded() / d.getBytesTotal());
         mc._width = pourcent * mc._w0;
         mc._height = pourcent * mc._h0 * 1.6;
      }
   }, 100, this);
};
// -----------------------------------------------------
MovieClip.prototype.cliquer = function() {
   _global.memoire.swapDepths(0);
   _global.memoire.relacher();
   if (_global.memoire != this) {
      _global.memoire = this;
      //---------------------
      delete this.onEnterFrame;
      //---------------------
      var grossissement_V = SH * .9;
      var grossissement_H = grossissement_V * this.dest.proportion;
      var positiont_V = SHsur2 * 1.1;
      //---------------------
      this._alpha = 99;
      this.swapDepths(_root.niveau++);
      //---------------------
      var x_deb = this._x;
      var y_deb = this._y;
      var dis_x = (SWsur2 - x_deb) / 2;
      var dis_y = (positiont_V - y_deb) / 2;
      var vitesse = Math.PI / 20;
      var angle = -Math.PI;
      var limite = -Math.PI / 3.3;
      var decalage = Math.PI / 6;
      //------------------------------------
      this.onEnterFrame = function() {
         angle += vitesse;
         s = 1 + Math.cos(angle - Math.sin(angle - decalage));
         this._x = x_deb + s * dis_x;
         this._y = y_deb + s * dis_y;
         this._width += (grossissement_H - this._width) / 5;
         this._height += (grossissement_V - this._height) / 3;
         //---------------------
         if (angle >= limite) {
            this._width = grossissement_H;
            this._height = grossissement_V;
            delete this.onEnterFrame;
         }
      };
   }
};
// -----------------------------------------------------
MovieClip.prototype.relacher = function() {
   delete this.onEnterFrame;
   this.onEnterFrame = function() {
      this._width += (this._w0 - this._width) / 4;
      this._height += (this._h0 - this._height) / 4;
      this._x += (this._x0 - this._x) / 4;
      this._y += (this._y0 - this._y) / 4;
      if (this._yscale < 70) {
         this._width = this._w0;
         this._height = this._h0 * 1.5;
         this._x = this._x0;
         this._y = this._y0;
         this._alpha = 50;
         delete this.onEnterFrame;
      }
   };
};
// -----------------------------------------------------
MovieClip.prototype.allons_y = function(tableau) {
   var L = SW / (tableau.length + 2);
   L = Math.floor(L * .9);
   var M = L + 5;
   for (var i = 0; i < tableau.length; i++) {
      clip = _root.createEmptyMovieClip("cadre" + i, i);
      clip.onLoad = function() {
         //--------------------
         this._alpha = 30;
         this.lineStyle(4, 0, 20);
         this.moveTo(-(L + 2), L);
         this.lineTo(M, L);
         this.lineTo(M, -(L - 3));
         // --------------------
         this.moveTo(M, -L);
         this.lineStyle(0, 0x999999);
         this.beginFill(0xfff6f0, 100);
         this.lineTo(-M, -L);
         this.lineTo(-M, L);
         this.lineStyle(0, 0);
         this.lineTo(M, L);
         this.lineTo(M, -L);
         this.endFill();
         //--------------------
         this._x0 = (1.2 * (i + 1)) * L;
         this._y0 = L;
         this._x = this._x0;
         this._y = this._y0;
         //--------------------
         this._w0 = L + 3;
         this._h0 = L - 5 + 3;
         this._width = this._w0;
         this._height = this._h0;
         //--------------------
         this.createEmptyMovieClip("dest", i + 200);
         //--------------------
         this.dest.onLoad = function() {
            this._x = -L - 3;
            this._y = -L + 2;
            var ladress = tableau[i] + "?" + random(99999);
            var ladress = tableau[i];
            this._parent.chargement_jpg(ladress, 0xff8800, 20, 50);
         };
         this.dest.onLoad();
      };
      clip.onLoad();
   }
};
//------------------------------------------------------
niveau = 10000;
//------------------------------------------------------
_global.fichier = [];
_global.repertoire = "http://is.freefoto.com/images/";
//------------------------------------------------------
fichier[0] = "1351/01/1351_01_6_web.jpg";
fichier[1] = "1351/02/1351_02_54_web.jpg";
fichier[2] = "1351/03/1351_03_18_web.jpg";
fichier[3] = "1351/04/1351_04_60_web.jpg";
fichier[4] = "1351/04/1351_04_89_web.jpg";
fichier[5] = "1351/05/1351_05_51_web.jpg";
fichier[6] = "1351/16/1351_16_61_web.jpg";
fichier[7] = "1351/16/1351_16_6_web.jpg";
fichier[8] = "1351/16/1351_16_58_web.jpg";
fichier[9] = "1351/07/1351_07_1_web.jpg";
fichier[10] = "1351/07/1351_07_61_web.jpg";
fichier[11] = "1351/07/1351_07_58_web.jpg";
fichier[12] = "1351/06/1351_06_86_web.jpg";
fichier[13] = "1351/16/1351_16_1_web.jpg";
fichier[14] = "1351/13/1351_13_1_web.jpg";
fichier[15] = "1351/13/1351_13_6_web.jpg";
fichier[16] = "10/51/10_51_10_web.jpg";
fichier[17] = "10/51/10_51_5_web.jpg";
fichier[18] = "10/51/10_51_12_web.jpg";
fichier[19] = "10/51/10_51_14_web.jpg";
fichier[20] = "10/15/10_15_53_web.jpg";
fichier[21] = "10/15/10_15_54_web.jpg";
fichier[22] = "10/15/10_15_1_web.jpg";
/**/
for (var i = 0; i < fichier.length; i++) {
   fichier[i] = repertoire + fichier[i];
   //trace(fichier[i]);
}
_root.createEmptyMovieClip("phototheque", 0);
phototheque.allons_y(fichier);
//------------------------------------------------------
stop();
//------------------------------------------------------

Mira por ejemplo esta línea

fichier[0] = "1351/01/1351_01_6_web.jpg";

Es la ruta de la primera foto.
Las líneas que le siguen son las rutas de las demás fotos
Cambiala a lo que necesites.

Jorge

pero yo me refiero a cambiar la url y que las fotos esten en mi compudadora sin tener que poner C:\blablabla yo solo quiero que lea los archivos en otro equipo por ejemplo

\fotos\foto1.jpg
y que la trasladar la carpeta con el archivo flash lo siga leyendo bien

otro problema no carga las imagenes cuando lo pongo en html el archivo swf solo si carga todo completo pero ya introducido en HTML no carga imagenes por que????

Esta es la ruta base

_global.repertoire = "http://is.freefoto.com/images/";

Esta es la ruta especifica

fichier[0] = "1351/01/1351_01_6_web.jpg";

Por ejemplo si quisieras que tome de la carpeta images (por debajo del swf no importe donde este) puedes usar

_global.repertoire = "images/";

Y luego el resto de la ruta de cada fichero, Esa es una ruta RELATIVA, quiere decir que no importa donde este el swf, siempre buscará una carpeta images que este por debajo.

Jorge