Problema con capturas de textos (cadenas capturadas incompletas)

Hola a todos,
Estoy teniendo problemillas con la captura de texto en un TextField de tipo INPUT.
Como voy a utilizar varios cuadros de entrada de texto, por no configurar cada uno de manera individual, me he creado la siguiente clase

Código ActionScript :

public class EntradaTexto extends Sprite {
   
   private var cajaTexto : TextField;
   private var _texto : String;
   
   public function EntradaTexto() {
      
      var formato : TextFormat = new TextFormat();
      formato.font = "Arial";
      formato.size = 12;
      formato.color = 0x000000;
      formato.align = TextFormatAlign.CENTER;
      
      cajaTexto = new TextField();
      cajaTexto.type = TextFieldType.INPUT;
      cajaTexto.defaultTextFormat = formato;
      cajaTexto.width = 100;
      cajaTexto.height = 100;
      cajaTexto.multiline = false;
      cajaTexto.border = true;
      cajaTexto.background = true;
      cajaTexto.backgroundColor = 0xFFFFFF;
      cajaTexto.addEventListener(TextEvent.TEXT_INPUT, capturaTexto);
      
      addChild(cajaTexto);
      
   }
   
   public function get texto():String {
      return _texto;
   }
   
   public function set texto(value:String):void {
      _texto = value;
      cajaTexto.text = _texto;
   }
   
   public function mostrarComoContrasena() : void {
      cajaTexto.displayAsPassword = true;
   }
   
   private function capturaTexto(e:TextEvent) : void {
      var str : String = cajaTexto.text;
      _texto = str;
   }
   
}

Esta clase, posteriormente la utilizo de la siguiente manera:

Código ActionScript :

var entradaTextoNombre : EntradaTexto = new EntradaTexto();
entradaTextoNombre.x = etiquetaNombre.x + etiquetaNombre.width + 20;
entradaTextoNombre.y = etiquetaNombre.y;
instancias.push(entradaTextoNombre);
addChild(entradaTextoNombre);
entradaTextoNombre.addEventListener(TextEvent.TEXT_INPUT, capturaEntradaTextoNombre);

y la función del evento es la siguiente:

Código ActionScript :

private function capturaEntradaTextoNombre(e:TextEvent) : void {
   trace(entradaTextoNombre.texto);
}

El problema que estoy teniendo, es que si en ese cuadro de texto escribo la palabra Hola, el trace me muestra Hol.
De hecho, al escribir la letra H, el trace pinta espacio en blanco, al continuar con la o, el trace me pinta H, al escribir l, el trace me muestra Ho, y al escribir la a , el trace me muestra Hol.
Es decir, que para que me capture la pantalla Hola, tendría que añadir una letra más.
¿Podéis ayudarme con esto por favor? No sé qué más intentar.

Muchísimas gracias

Tienes un setter/getter de una propiedad que no se actualiza. Cambia el getter por esto

Código ActionScript :

 public function get texto():String {
      return cajaTexto.text;
   }

Jorge

Mil gracias!! Funciona perfectamente