pausar un sonido mp3 externo

ola amigos de cristalab, hace poco escribi un post de como manejar el volumen de un mp3 externo y wao valla que lo sucionaron eh aqui .

El prblema ahora es q mi codigo lo que hace es reproducir y deterner el archivo yu ahora loq ue nesecito es que en ves de uqe se detenga se pause, que al darle play de nuevo empiece desde la pausa....

ALGUIEN ME AYUDA!!!

guardas la posicion en una variable y luego incias play desde esa posicion:

Código ActionScript :

var tiempo:Number.

function puasar( Void ):Void
{
  tiempo = sonido.position;
  sonido.stop();
}
function reproducir( Void ):Void
{
  sonido.start(tiempo);
}

suerte.

ola maigo me genera erron en la linea

function puasar( Void ):Void

dice "despues de : se espera un identifidor de tipo...

jeje q pasa???

Código ActionScript :

//var tiempo:Number. 
var tiempo:Number;

ola amigo de nuevo yo, se que a veces la solucion esta hay pero quizas no la veo...lo que tengo es lo siguiente:

en el boton play:

Código :

on (press){
var misonido:Sound = new Sound();
misonido.loadSound("elsonido.mp3", true);
}

en el boton stop

Código :

on(release){
misonido.stop();
}

hasta hay todo wao...

la verdad amigo no se como aplicar tu codigo....

Código :

var tiempo:Number;
function puasar( Void ):Void 
{ 
tiempo = misonido.position; 
misonido.stop(); 
} 
function reproducir( Void ):Void 
{ 
  misonido.start(tiempo); 
} 

a un boton pause, intente por mis medios de poder hacerlo pero no soy mu chulo con AS.

como aplico ese codigo a un boton pause_btn..
Gracias por tu colaboracion de antemano....

Hola, supongamos que tienes 3 MovieClips que funcionan como botones, se llaman "play_btn", "pause_btn", "stop_btn".

Ahora, no debes poner nada sobre el boton, osea, nada dentro de "on(release)", todo va en el fotograma.

Código ActionScript :

var pausa:Number = 0;
var misonido = new Sound();
misonido.attachSound("Sonido");
misonido.loadSound("elsonido.mp3", true);
stop_sound();

function stop_sound( Void ):Void
{
    pausa = 0;
    misonido.stop();
}
function pause_sound( Void ):Void
{
    pausa = misonido.position;
    misonido.stop();    
}
function start_sound( Void ):Void
{
    misonido.start(pausa/1000);
}

play_btn.onRelease = function ( Void ):Void
{
    start_sound();
}
pause_btn.onRelease = function ( Void ):Void
{
    pause_sound();
}
stop_btn.onRelease = function ( Void ):Void
{
    stop_sound();
}

Suerte.

oye amigo lo he probado y me ha funcionado de maravilla muchisimas gracias por aclarame la duda, eres muy buena onda, mucha suerte amigo

gracias, oie mira tambien esto, es para hacer una barra de posicion del sonido, igual te sirve.

http://foros.cristalab.com/como-hacere-so-t69067/#459405

Si tienes dudas, no dudes en preguntar. Saludos.

ola amigo eh visto tu tuto y sabes es lo que nesecito no me atrevia a preguntarlo ps me parece muy complejo pero la verdad recuerdas que no soy muy chulo para AS2 como aplicari ese codigo a al que tu mismo me has dado amigo que me carge la barra referente al sonido que especifica el codigo que tu me diste..

gracias amigo eres super jejeje

Hola, mmm, bueno, dejame hacer pruebas y regreso con el codigo final ya con los botones y la barra incorporados. peroo, los botones seran mus sencillos, me refiero a que solo tendran los simbolos de play pause y stop. luego ya vemos como meterles ams diseño.

si amigo ya lo logre eh aqui el link de lo echo con tus ideas que bien amigo [url=http://www.arlesvanegas.org/index/palabradefe_b.html][/url] ...gracias amigo je je

perfecto, bueno, de todas formas intentare hacer algo similar.

ola long vie aqui te monto el codigo que use para q ps lo acomedes (esta echo un desorde) y lo postees sera muy util... he aqui

Código :

this.createEmptyMovieClip("barra_mc", 0); 
barra_mc._x = 22; 
barra_mc._y = 140; 
barra_mc.max = 10000; 
barra_mc.createEmptyMovieClip("bound_mc", 0); 
barra_mc.createEmptyMovieClip("color_mc", 1); 
setArea(barra_mc.bound_mc, 235, 20, 0x0099cc, 20); 
setArea(barra_mc.color_mc, 235, 20, 0x0099cc, 100); 
 
barra_mc.bound_mc.onRelease = function( Void ):Void 
{ 
   sonido.stop(); 
   sonido.start(Math.floor(this._xmouse * this._parent.max / this._width)/1000); 
}; 
barra_mc.setPosition = function( position:Number ):Void 
{ 
   setArea( this.color_mc, position / this.max * this.bound_mc._width ,20, 0x0099cc, 100 ); 
}; 
 
var sonido:Sound = new Sound(); 
sonido.attachSound("Sonido");
sonido.loadSound( "7 no es un numero,es una actitud.mp3" , true ); 
stop_sound();
sonido.onLoad = function(success:Boolean) { 
   if (success) { 
      iniciar(); 
   } 
}; 
 
function iniciar( Void ):Void 
{ 
   this.barra_mc.max = sonido.duration; 
   this.barra_mc.onEnterFrame = function() 
   { 
      this.setPosition( sonido.position ); 
   }; 
} 
 
function setArea( clip:MovieClip, w:Number, h:Number, color:Number, alpha:Number ):Void  
{  
   //Dibujamos un cuadrado  
   clip.clear();  
   clip.beginFill( color?color:0, alpha?alpha:0 );  
   clip.moveTo( 0, 0 );  
   clip.lineTo( w, 0 );  
   clip.lineTo( w, h );  
   clip.lineTo( 0, h );  
   clip.endFill();     
}  
function stop_sound( Void ):Void 
{ 
    pausa = 0; 
    sonido.stop(); 
} 
function pause_sound( Void ):Void 
{ 
    pausa = sonido.position; 
    sonido.stop();     
} 
function start_sound( Void ):Void 
{ 
    sonido.start(pausa/1000); 
} 
 
play_btn.onRelease = function ( Void ):Void 
{ 
    start_sound(); 
} 
pause_btn.onRelease = function ( Void ):Void 
{ 
    pause_sound(); 
} 
stop_btn.onRelease = function ( Void ):Void 
{ 
    stop_sound(); 
} 

acomodalo que se vea bonito si puedes y lo posteas de nuevo jejejejejej y gracias de nuevo hermano.