Galeria con carga dinamica en Flash + scroll bar + links

Hola a todos!!!!
Agrh.. me estoy quebrando la cabeza con esto, la verdad esq no se mucho de flash, he visto muchos tutoriales y aun no encuentro la forma de enlazar estas fotos con su link correspondiente.

Estoy cargando desde un archivo XML de una web q contiene estos datos:

Código :

<?xml version="1.0" encoding="iso-8859-1"?>

<gallery width="880" height="135" y="20" image_width="130" vertical_spacing="10" bar_thickness="10">
   <image nom_xml="http://www.medstrend.com/medstrend/index/flash/00.jpg"   url_xml="http://www.medstrend.com/medstrend/PerfectingElixir.html" />
   <image nom_xml="http://www.medstrend.com/medstrend/index/flash/01.jpg"    url_xml="http://www.medstrend.com/medstrend/EyeGelee.html" />
   <image nom_xml="http://www.medstrend.com/medstrend/index/flash/02.jpg"    url_xml="http://www.medstrend.com/medstrend/EssentialLash.html" />
 ..... etc etc ...

</gallery>

tengo en el código AS2 esto (tengo otras funciones mas como una mascara y un scroll para q una barra, al momento de desplazarce, mueva la pelicula, igual les dejo todo el scrip por si ustedes quieren hacer una galeria similar):

Código :

var xml:String = "http://www.medstrend.com/medstrend/index/flash/galeria.xml"
var myGalleryXML:XML = new XML ();
myGalleryXML.ignoreWhite = true;
myGalleryXML.load(xml);

myGalleryXML.onLoad = function() {

   _root.gallery_width = myGalleryXML.firstChild.attributes.width;
   _root.gallery_height = myGalleryXML.firstChild.attributes.height;
   _root.gallery_y = myGalleryXML.firstChild.attributes.y; 

   _root.spacing = myGalleryXML.firstChild.attributes.vertical_spacing;
   _root.bar_y = Number(_root.gallery_height)+Number(_root.spacing);
   _root.bar_thickness = myGalleryXML.firstChild.attributes.bar_thickness;
   _root.scroller_width = _root.bar_thickness*2

   _root.image_width = myGalleryXML.firstChild.attributes.image_width;

   _root.myImages = myGalleryXML.firstChild.childNodes;
   _root.myImagesTotal = _root.myImages.length; 
   
   crearContenedor ();
   crearImagenes ();
   mascara();
   scrollbar ();
   scroller ();
}

function crearContenedor() {
   _root.myGallery_mc = _root.createEmptyMovieClip("myGallery_mc", _root.getNextHighestDepth());
   _root.myGallery_mc._y = _root.gallery_y;
   _root.myGallery_mc._x = (Stage.width-_root.gallery_width)/2;
function crearImagenes (){
   _root.myImages_mc = _root.myGallery_mc.createEmptyMovieClip("myImages_mc", _root.myGallery_mc.getNextHighestDepth()); 
   var myMCL:MovieClipLoader = new MovieClipLoader();
   for (i=0; i<_root.myImagesTotal; i++) {
      imageNOM = _root.myImages[i].attributes.nom_xml;
      imageWEB = _root.myImages[i].attributes.url_xml;
      image_mc = _root.myImages_mc.createEmptyMovieClip(i, _root.myImages_mc.getNextHighestDepth());
      image_mc._x = _root.image_width*i;

      myMCL.loadClip(imageNOM,image_mc);
      
      myImages_mc.onPress = function (){
         getURL(imageWEB, "_self");
      }
   }
}
function mascara() {
   _root.myMask_mc = _root.myGallery_mc.createEmptyMovieClip("myMask_mc", _root.myGallery_mc.getNextHighestDepth());

   _root.myMask_mc.beginFill(0x000000,100);
   _root.myMask_mc.lineTo(_root.gallery_width,0);
   _root.myMask_mc.lineTo(_root.gallery_width,_root.gallery_height);
   _root.myMask_mc.lineTo(0,_root.gallery_height);
   _root.myMask_mc.lineTo(0,0);
   _root.myMask_mc.endFill();

   _root.myImages_mc.setMask(_root.myMask_mc);
}

function scrollbar () {
   _root.scrollbar_mc = _root.myGallery_mc.createEmptyMovieClip("scrollbar_mc", _root.myGallery_mc.getNextHighestDepth());
   _root.scrollbar_mc._y = _root.bar_y;

   _root.scrollbar_mc.beginFill(0x000000,100);
   _root.scrollbar_mc.lineTo(gallery_width,0);
   _root.scrollbar_mc.lineTo(gallery_width,_root.bar_thickness);
   _root.scrollbar_mc.lineTo(0,_root.bar_thickness);
   _root.scrollbar_mc.lineTo(0,0);
   _root.scrollbar_mc.endFill();
   
   _root.scrollbar_mc.onPress = function(){
      _root.scroller_mc._x = this._xmouse;

      if (_root.scroller_mc._x > (this._width-_root.scroller_mc._width)){
         _root.scroller_mc._x = this._width-_root.scroller_mc._width;
      }

   mover();
   }

}

function scroller () {
_root.scroller_mc = _root.myGallery_mc.createEmptyMovieClip("scroller_mc", _root.myGallery_mc.getNextHighestDepth());
_root.scroller_mc._y = _root.bar_y;

_root.scroller_mc.beginFill(0x999999,100);
_root.scroller_mc.lineTo(200,0);
_root.scroller_mc.lineTo(200,_root.bar_thickness);
_root.scroller_mc.lineTo(0,_root.bar_thickness);
_root.scroller_mc.lineTo(0,0);
_root.scroller_mc.endFill();

_root.scroller_mc.onPress = function(){
startDrag(this, false, 0, this._y, _root.scrollbar_mc._width-this._width, this._y);
moverInterval = setInterval(mover,250);
};

_root.scroller_mc.onRelease = function(){
stopDrag();
clearInterval(moverInterval);
mover()
};

}

function mover(){
   var scrollerLocation = _root.scroller_mc._x/(_root.scrollbar_mc._width-_root.scroller_mc._width);
   var galleryLocation = scrollerLocation*(_root.myMask_mc._width-_root.myImages_mc._width);

   new Tween (_root.myImages_mc, "_x", Strong.easeOut, _root.myImages_mc._x, galleryLocation, 1.5, true);
}

este es todo mi scrip, mi problema es este:

function crearImagenes (){
_root.myImages_mc = _root.myGallery_mc.createEmptyMovieClip("myImages_mc", _root.myGallery_mc.getNextHighestDepth());
var myMCL:MovieClipLoader = new MovieClipLoader();
for (i=0; i<_root.myImagesTotal; i++) {
imageNOM = _root.myImages[i].attributes.nom_xml;
imageWEB = _root.myImages[i].attributes.url_xml;
image_mc = _root.myImages_mc.createEmptyMovieClip(i, _root.myImages_mc.getNextHighestDepth());
image_mc._x = _root.image_width*i;

myMCL.loadClip(imageNOM,image_mc);

myImages_mc.onPress = function (){
getURL(imageWEB, "_self");
//aki no se enlazan las imagenes al link q le corresponde
}
}
}

Me podrian ayudar???? Gracias!!!

hola, mira prueba esto:

Código ActionScript :

function crearImagenes (){
     _root.myImages_mc = _root.myGallery_mc.createEmptyMovieClip("myImages_mc", _root.myGallery_mc.getNextHighestDepth());
     for (i=0; i<_root.myImagesTotal; i++) {
          imageNOM = _root.myImages[i].attributes.nom_xml;
          image_mc = _root.myImages_mc.createEmptyMovieClip("clip"+i, _root.myImages_mc.getNextHighestDepth());
          image_mc.imageWEB = _root.myImages[i].attributes.url_xml;
          image_mc._x = _root.image_width*i;
          var myMCL:MovieClipLoader = new MovieClipLoader();
          myMCL.loadClip(imageNOM,image_mc);
          image_mc.onPress = function (){
               getURL(this.imageWEB, "_self");
          }
     }
}

Mhh, ya lo intenté con tu propuesta pero no me funcionó.

Lo que pasa es que, al darle click a mi imagen, si me abre una pagina y me abre un url, pero me manda siempre al ultimo url de mi lista en XML, sea cual sea la imagen a la que le de click, ¿saben porque?

NOTA: Se me olvidó agregar dos renglones q van hasta el principio del script, y son estos:

import mx.transitions.Tween;
import mx.transitions.easing.*;

Por si les interesa

hola, si se enlazan al ultimo es porque la variable imageWEB, cambia constantemente:

Código ActionScript :

imageWEB = _root.myImages[i].attributes.url_xml;

al final del for, imageWEB tendra el ultimo valor, entiendes? entonces, tu pones el evento onPress para el clip que contiene todas las imagenes "myImages_mc" lo cual me parece una ambigüedad de tu parte, no crees?

Código ActionScript :

myImages_mc.onPress = function (){
    getURL(imageWEB, "_self");
}

siempre va a ir a imageWEB la cual tiene el ultimo valor del for, por eso yo asigno a una varialbe interna:

Código ActionScript :

image_mc.imageWEB = _root.myImages[i].attributes.url_xml;

y hago onpress para cada "image_mc", NO al "myImages_mc"

Código ActionScript :

image_mc.onPress = function (){ 
        getURL(this.imageWEB, "_self"); 
}

Espero que hayas entendido el razonamiento, tu problema esta ahi, en tus asignaciones, si no te resulta, postea de nuevo el codigo que tienes, que al presionar envia a la ultima imagen, y asegurate de ponerlo entre las etiquetas [code], para que sea mas entendible. Suerte

Ok .... me di por vencida y cambie totalmente mi estrategia, y me funcionó bien hasta q le quise poner un scrollbar, jaja, soy novata en flash, disculpenme. He aqui mi codigo en XML:

Código :

<gallery>
   <foto nom_xml="00.jpg"    url_xml="http://www.cristalab.html" />
   <foto nom_xml="01.jpg"    url_xml="http://www.cristalab.html" />
   <foto nom_xml="02.jpg"    url_xml="http://www.cristalab.html" />
   <foto nom_xml="03.jpg"    url_xml="http://www.cristalab.html" />
   </gallery>

Ahora en Flash hice esto:
- hice un movieclip al que llame thumb_total (de 125 X 135) y dentro de el otro movieclip que llame thumb_mc. En el thumb_total se muestran las imágenes, y en el thumb_mc se enlazan los links (que era el problema que tenia en mi codigo anterior, no sabia como enlazarlos. El caso es q me funciona bastante bien los enlaces y se ven las imagenes, mi problema es q ya no se como hacerle un scrollbar para q se muevan las imágenes de izq-der y der-izq...

Este de aca es mi codigo flash

Código :

var xml:XML = new XML ();
xml.ignoreWhite = true;
xml.load("lista.xml");
thumb_total._visible = false;

var dirX:Number = 0;
var dirY:Number = 0;
var mcs:MovieClip;
var thumbloader:MovieClipLoader = new MovieClipLoader;
var thumb:MovieClip;

xml.onLoad = function() {
   
   numFotos = xml.firstChild.childNodes;
   numFotosTotal = numFotos.length;
   
   crearImagenes ();
}

function crearImagenes(){

   for(i=0; i<numFotosTotal; i++){
      Duplicar ();
      imageNOM = numFotos[i].attributes.nom_xml;
      mcs.url_flash = numFotos[i].attributes.url_xml;
      
      thumb = mcs.createEmptyMovieClip("n", this.getNextHighestDepth());
      thumbloader.loadClip(imageNOM, thumb);

      mcs.thumb_mc.onPress = function (){ 
         getURL(this._parent.url_flash); 
      }
   }
}

function Duplicar (){
   mcs = thumb_total.duplicateMovieClip("mc"+i, i);
   mcs._x = 140*dirX + 10;
   mcs._y = 100*dirY + 10;
   dirX++;

}

Me podrian asesorar?
Ahora como le pongo un scrollbar?

Hola, la verdad es que si, tu codigo se ve muy desordenado, pero no te preocupes, lo vamos a ordenar y aparte voy a hacer el scroll, este nuevo codigo que desarrolle no duplica movieclips, por tanto tienes que borrar el objeto thumb_total que tenias, pues este codigo lo crea todo con AS sin necesidad de tener nada en el escenario o en la biblioteca. Bueno aqui van las explicaciones:

MiniTutorial de como crear una galeria via XML con ScrollBar

por mi.

Definir variables inciales

Código ActionScript :

var lista_xml:XML = new XML();
lista_xml.ignoreWhite = true;
var cargador_mcl:MovieClipLoader = new MovieClipLoader();
cargador_mcl.addListener(this);
var img_w:Number = 125;//Ancho de las imagenes
var img_h:Number = 135;//Alto de las imagenes
var img_n:Number = 3;//Numero de imagenes que se mostraran
var img_s:Number = 10;//Separacion entre las imagenes
var gal_x:Number = 50;//Posicion en X de la galeria
var gal_y:Number = 100;//Posicion en Y de la galeria

Bueno, creo que todo esta bien claro, pero por si las dudas te explico "img_n", esa variable es el numero de thumbs que se van a mostrar, por ejemplo si tienes 10 thumbs, img_n determinaria que solo se muestren 3 y con el scroll se puedan mostrar las otras 7, img_n en combinacion con img_w determinan el tamaño de la galeria, cuando hagas pruebas cambia el valor de img_n para que veas que sucede.

Crear la galeria

Código ActionScript :

var galeria:MovieClip = this.createEmptyMovieClip("galeria", 120);
galeria.createEmptyMovieClip("miniaturas", 0);
galeria.createEmptyMovieClip("mascara", 1);
galeria.mascara.beginFill(0,0);
galeria.mascara.moveTo(0,0);
galeria.mascara.lineTo((this.img_w + this.img_s) * this.img_n, 0);
galeria.mascara.lineTo((this.img_w + this.img_s) * this.img_n, this.img_h);
galeria.mascara.lineTo(0, this.img_h);
galeria.mascara.endFill();
galeria.miniaturas.setMask( galeria.mascara );
galeria._x = this.gal_x;
galeria._y = this.gal_y;

Simplemente se crean los movieclips que contendran la galeria y la mascara, "beginFill" "lineTo" son funciones de la api de dibujo de los movieclips con las cuales creo un cuadrado en las mascara del tamaño justo para que solo se vean el numero de imagenes indicado en las variables inciales.

Crear ScrollBar

Código ActionScript :

var slider:MovieClip = galeria.createEmptyMovieClip("slider", 2);
slider.beginFill(0xFFCC33,100);
slider.moveTo(0,0);
slider.lineTo(this.img_w/2, 0);
slider.lineTo(this.img_w/2, 20);
slider.lineTo(0, 20);
slider.endFill();
slider._y = this.img_h + 5;
slider.onPress = function( Void )
{
   this.startDrag(false,0,this._y,this._parent.mascara._width - this._width, this._y);
}
slider.onRelease = function( Void )
{
   this.stopDrag();
}
slider.onEnterFrame = function()
{ 
   this._parent.miniaturas._x = this._x / (this._parent.mascara._width - this._width) * (this._parent.miniaturas._width - (this._parent.mascara._width - this._parent._parent.img_s)) * -1;
}

Creo el movieclip que contendra la scrollbar, dibujo un cuadrado que sera la representacion y defino los metodos que arrastraran la scrollbar, en el evento OnEnterFrame, evaluo la posicion de la scrollbar y con unos calculos obtengo la nueva posicion de las imagenes enmascaradas.

Cargar XML

Código ActionScript :

lista_xml.onLoad = function( ok:Boolean ) 
{
   if( ok )//Si se cargo correctamente
   {
      crearImagenes();
   }
   else trace("No se pudo cargar el XML");
}
lista_xml.load("lista.xml");

Simplemente le decimos al objeto XML que debe cargar y agregamos su evento onLoad, el XML debe estar formado de la siguiente manera:

Código XML :

<?xml version="1.0" encoding="UTF-8"?>
<galeria>
   <img nom_xml="IMG/img1.jpg" url_xml="http://www.cristalab.com" />
   <img nom_xml="IMG/img2.jpg" url_xml="http://www.google.com" />
   <img nom_xml="IMG/img3.jpg" url_xml="http://www.w3c.es" />
   <img nom_xml="IMG/img4.jpg" url_xml="http://www.adobe.com" />
</galeria>

En realidad los nombres galeria e img, son depreciables, pueden ser cualquier otro pero elegi esos para que se entienda.

Crear las imagenes

Código ActionScript :

function crearImagenes( Void ):Void
{
   //Variables auxiliares
   var aux:MovieClip;
   var img_aux:String;
   var url_aux:String;
   for( var i:Number = 0, l:Number = lista_xml.firstChild.childNodes.length; i < l; i++)
   {
      aux = this.crearImagen( i );
      url_aux = lista_xml.firstChild.childNodes[i].attributes.url_xml;
      img_aux = lista_xml.firstChild.childNodes[i].attributes.nom_xml;
      //Aqui se indica que al presionar el boton se carge la url
      aux.boton_mc.url = url_aux;
      aux.boton_mc.onRelease = function( Void )
      {
         getURL( this.url ); 
      };
      cargador_mcl.loadClip( img_aux, aux.thumb_mc );
   }
}
function crearImagen( index:Number ):MovieClip
{
   //Clips
   var clip:MovieClip = this.galeria.miniaturas.createEmptyMovieClip("mc_" + index, index);
   clip.createEmptyMovieClip("boton_mc", 1)
   clip.createEmptyMovieClip("thumb_mc", 0)
   
   //Posicion
   clip.index = i;
   clip._x = (this.img_w + this.img_s) * index;
   
   //Fondo transparente del boton
   clip.boton_mc.beginFill(0,0);
   clip.boton_mc.moveTo(0,0);
   clip.boton_mc.lineTo(this.img_w,0);
   clip.boton_mc.lineTo(this.img_w, this.img_h);
   clip.boton_mc.lineTo(0, this.img_h);
   clip.boton_mc.endFill();
   return clip;
}

La primer funcion "crearImagenes", sirve para parsear el objeto XML, asignar valores al boton y cargar las imagenes, ademas de invocar a la segunda funcion "crearImagen" la cual se encarga de crear el movieclip y posicionarlo deacuerdo al indice que se le pasa como parametro, crea el boton y dibuja un cuadrado transparente que es el que sera presionado.

Los eventos del cargador

Código ActionScript :

function onLoadInit( target:MovieClip )
{ 
   target._width = this.img_w; 
   target._height = this.img_h;
}

Pues estos eventos solo se encargan de redimensionar los clips con respecto a las variables inciales.

Eso es todo, me funciona de maravilla, espero que a ti tambien, Suerte.

Aqui el codigo completo

Código ActionScript :

//--Definir variables inciales --//
var lista_xml:XML = new XML();
lista_xml.ignoreWhite = true;
var cargador_mcl:MovieClipLoader = new MovieClipLoader();
cargador_mcl.addListener(this);
var img_w:Number = 125;//Ancho de las imagenes
var img_h:Number = 135;//Alto de las imagenes
var img_n:Number = 3;//Numero de imagenes que se mostraran
var img_s:Number = 10;//Separacion entre las imagenes
var gal_x:Number = 50;//Posicion en X de la galeria
var gal_y:Number = 100;//Posicion en Y de la galeria


//-- Crear la galeria --//
var galeria:MovieClip = this.createEmptyMovieClip("galeria", 120);
galeria.createEmptyMovieClip("miniaturas", 0);
galeria.createEmptyMovieClip("mascara", 1);
galeria.mascara.beginFill(0,0);
galeria.mascara.moveTo(0,0);
galeria.mascara.lineTo((this.img_w + this.img_s) * this.img_n, 0);
galeria.mascara.lineTo((this.img_w + this.img_s) * this.img_n, this.img_h);
galeria.mascara.lineTo(0, this.img_h);
galeria.mascara.endFill();
galeria.miniaturas.setMask( galeria.mascara );
galeria._x = this.gal_x;
galeria._y = this.gal_y;

//-- Crear ScrollBar --//
var slider:MovieClip = galeria.createEmptyMovieClip("slider", 2);
slider.beginFill(0xFFCC33,100);
slider.moveTo(0,0);
slider.lineTo(this.img_w/2, 0);
slider.lineTo(this.img_w/2, 20);
slider.lineTo(0, 20);
slider.endFill();
slider._y = this.img_h + 5;
slider.onPress = function( Void )
{
   this.startDrag(false,0,this._y,this._parent.mascara._width - this._width, this._y);
}
slider.onRelease = function( Void )
{
   this.stopDrag();
}
slider.onEnterFrame = function()
{ 
   this._parent.miniaturas._x = this._x / (this._parent.mascara._width - this._width) * (this._parent.miniaturas._width - (this._parent.mascara._width - this._parent._parent.img_s)) * -1;
}

//-- Carga XML --//
lista_xml.onLoad = function( ok:Boolean ) 
{
   if( ok )//Si se cargo correctamente
   {
      crearImagenes();
   }
   else trace("No se pudo cargar el XML");
}
lista_xml.load("lista.xml");

//-- Crear las imagenes --//
function crearImagenes( Void ):Void
{
   //Variables auxiliares
   var aux:MovieClip;
   var img_aux:String;
   var url_aux:String;
   for( var i:Number = 0, l:Number = lista_xml.firstChild.childNodes.length; i < l; i++)
   {
      aux = this.crearImagen( i );
      url_aux = lista_xml.firstChild.childNodes[i].attributes.url_xml;
      img_aux = lista_xml.firstChild.childNodes[i].attributes.nom_xml;
      //Aqui se indica que al presionar el boton se carge la url
      aux.boton_mc.url = url_aux;
      aux.boton_mc.onRelease = function( Void )
      {
         getURL( this.url ); 
      };
      cargador_mcl.loadClip( img_aux, aux.thumb_mc );
   }
}
function crearImagen( index:Number ):MovieClip
{
   //Clips
   var clip:MovieClip = this.galeria.miniaturas.createEmptyMovieClip("mc_" + index, index);
   clip.createEmptyMovieClip("boton_mc", 1)
   clip.createEmptyMovieClip("thumb_mc", 0)
   
   //Posicion
   clip.index = i;
   clip._x = (this.img_w + this.img_s) * index;
   
   //Fondo transparente del boton
   clip.boton_mc.beginFill(0,0);
   clip.boton_mc.moveTo(0,0);
   clip.boton_mc.lineTo(this.img_w,0);
   clip.boton_mc.lineTo(this.img_w, this.img_h);
   clip.boton_mc.lineTo(0, this.img_h);
   clip.boton_mc.endFill();
   return clip;
}

//-- Eventos del Cargador --//
function onLoadInit( target:MovieClip )
{ 
   target._width = this.img_w; 
   target._height = this.img_h;
}

Suerte.

WOW!!!!! Sensei ...... eres un genio!!!! muchisisisisimas gracias ... no se que seria de nosotros novatos sin masters como ustedes... me funcionó muy bien, fuiste de mucha ayuda Gracias!

please como hago para cambiar el scroll para que scrollee vertical y no horizontal please ayuda!!

¡¡Qué maravilla de tutorial!!

Jajajajaj si quieres yo te paso el ejemplo

Pues sí, estaría genial!! Muchas gracias!!

Mi correo es [email protected]

Tiene no solo todo lo que esta arriba sino también exploración de carpetas de las cuales muestra las fotos....

Hola sforero, ya habia sacado esto: http://foros.cristalab.com/snippet-as2-menu-galeria-miniaturas-xml-scrollbar-t68632/

Pero no he tenido tiempo de mejorarlo y actualizarlo o subirlo como tutorial, cosa que ya se me ha sugerido. Si quieres puedes continuiar el proyecto y lo envias con tu modificacion al webmaster para que lo pongan como tuto o ejemplo, yo que se, o simplemente publica tus mejoras, el chiste es apoyar a la comunidad.

Me cuentas si te animas.

nooo...la verdad no tengo tiempo...lol

hola, alguien k me pueda pasar el ejemplo para descargar, no me sale!!!
me marca errores y no se ve nada en el swf, porfavor !!!

Hola, mira no recuerdo donde quedo ese fla, pero el codigo es de copiar y pegar y lo puedes encontrar en:

http://foros.cristalab.com/snippet-as2-menu-galeria-miniaturas-xml-scrollbar-t68632/#459769

y la estructura de carpetas donde se monto el tutorial es esta:

http://longevie.theninjabunny.com/Galeria_Menu_XML_Scroll/

Leelo, echale ganas y veras que puedes hacer que trabaje, es facil

Ps. En las opciones de publicación revisa que sea ActionScript2 y que no te salgan errores

Saludos,

LongeVie escribió:

Es genial el tuto me podrian ayudar un poco con esto como le hago para que se mueva la galeria con el mouse y aplicarle un efecto de profundidad a la tira de imagenes y muestre de la vista de 3 imagenes la del centro mas grande, espero me puedan ayudar ya que estoy tratando de resolver esto pero no me sale, es algfo parecido a esta galeria

http://www.morgandetoi.com/mode_feminine/silhouettes.cfm

gracias.

Que tal, eso se llama menú Dock, podrías iniciar por aquí.

Saludos,

Gracias por tu respuesta pero lo que necesito es algo asi pero en galeria con imagenes normales no miniaturay que la galeria avance de derecha a izquierda pero la imagen del centro siempre este ampliada, espero me puedas ayudar ya que este tema lo tengo hace varios dias y me urge, gracias