Propiedades de anchura y altura de un movieclip

Hola a todos, tengo el siguiente problema cuando cargo una imagen de la siguiente forma

Código :

var mcListener:Object = new Object();
var image_mc:MovieClipLoader = new MovieClipLoader();

mcListener.onLoadProgress = function(target_mc:MovieClip)
{
   var pct = Math.round(target_mc.getBytesLoaded() * 100 / target_mc.getBytesTotal());
   cargado.text = pct.toString() + " %";
}

mcListener.onLoadComplete = function(target_mc:MovieClip)
{
        trace("Nombre "+ target_mc._name);
   trace("Anchura "+ target_mc._width);
}

mcListener.onLoadError = function(target_mc:MovieClip)
{
   trace("error loading image" + target_mc);
}

image_mc.addListener(mcListener);
image_mc.loadClip(url_foto, cargar_foto);

¿Por qué aparece 0?, ¿debería ser la anchura de la imagen cargada?, me gustaría tener esta información para poder centrar la imagen. Alguna idea?
Gracias.

MovieclipLoader.onLoadComplete es un evento que informa que la imagen se terminó de cargar, debes utilizar MovieclipLoader.onLoadInit que te informa que el primer frame del movieClip ha sido leido

Código :

var mcListener:Object = new Object();
var image_mc:MovieClipLoader = new MovieClipLoader();

mcListener.onLoadProgress = function(target_mc:MovieClip){

   var pct = Math.round(target_mc.getBytesLoaded() * 100 / target_mc.getBytesTotal());
   cargado.text = pct.toString() + " %";

}

mcListener.onLoadInit = function(target_mc:MovieClip){

   trace("Nombre "+ target_mc._name);
   trace("Anchura "+ target_mc._width);

}

mcListener.onLoadError = function(target_mc:MovieClip){

   trace("error loading image" + target_mc);

}

image_mc.addListener(mcListener);
image_mc.loadClip(url_foto, cargar_foto);

Qué velocidad en responder. Muchas gracias!!