getPixel de imagen externa.

Hola a todos.. tengo la siguiente duda: Me gustaría saber si existe la forma cargar una imagen en un contenedor con loadMovie(); y a esta imagen aplicarle las funciones del getPixel?
• Tengo este código pero solo funciona con una imagen en attach... y yo quiero que haga lo mismo pero con una galería de fotos externas.

Código :

import flash.display.BitmapData;
//------------------------------------------------
color_select = this.createEmptyMovieClip("color_select", 1);
img = BitmapData.loadBitmap("imagen");
color_select.attachBitmap(img,0);
color_select.onRollOver = function() {
   this.onMouseMove = function() {
      color_mc._x = _xmouse;
      color_mc._y = _ymouse;
      color_mc.swapDepths(2);
      colorget = img.getPixel(_xmouse, _ymouse);
      updateAfterEvent();
      //
      var color_in:Color = new Color(color_mc);
      color_in.setRGB(colorget);
   };
   color_mc._visible = true;
};
color_select.onRollOut = function() {
   delete this.onMouseMove;
   color_mc._visible = false;
};
color_select.useHandCursor = false;

Saludos!!!!

Si no te funciona en AS2,
Creo que con AS3 si funciona.

Y cuales serían las líneas para cargar las imagenes?.... que no sea desde attach.

Tendrias que cambiar todo el codigo, ya que AS3 es muy diferente a AS2, pero si no sabes AS3, te recomiendo que lo vayas estudiando.

Jejeje... muchas gracias gabyufe... de verdad he estado mirando AS3 pero me parece más para programadores y AS2 me gusta porque tiene ese enfoque a Diseñadores.

• Igual me gustaría saberlo para AS2...
Saludos!!!

El código AS2 sería este:

Código :

import flash.display.BitmapData;
//------------------------------------------------
color_select = this.createEmptyMovieClip("A", this.getNextHighestDepth());
miListener =new Object();;
cargador = new MovieClipLoader();
cargador.addListener(miListener);
color_select.onRollOver = function() {
   this.onMouseMove = function() {
      color_mc._x = _xmouse;
      color_mc._y = _ymouse;
      color_mc.swapDepths(2);
      colorget = img.getPixel(_xmouse, _ymouse);
      updateAfterEvent();
      //
      var color_in:Color = new Color(color_mc);
      color_in.setRGB(colorget);
   };
   color_mc._visible = true;
};
color_select.onRollOut = function() {
   delete this.onMouseMove;
   color_mc._visible = false;
};
color_select.useHandCursor = false;

/*
cada vez que se dé la siguiente orden en cualquier evento
cargará la imagen de la URL: rutadeimagen (en este ejemplo
 es "unaimagen.jpg" supuestamente en el mismo directorio que el SWF )                                      
*/
cargador.loadClip("unaimagen.jpg", color_select);

Taseo.... sigue sin funcionar.
ya le he intentado desde muchas partes pero por más que lo intento siempre me imprime la variable colorget como undefined. Pienso que en algún lugar del código debo hacer referencia al contenedor pero.... undefined por todos lados. hice unos cambios con la variable img porque ya no la usas, entons pensé que podía ser por ese lado. .... pero undefined. jeje.

Muchas gracias por la atención.
Saludos!!!

Cosas de las 3 de la mañana, sorry.
Se me escaparon lineas al escribir.....

Código :

import flash.display.BitmapData;
//------------------------------------------------
color_select = this.createEmptyMovieClip("A", this.getNextHighestDepth());
miListener =new Object();;
cargador = new MovieClipLoader();
cargador.addListener(miListener);
miListener.onLoadInit = function(color_select){
img=new BitmapData(color_select._width,color_select._height,true,0);
img.draw(color_select);
color_select.onRollOver = function() {
   this.onMouseMove = function() {
      color_mc._x = _xmouse;
      color_mc._y = _ymouse;
      color_mc.swapDepths(2);
      colorget = img.getPixel(_xmouse, _ymouse);
         trace(colorget);
      updateAfterEvent();
      //
      var color_in:Color = new Color(color_mc);
      color_in.setRGB(colorget);
   };
   color_mc._visible = true;
};
color_select.onRollOut = function() {
   delete this.onMouseMove;
   color_mc._visible = false;
};
color_select.useHandCursor = false;
}
/*
cada vez que se dé la siguiente orden en cualquier evento
cargará la imagen de la URL: rutadeimagen (en este ejemplo
 es "unaimagen.jpg" supuestamente en el mismo directorio que el SWF )                                      
*/
cargador.loadClip("unaimagen.jpg", color_select);

Perfecto!!!!!
Muchas gracias Teseo. de verdad sirve mucho ese código!!!!

yo odiaba AS3 con toda mi vida. Un dia ya no aguante mas me puse a estudiar el tema. Lo domine en 5 horas. Parece complicado pero la verdad es que termina siendo mucho mas simple que AS2