carga de datos de un txt con action3

ok, no entendi bien lo que querias hacer, has creado un cargador en un archivo as sta putamadre me lo podrias explicar un poco, ya que no me acaba de funcionar, un saludo, gracias y feliz año nuevo.

El problema es que como ya me dijeron en otros foros as3 no es lenguaje de bajo nivel, y mi problema se solucionaria si pudiera pasar un string en variable sin poner el nombre de la variable el problema se me solucionaria bastante de hecho en php esto mismo me ocupa 20 lineas. Ahora en vez de 360 variables solo utilizo 8, ademas los 360 campos dinamicos necesito que sean equidistantes con las letras entre si que van capturando, si pudiera hacer de otra manera o si quedase bien de otra manera simplemente utilizaria solo una variable en solo un campo de texto y no tendria que poner tal cantidad de lineas, de todas maneras estas en lo cierto que con el loop esto se hace mucho mas facil. De todas maneras creo todavia que siendo as3 superior a as2 esto se puede hacer mucho mas facil lo de hacer de el nombre de una variable un variable es decir de dos string de dos variables hacer una variable nueva solo con los strings de las dos variables viejas es decir con getChildByName y con una idea que me has dado de lo del loop. Dame un ejemplo simple de lo del loop a ver como aplico esa idea y me salgo de este tema ke ya no tiene nada que ver lo que se esta hablando aqui con el titulo del tema.

primero no use ningun archivo .as , prueba el codigo del otro post y debe de funcionar , ahora lo de la variables no te entiendo muy bien, pero getChildByName , se usa para identificar u obtener displayObjects que tengan la propiedad name. Ahora lo del loop te comento el codigo para que te sirva de guia.

Código ActionScript :

//esta funcion recibe como parametro un array que contiene las variables deserializadas
function makeTextField (pData:Array):void
{
   /*en tu codigo tu tienes 360 campos de texto p1,p2,p3..., ahora me guie a que en tu codigo
   cada 45 campos  cambia de variable str2..45 campos mas..str3. entonces se me ocurrio hacer dos loop
   ya que el pData es un array tiene un lenght de 8 esto debido al numero de variables eso multiplicado por 45
   son los 360 campos de texto*/
   
   var len:int = pData.length;
   var spacing:int = 5;

   //en este vector guadare los 360 campos de texto
   vecTexts = new Vector.<TextField>();
   //este es el campo de texto
   var displayText:TextField;


   for (var i:int=0; i<len; ++i)
   {
      for (var j:int=0; j<45; ++j)
      {
         /*en tu codigo tenias algo como substring(0,1),(1,2)... para eso me axuilie de la variable n y de
         la del contador j*/
         var n:int = 1 + j;
         //creo una nueva instancia del campo de texto
         displayText = new TextField();
         //le doy unas propiedades: width,height,borde..etc
         displayText.width = displayText.height = 20;
         /*ahora cada ves que entre el loop genero un campo de texto , su propiedad text sera el index i del array
         que contiene las variables, es decir para el index 0 que es la primer variable str , se haran 45 campos
         de texto, en el subtring recibira lo que tu tenias en tu codigo,  (j,n) genera (0,1),(1,2,),(2,3)..etc*/
         displayText.text = pData[i].substring(j,n);
         displayText.border = true;
         //por ultimo para que no se vieran amontonados los campos en el escenario lo acomode a modo de rows y cols
         displayText.x = spacing + (displayText.width + spacing) * j;
         displayText.y = spacing + (displayText.height + spacing) * i;
         //agrego el campo de texto al escenario
         addChild (displayText);
         /*cada texto que se genera , lo introdusco el vector, asi si tengo que hacer alguna comparacion
         me bastaria con hacer otro loop y los condicionantes, y me ahorro tiempo y esfuerzo*/
         vecTexts.push (displayText);
      }
   }
}

si estudias el code ya no tuve que usar el nombre de la variable para cada campo de texto p1.text = data.str0..etc, eso quedo obsoleto , ahora mediante el loop se lleva acabo, saludos y suerte.

Jonathan