preloader

Tengo una presentación de diapositivas que se llama "hasta_2005.swf". Como tarda varios segundos en cargar necesito ponerle un preloader, pero no es posible en una presentación de diapositivas. Leí que debo poner el preloader en un nuevo swf. No tengo idea de cómo hacerlo.
No sé nada sobre actionscript. No importa que el preloader sea ficticio, sólo lleva unos pocos segundos. Incluso preferiría que fuera solamente la palabra "Cargando...". El tema es: cómo hacer que cargue la presentación en la misma ventana.

Hola, bueno, creas un nuevo flash que le llamaremos "cargador.swf"

en el codigo del primer fotograma pon algo como esto:

Código ActionScript :

this.createTextField("texto", 9, 30, 30, 150, 40);
var cargador:MovieClipLoader = new MovieClipLoader();
cargador.addListener( this );
cargador.loadClip( "hasta_2005.swf", this.createEmptyMovieClip("carga", 10) );

function onLoadProgress( tg:MovieClip, l:Number, t:Number  )
{
     texto.text = "cargando..." + Math.floor( l / t * 100 );
}
function onLoadComplete( tg:MovieClip )
{
    texto.text = "";
}

Listo, con eso debe parecer un cargador de texto, suerte.

Muchísimas gracias. Lo probaré. Pero tengo que cambiar algo en el actioscript para que se cargue mi película? Un experto da muchas cosas por sobreentendidas, y yo NO TENGO IDEA de actioscript. Debo cambiar algo o llenar algún espacio vacío en tu código? Perdón por mi ignorancia.

no, solo debes de tener el swf de la presentacion en la misma carpeta donde esta este cargador. ese codigo lo hace todo de corrido

Mil gracias, LongeVie!!!
Funcionó!! No lo puedo creer, estuve todo el día sin poder lograrlo.
Ahora solamente decime cómo hago para centrar el texto de la precarga, y aumentar el tamaño de la tipografía.
A tus pies.
Desde Argentina,
Adriana.

Perfecto tocalla, mira aqui la modificacion para que lo deje en el centro del escenario y le cambie la fuente por Arial tamaño 9 y color gris.

Código ActionScript :

//Creamos el campo de texto y lo centramos
this.createTextField("texto_txt", 9, Stage.width / 2 - 100, Stage.height / 2 - 25, 200, 50); 
//Le damos formato 
var format:TextFormat = new TextFormat(); 
format.align = "center" 
format.bold = true; 

format.font = "Arial";//Nombre de la fuente
format.color = 0xA2A2A2; //Color de la fuente RRGGBB
format.size = 9;//Tamaño de la fuente

this.texto_txt.setNewTextFormat( format ); 
this.texto_txt.selectable = false; 

var cargador:MovieClipLoader = new MovieClipLoader(); 
cargador.addListener( this ); 
cargador.loadClip( "hasta_2005.swf", this.createEmptyMovieClip("carga", 10) ); 
 
function onLoadProgress( tg:MovieClip, l:Number, t:Number  ) 
{ 
     this.texto_txt.text = "Cargando..." + Math.floor( l / t * 100 );
} 
function onLoadComplete( tg:MovieClip ) 
{ 
    this.texto_txt.text = "";
   this.texto_txt.removeTextField();//Si ya no vas a usar el textfield.
} 

Suerte.

Mil gracias tocayo.
Ya lo copié y funciona perfecto, sólo le aumenté el tamaño de la fuente.
Puedo utilizarlo para cargar cualquier otro swf, solamente cambiando el nombre de archivo? O debo cambiar algo más?

Ojalá pudiera serte de ayuda en algo, pero lo dudo, a mí sólo me interesa el aspecto estético de todo esto.

si, exatamente en cargador.loadClip( "hasta_2005.swf"... solo tienes que cambiar el nombre del swf que se va a cargar, supon que ese swf esta en otra capreta tambien se puede usar asi cargador.loadClip( "otracarpeta/otro.swf".... pero bueno, en este caso, es recomentable y es buena idea tenerlos en la misma caprtea, este cargador y el archivo que se va a cargar.
Gracias y Suerte.