mediaplayback con playlist?

Hola bueno en flash 8, el componente para reproducir .flv esta excelente pero mi duda es que si le puede añadir una lista de reproducción? he estado buscando y no he encontrado nada

Gracias

esto t puede servir. es un repro mp3 hecho elecash

Holas... soy nuevo en el foro, este esmi primer mensaje. Agrego que lo que sé de flash y lo he aprendido metiendo mano y leyendo, nunca estudié y demás, por lo que si le pongo un nombre extraño a alguien sepan entender que uso otros términos, más "de calle" podría decirse.
Mi problema es este:

He seguido el tuto para hacer un mp3 player en flash con los componentes que vienen en el programa. Consulto por el tema del playlist, hice todo lo que se necesita y funciona perfectamente, pero me gustaría que mi reproductor reproduzca 1 solo archivo y lo que muestre el playlist sea un nombre de fantasía y no el nombre del archivo, aquí pego mi lista.xml

Código :

<?xml version="1.0" encoding="iso-8859-1"?>
<lista>
        <cancion>marchetti.mp3</cancion>
 
</lista>

el tema es que cuando pongo otra línea que se llama "nombre" en el xml (no sé dónde definirla en el código del flash) me aparecen los dos en el playlist como si fueran dos archivos distintos, y al hacer click intenta cargar el nombre (que sería "Entrevista a Pablo Marchetti") y como no existe ese archivo (pq el archivo es marchetti.mp3) me tira error. Enfin, cómo le puedo hacer para que cargue sólo el nombre del mp3 y al hacer click sobre el nombre reproduzca el archivo??? En todo caso lo que más me serviría sería saber cómo hacer para que reproduzca un mp3 sólo (la idea es hacer un reproductor para cada entrevista, y son varias, pq lasentrevistas van a tener un botón para cada una * ). También me gustaría agregar al swf una pequeña referencia de qué trata la entrevista.
* La página donde irá esto también es en flash y es muy sencilla. Es un cuadrado que a la derecha tiene 4 botones (quiénes somos, contacto, enlaces e inicio). En el angulo inferior derecho va un logo. Sobre la línea horizontal inferior va un menú con efecto easing (me bajé el fla y lo edité, tampoco sé hacerlo), en esa línea se van desplazando los nomres de los entrevistados. La idea es que al hacer click se abra un popup con el reproductor, este empiece a reproducir la entrevista y tenga esa pequeña reseña. Bien... les agradezco, pero porfavor explíquenme qué hago, no me digan "pon esto" simplemente, pq sino no aprendo y lo único que hago es copiar de los que saben. Grax!!!!

pd. el reproductor es el mediaplayback y el list que vienen con el flash, el único código as que hay está en el primer frame y es este:

import mx.controls.List;
import mx.controls.MediaPlayback;
//Cargamos el XML
canciones = new XML();
canciones.ignoreWhite = true;
canciones.onLoad = function(success) {
     if (success) {
          //Shortcuts
             cancion = canciones.firstChild;
         num_total = canciones.firstChild.childNodes.length;
             //Creamos y llenamos la lista
           crearLista();
           //Creamos el reproductor
                crearPlayer();
  } else {
                trace("No se pudo cargar la lista de canciones");
       }
};
canciones.load("lista.xml");
///////////////////////////////////////////////////////////////////
///////////////////////////  LISTENERS  ///////////////////////////
///////////////////////////////////////////////////////////////////
lista.addEventListener("change", alCambiar);
///////////////////////////////////////////////////////////////////
///////////////////////////  FUNCIONES  ///////////////////////////
///////////////////////////////////////////////////////////////////
function crearLista() {
    //Posicionamos la lista de las canciones
        lista.setSize(150, 170);
        lista._x = 220;
 lista._y = 0;
   //Llenamos la lista con las canciones
   misDatos = new Array();
 lista.dataProvider = misDatos;
  for (var i = 0; i<num_total; i++) {
             misDatos.addItem({label:cancion.childNodes[i].firstChild, 
                data:cancion.childNodes[i].firstChild});
        }
}
function crearPlayer() {
      //Posicionamos el reproductor
   player.setSize(200, 200);
       player._x = 0;
  player._y = 0;
  //Propiedades del reproductor
   player.controllerPolicy = "on";
 player.mediaType = "MP3";
}
//Cuando cambiamos la canción seleccionada en la lista... cargamos la nueva canción, y ejecutamos
function alCambiar(evento) {
 if (evento.type == "change") {
          player.setMedia("musica/"+lista.selectedItem.data, "MP3");
              player.play();
  }
}

pd.- si también pueden explicarmelo podría entenderlo y no molestaría a naides.... je! gracias!

Para que aparezca un nombre a cada canción debes hacer el siguiente cambio en el xml

Código :

<?xml version="1.0" encoding="iso-8859-1"?>
<lista>
<cancion nombre="Entrevista a Marchetti">marchetti.mp3</cancion>

</lista> 

Y en el código ActionScript colocas esto:

Código :

for (var i = 0; i<num_total; i++) {
   misDatos.addItem({label:cancion.childNodes[i].attributes.nombre,
   data:cancion.childNodes[i].firstChild});
} 

PD: Por favor utiliza las etiquetas [code] para colocar tu código.

gracias!!! ahora funciona!! Perdón por no usar la etiqueta... saludos,

curchunflo

Buenas a todos, tengo un problema con este reproductor. Cuando termina un tema se pausa y no sigue con el siguiente. Tengo tildada la opcion Automatically play, pero no hay caso. Alguien me puede dar un mano.
Saludo a todos y gracias !!!!

tengo una super duda con el reproductor hise todo lo q dice pero no me aparce nada en e la list y no carga nada y no se por q y la otra duda es como las canciones deben de ir en la misma carpeta me supengo, espero que me respondan pronto lo nesecito para una pag web

mandame el fla y el xml que te digo que anda mal.... [email protected]
Saludos
Manuel

A pesar de estar viejo el ultimo post espero alguien pueda responder lo siguiente...

He creado mi reproductor en Stream pero sin el Componente Flash PlayBack y en cuanto a cargar el XML si lo hace, me llena el List pero no lo reproduce, que estara mal?

Les dejo el Codigo para que me hechen una mano vale!
Se los agradesco.

Código :

stop();
var conexion:NetConnection = new NetConnection();
conexion.connect(null);
var stream:NetStream = new NetStream(conexion);
my_audio.attachAudio(stream);
sound_controll = new Sound(my_audio);
//--------------------
var estado:Number = 0;
boton.stop();
barritas.stop();
boton.gotoAndStop("pause");
boton.onPress = function() {
   if (estado == 1) {
      stream.pause();
      estado = 0;
      boton.gotoAndStop("pause");
      barritas.play();
   } else {
      estado = 1;
      stream.pause();
      boton.gotoAndStop("play");
      barritas.stop();
   }
};
volumen.stop();
var estado2:Number = 1;
volumen.onPress = function() {
   if (estado2 == 1) {
      estado2 = 0;
      volumen.gotoAndStop("mute");
      sound_controll.setVolume(0);
   } else {
      estado2 = 1;
      volumen.gotoAndStop("volumen");
      sound_controll.setVolume(100);
   }
};
//Cargamos el XML
canciones = new XML();
canciones.ignoreWhite = true;
canciones.onLoad = function(success) {
   if (success) {
      cancion = canciones.firstChild;
      num_total = canciones.firstChild.childNodes.length;
      misDatos = new Array();
      lista_mp3.dataProvider = misDatos;
      for (var i = 0; i<num_total; i++) {
         misDatos.addItem({label:cancion.childNodes[i].attributes.nombre, data:cancion.childNodes[i].firstChild});
      }
   } else {
      trace("No se pudo cargar la lista de canciones");
   }
};
canciones.load("lista.xml");
lista_mp3.addEventListener("change", alcambiar);
function alcambiar(evento) {
   if (evento.type="change") {
      barritas.play();
      stream.pause();
      estado = 0;
      boton.gotoAndStop("pause");
      stream.stop();
      stream.play(lista_mp3.selectedItem.data);
      stream.play();
   }
}
stream.onStatus = function(infoObject:Object) {
   if (infoObject.code == "NetStream.Play.Stop") {
      stream.play(lista_mp3.selectedItem.data);
   }
};
stream.onMetaData = function(MD:Object):Void  {
   duracion = MD.duration;
   xduracion = Math.floor((duracion*100)/100);
   if (xduracion<60) {
      txt_duracion.text = "00:"+xduracion;
   } else {
      yduracion = Math.floor((xduracion)/(60));
      xsegundo = Math.floor(((xduracion-(yduracion*60))*100)/100);
      if (xsegundo<10) {
         txt_duracion.text = "0"+yduracion+":0"+xsegundo;
      } else {
         txt_duracion.text = "0"+yduracion+":"+xsegundo;
      }
   }
};
var TTranscurrido;
onEnterFrame = function () {
   TTranscurrido = Math.floor((stream.time*100)/100);
   minutos = Math.floor(((TTranscurrido/60)*100)/100);
   minseg = ((minutos*60)-TTranscurrido)*(-1);
   if (TTranscurrido<10) {
      txt_trans.text = "00:0"+TTranscurrido;
   } else {
      if (TTranscurrido<60) {
         txt_trans.text = "00:"+TTranscurrido;
      } else {
         if (minutos<1) {
            txt_trans.text = "00:"+TTranscurrido;
         } else {
            if (minseg<10) {
               txt_trans.text = "0"+minutos+":0"+minseg;
            } else {
               txt_trans.text = "0"+minutos+":"+minseg;
            }
         }
      }
   }
   BTV = stream.bytesTotal;
   BCV = stream.bytesLoaded;
};
var hiloprecarga = setInterval(cargando, 100);
function cargando() {
   porcentaje = Math.floor((BCV*100)/BTV);
   bar_load.gotoAndStop(porcentaje);
   if (BCV == BTV) {
      bar_load.gotoAndStop(100);
      _root.msg_load._alpha = 100;
      _root.msg_loading._alpha = 0;
      clearInterval(hiloprecarga);
   }
}

En el XML

Código :

<?xml version="1.0" encoding="iso-8859-1"?>
<lista>
<cancion nombre="Kill Bill : Sound Track"> killbill.flv </cancion>
<cancion nombre="My Way : Sex Pistols"> myway.flv </cancion>
<cancion nombre="Cargar Pistola : Loop de Sonido"> disparo1.flv </cancion>
</lista>