Me sale error cuándo intento ejecutar este ejemplo.

Ejemplo

Compile y ejecute el siguiente archivo. Cuando ejecute el archivo, arrastre el ratón para seleccionar texto en cada uno de los dos campos de texto y observe la diferencia del resaltado de la selección cuando seleccione el texto de los dos campos de texto (cambiando la selección):

Código :

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_alwaysShowSelection extends Sprite {
        public function TextField_alwaysShowSelection() {
            var label1:TextField = createTextField(0, 20, 200, 20);
            label1.text = "This text is selected.";
            label1.setSelection(0, 9);
            label1.alwaysShowSelection = true;

            var label2:TextField = createTextField(0, 50, 200, 20);
            label2.text = "Drag to select some of this text.";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x; result.y = y;
            result.width = width; result.height = height;
            addChild(result);
            return result;
        }
    }
}

Fuí a archivo NUEVO -> ACTIONSCRIPT 3.0

En el primer fotograma -> Acciones ... y coloque el ejemplo, pero me sale este error:
"Escena 1, Capa 'Capa 1', Fotograma 1, Línea 1 1037:Los paquetes no se pueden anidar."


Espero sus respuestas muchas gracias

Las clases no se ponen en la linea de tiempo, se ponen un archivo .as con el mismo nombre de la clase. Para poder verlo en el escenario, hay que instanciarlo y agregarlo al displayList, por ejemplo en el primer fotograma

addChild(new TextField_alwaysShowSelection())

Jorge