Saltar aplicando leyes fisicas (videojuego)

Buenas, no logro que en mi videojuego el personaje salte de manera correcta, he mirado tutoriales y no acabo de verlo claro, lo unico que quiero es que haga cuando se presione una tecla determinada, el personaje se desplaze hacia arriba (hasta cierta altura) y después baje a la posición inicial. (Por supuesto tiene que tener interactividad con las teclas de dirección izquierda y derecha pero eso es sencillo)

Muchas gracias por la ayuda

Locke

Eso depende de cuan realista quieres que sea la física. Por ejemplo puedes usar composición de fuerzas sobre el eje x e y, o resolverla usando vectores ...

Jorge

Bueno mi intención solo es que cuando presiono la tecla de saltar se mueva hacia arriba y después hacia abajo, he mirado algún tutorial y utiliza variables como gravedad, aceleración, etc, pero no acabo de encontrarle la lógica. Probé haciendo que cuando llegara a una altura determinada iniciara el descenso pero sin ningún resultado, la verdad es que no entiendo que falla.

Pues de ese tipo de tutoriales estoy hablando. Hacer una física veroscímil tiene esa dificultad, si sigue intentando con alguna animación

Jorge

Bueno, ya sé que la finalidad del foro es que la gente aprenda, y que no debería postear el código, pero ya que me he liado y lo he escrito aquí te lo dejo.
Una forma sencilla de hacerlo es usando 2 variables, velocidad y aceleración:

Código ActionScript :

var velocidad:int   = 0;
var aceleracion:int   = 2;

var estaSaltando:Boolean = false;
var moviendoIzquierda:Boolea = false;
var moviendoDerecha:Boolean = false;

this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
this.stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDownHandler);
this.stage.addEventListener(KeyboardEvent.KEY_UP, keyUpHandler);

function enterFrameHandler(event:Event):void
{
   if (moviendoIzquierda == true) personaje.x -= 8;
   if (moviendoDerecha == true) personaje.x += 8;
   
   personaje.y += velocidad;
   if (personaje.y < stage.stageHeight)
   {
      velocidad += aceleracion;
   }
   else
   {
      personaje.y = stage.stageHeight;
      velocidad = 0;
      estaSaltando = false;
   }
}

function keyDownHandler(event:KeyboardEvent):void
{
   if (event.keyCode == Keyboard.LEFT) moviendoIzquierda = true;
   if (event.keyCode == Keyboard.RIGHT) moviendoDerecha = true;
   
   if (estaSaltando == true) return;
   if (event.keyCode == Keyboard.UP)
   {
      velocidad = -20;
      estaSaltando = true;
   }
}

function keyUpHandler(event:KeyboardEvent):void
{
   if (event.keyCode == Keyboard.LEFT) moviendoIzquierda = false;
   if (event.keyCode == Keyboard.RIGHT) moviendoDerecha = false;
}