punto quieto arrastra otro y crea linea

hola a todos haber si me puedo explicar tengo un mc bollita que esta quieta en el escenario, lo que quiero es que haya otro mc bolita1 encima y que sea arrastrable y cuando yo la arrastre cree una linea recta, esto dentro de mi escena se duplica muchas veces es decir va a haber mas mc bolita2,3,4 etc, y cada una debe ser arrastrable creando lineas rectas que parten hacia diferentes lugares, el problema es que no se como manejar el crear una linea al arrastrar, y como eliminar el grafico cuando cambies a otro frame

tratando de resolver esto, cree un clip de pelicula que tuviera un circulo y una linea y le puse movimiento, para crear el efecto de la linea arrastrable junto con el circulo, pero al colocarlo en mi escena no jala, es decir si funciona la accion de arrastrar y soltar pero no se ve el movimiento del clip...
alguien podra ayudarme?

Bueno, ya tienes dos post con un tema parecido a este, y creo que nadamas no das con la solucion, te envie un mp, Suerte.

si lo se pero lo que pasa es que intente con el concepto anterior y no funciono porque no es la unica accion que tengo en esa escena por lo tanto complica mucho la funcion en si asi que pense en solucionarlo de esta manera

Hola, aqui publico los resultados de esta colaboracion, una clase que se debe asociar con un Movieclip, que puede dibujar lineas rectas con mantener presionado el mouse, ademas de poder borrar la ultima linea recta dibujada, Suerte.

Código ActionScript :

class DibujaMovieClip extends MovieClip
{
   var figura_mc:MovieClip;
   
   var dibujar_mc:MovieClip;
   var initX_num:Number;
   var initY_num:Number;
   var count_nmb:Number;
   
   public function cargar( linkage:String ):Void
   {
      this.figura_mc = this.attachMovie(linkage, "figura_mc", 0);      
   }
   
   private function dibujar( Void ):Void
   {
      this.dibujar_mc.clear();
      this.dibujar_mc.lineStyle(1,0x0000FF);
      this.dibujar_mc.moveTo( this.initX_num, this.initY_num );
      var auxx:Number = Math.max( Math.min( this.dibujar_mc._xmouse, this.figura_mc._width - 2 ), 2 );
      var auxy:Number = Math.max( Math.min( this.dibujar_mc._ymouse, this.figura_mc._height - 2 ), 2 );
      this.dibujar_mc.lineTo( auxx, auxy );
   }
   
   public function borrar( Void ):Void
   {
      if(   this["eje" + (this.count_nmb)] != undefined )
      {
         this["eje" + (this.count_nmb)].removeMovieClip();
         this.count_nmb--;
      }
   }
   
   private function onPress( Void ):Void
   {
      this.count_nmb = ( this.count_nmb == undefined )? 1 : this.count_nmb + 1 ;
      this.dibujar_mc = this.createEmptyMovieClip("eje" + this.count_nmb, this.count_nmb);
      this.initX_num = this.dibujar_mc._xmouse;
      this.initY_num = this.dibujar_mc._ymouse;
      this.dibujar();
   }
   
   private function onRelease( Void ):Void
   {
      this.dibujar_mc = undefined;
   }
   private function onReleaseOutside( Void ):Void
   {
      this.dibujar_mc = undefined;
   }   
   private function onEnterFrame( Void ):Void
   {
      if( this.dibujar_mc != undefined )
      {
         this.dibujar();
      }
   }   
}