variables "dinamicas" y onPress

hola

Tengo un problema que me esta desesperando hasta niveles desconocidos
la idea es que tengo 3 botones generados dinamicamente por medio de un for (con attachMovie)
Para las funciones de OnRollOver y onRollOut no hay el minimo problema, pero cuando trato de aplicar el mismo concepto en onPress es cuando de plano hace lo que le viene en gana

en si, la parte de los botones seria esta:

Código ActionScript :

for(i=0;i<3;i++){
_root["btn"+(i+1)].onRollOver = function () {
...
}

_root["btn"+(i+1)].onRollOut = function () {
...
}

_root["btn"+(i+1)].onPress = function () {
   trace(_root.arrTrace[i]);
}
}

el problema es que el trace siempre me manda el ultimo valor del arreglo (arrTrace) y no valores consecuentes como debiera

hize un experimento en un proyecto nuevo con solo este codigo y va perfecto, pero al momento de mezclarlo con mi proyecto actual hace lo mismo (pone el ultimo valor al presionar el boton)

Código ActionScript :

for(i=0;i<3;i++){
   this["test"+i] = "hola"+i
}
for(i=0;i<3;i++){
   temp = eval("test"+i);
   trace(temp);
}

ojala alguien entienda mi duda y tenga alguna idea de como solucionarla

grasias de hantebrazo T_T

Hola,
yo para asignar eventos a varios botones en un for, siempre uso el truco de la función que simula un Delegate con parámetros, y te aseguro que nunca da ningún problema:

Código ActionScript :

var arrTrace:Array = [1, 2, 3];

for(var i:Number = 0; i < 3; i++) {
   _root["btn" + (i+1)].onRollOver = ParamDelegate(this, rollOverHandler, i);
   _root["btn" + (i+1)].onRollOut = ParamDelegate(this, rollOutHandler, i);
   _root["btn" + (i+1)].onPress = ParamDelegate(this, pressHandler, i);
}

function rollOverHandler(i:Number):Void {
   trace("RollOver: " + _root.arrTrace[i]); 
}

function rollOutHandler(i:Number):Void {
   trace("RollOut: " + _root.arrTrace[i]); 
}

function pressHandler(i:Number):Void {
   trace("Press: " + _root.arrTrace[i]); 
}

function ParamDelegate(o:Object, f:Function):Function{
   var args:Array = arguments.slice(2);
   var func:Function = function():Void {
      var newArgs:Array = arguments.concat(args);
      f.apply(o, newArgs);
   }
   return func;
}

WOW
te agradesco (infinita+1)mente
intentare aplicarlo a mi codigo a ver si no hago otra tonteria , graciaaas!

tribak eres el mejor!!!!!

tribak escribió:

No me des las gracias a mí, que la función no es mía. La encontré en otra página hace tiempo. Yo incluso he hecho una clase para ella, y la uso siempre en lugar de Delegate (viene muy bien para hacer "botoneras" y pasarle parámetros a sus eventos onPress):

Código ActionScript :

class ParamDelegate {
   public static function create(o:Object, f:Function):Function {
      var args:Array = arguments.slice(2);
      var func:Function = function():Void {
         var newArgs:Array = arguments.concat(args);
         f.apply(o, newArgs);
      }
      return func;
   }
}

Se usa igual que Delegate, pero podemos pasarle los parámetros que queramos, y además el código queda muy ordenado (usando tu ejemplo, un poco modificado):

Código ActionScript :

import ParamDelegate;

var arrTrace:Array = [1, 2, 3];
var butArray:Array = new Array(); //Array de botones

for(var i:Number = 0; i < 3; i++) {
   var aux_mc:MovieClip = this.attachMovie("button", "button" + i, this.getNextHighestDepth());
   aux_mc._x = 100 * i;
   aux_mc._y = 100 * i;
   aux_mc.onRollOver = ParamDelegate.create(this, rollOverHandler, i);
   aux_mc.onRollOut = ParamDelegate.create(this, rollOutHandler, i);
   aux_mc.onPress = ParamDelegate.create(this, pressHandler, i);
   butArray.push(aux_mc);
}

function rollOverHandler(i:Number):Void {
   trace("RollOver: " + _root.arrTrace[i]);
}

function rollOutHandler(i:Number):Void {
   trace("RollOut: " + _root.arrTrace[i]);
}

function pressHandler(i:Number):Void {
   trace("Press: " + _root.arrTrace[i]);
}