Galeria Dinamica... los thumbnails no funcionan como botones

Hola, tengo el siguiente problema: Estoy haciendo una galería dinámica, con imagenes externas que llamo desde un XML.
Todo parecería andar bárbaro, salvo que cuando quiero agregar una accion onRelease a estos thumbs que cargué no puedo hacer que pase absolutamente nada....
Éste es el Código:

Código :

stop();
// -- posición donde se cargará la primera imagen
x = 96;
y = 635;
// -- ancho y alto de la imagen más 5 pixeles de espacio
ancho = 51;
alto = 42;
// -- numero de columnas
num_columnas = 12;
// -- creo un nuevo objeto XML
miXML = new XML();
// -- ignorar espacios 
miXML.ignoreWhite = true;
// -- proceso si la carga tuvo éxito
miXML.onLoad = function(succes) {
   if (succes) {
      // -- por cada nodo hijo del nodo principal...
      for (var i = 0; i<this.firstChild.childNodes.length; i++) {
         // -- delaro una variable que recoje el atributo del nodo (nombre de la imagen)
         galeria = this.firstChild.childNodes[i].attributes.id;
         //datos = this.firstChild.childNodes[i].attributes.dato;
         // -- creo un clip de película vacio 
         _root.createEmptyMovieClip("diapo"+i, i+100);
         // --  cargo la imáen el clip vacio
         item = _root["diapo"+i];
         item.loadMovie(galeria);
         // -- indico posición x - y
         item._x = x;
         item._y = y;



         item.onRelease = function() {
            trace("hacé algo!!!");

         };


         // -- incremento el valor de x para la siguiente imágen
         x += ancho;
         // -- incremento en 1 el número de columnas
         columna += 1;
         // -- ruptura de control, control de número de columnas
         if (columna == num_columnas) {
            columna = 0;
            x -= (ancho*num_columnas);
            y += alto;
         }
      }
   }
};
// -- cargar XML
//miXML.load("imagenes.xml");

miXML.load("imagenes.xml");

Les agradezco la ayuda!!!!

No hagas el loadMovie directamente en el clip de película "diapoX", crea dentro de él un clip de película vacío y haz el loadMovie en él. Por ejemplo:

Código :

[...]
 _root.createEmptyMovieClip("diapo"+i, i+100);
         // --  cargo la imáen el clip vacio
         item = _root["diapo"+i];
         item.createEmptyMovieClip("target_mc", 1);  //<-------Este es el clip de película donde vas a cargar la imagen.
         item.target_mc.loadMovie(galeria); //<---------Cargas la imagen...
[...]

Lo que pasa es que loadMovie realmente lo que hace es reemplazar el clip de película por el swf o la imagen que estás cargando. Es una de las razones por la que es mejor usar MovieClipLoader...
Suerte!

Sos lo más capo. Muchas Gracias, funciona perfecto.
Me hiciste terminar bien el día. Nos vemos.