Boton que aumenta objetos

hola.. ustedes diran: que fregado es este broder , pero comprendan que son mis ganas de aprender . Espero que puedan ayudarme o guiarme con esto. Alguno de ustedes sabe si se puede crean un boton en flash que cuando le den clik muestre un objeto y que si repiten el clik en ese boton el objeto aparecera tantas veces como tantos clic se den?
Se entiende la idea?, alguien sabe algun metodo? Gracias por todo

checa este vinculo
[url=http://www.x-flash.org/as/docs/attachmc1.htm][url=]

Hola. Primero, muchas gracias por responder a la duda que tengo . Sin embargo, creo que no es lo que en realidad busco. Aun no he visto este tipo de ejemplos en internet por mas que he buscado (o quizas no se buscar muy bien) pero trata de un Boton que al momento de precionarlo (por ejemplo, unas 3 veces) se repita un evento. Por ejemplo si preciono el boton A 3 veces, que muestre AAA.
COmo les dije en un principio, no lo he visto en internet por mas que he buscado, pero quisiera saber si es que alguno de ustedes tiene alguna idea de como se hace.
GRacias por todo

No entiendo que es lo que quieres, si lo que quieres es que al hacer click aparezca un objeto el link te lo muestra, pero ahora hablas de una letra?

Explica bien con detalles lo que deseas.

Hola Chininet.
Soy un poco dificil para hacerme entender en muchas ocaciones... intentare hacerlo bien esta vez:
No he visto por ningun lado lo siguiente:
Que al presionar un boton aparesca una letra u objeto. Que tenga la funcion como la de un teclado virtual o similar.
Ejemplo:
Tengo mi boton "W" y cuando presione el boton "W" en un lugar de el clip aparesca un objeto o mc que identifique a dicho boton presionado.
Pongo un grafico para que mas o menos puedan verla mejor:


Espero me hayan podido entender y espero que puedan apoyarme, muchas gracias por todo amigos

Disculpa @julfit0, sigo sin entender bien. Dices lo siguiente:



Un MovieClip o un Texto son objetos y sin embargo dices que en vez del clip lo que aparezca sea un objeto o mc y por otro lado no entiendo lo de que identifique al botón presionado.

olvidare el W y demas pq creo q lo estoy haciendo mal.
Tratare de explicarlo lo mas sencillo posible:

1. Tengo un boton, presiono boton, me muestra un objeto.
2. Presiono nuevamente el boton, me aparece otro objeto (ya serian 2 objetos)
3. Presiono por tercera ves el boton y me aparece un tercer objeto.
Osea, presione 3 veces el boton y me mostro 3 objetos en distintas posiciones.

En ese tercer evento del boton, queda desactivado para que ya no aumenten mas objetos.

Espero haberme hecho entender .
Te pido disculpas Chininet, pues se que tus intensiones son buenas para ayudarme, pero a veces soy torpe para explicarme... esta ves espero que me puedas entender, gracias

Bueno te voy a responder con código, si te vuelvo a hacer otra pregunta eres capaz de coger la pistola de tu avatar y dispararme.

Si el código no cumple tus espectativas entonces dices que le falta al código para lograr lo que quieres, pero es lo más cercano que se me ocurre:

(Debes crear un MovieClip con nombre de instancia "boton" en la escena)

Código ActionScript :

//---Al presionar el botón llamar a la función
boton.onPress = function():Void{
   
   buildObject();
   
}

//---Función de crear los objetos
var num:Number = 0;
var posX:Number = 10;

function buildObject():Void{
   
   var obj:MovieClip = _root.createEmptyMovieClip("obj" + num, _root.getNextHighestDepth());
   var borde:MovieClip = obj.createEmptyMovieClip("borde", obj.getNextHighestDepth());
   var texto:TextField = obj.createTextField("texto", obj.getNextHighestDepth(), 0, 0, 0, 0);
   
   //---Llenar el texto
   with(texto){
      
      autoSize = true;
      selectable = false;
      text = "objeto\r" + (num + 1);
      
   }
   
   var ancho:Number = texto._width;
   var alto:Number = texto._height;
   
   //---Dibujar el borde
   with(borde){
      
      lineStyle(1, 0x000000, 100);
      moveTo(-2, -2);
      lineTo(ancho + 4, -2);
      lineTo(ancho + 4, alto + 4);
      lineTo(-2, alto + 4);
      lineTo(-2, -2);
      
   }
   
   //---Posicionar
   obj._x = posX;
   posX += (obj._width + 10);
   num++;
   
}

Chininet.
No, como se te ocurre... por el contrario te agradesco que me ayudes y si no entendias la pregunta no era por ti, si no por mi, que como te dije, soy un poco torpe para hacerme entender.

Muchisimas gracias por el codigo, ya lo acabo de probar y esta genial, en insisto, eres mi maestro pues estoy aprendiendo harto con tus tips.
Una dudita, y si no es mucho pedir, se puede hacer algo para desactivar la funcion despues de dar 3 veces clic al boton?
Es decir, al llegar al objeto 3 el boton quede desactivado para que ya no siga aumentando. Se puede hacer eso?.

En todo caso, de no poderse igual quedo muy agradecido contigo siempre

Sólo debes añadir una condición:

Código ActionScript :

//---Al presionar el botón llamar a la función 
boton.onPress = function():Void{ 
    
   buildObject(); 
    
} 
 
//---Función de crear los objetos 
var num:Number = 0; 
var posX:Number = 10; 
 
function buildObject():Void{ 
    
   var obj:MovieClip = _root.createEmptyMovieClip("obj" + num, _root.getNextHighestDepth()); 
   var borde:MovieClip = obj.createEmptyMovieClip("borde", obj.getNextHighestDepth()); 
   var texto:TextField = obj.createTextField("texto", obj.getNextHighestDepth(), 0, 0, 0, 0); 
    
   //---Llenar el texto 
   with(texto){ 
       
      autoSize = true; 
      selectable = false; 
      text = "objeto\r" + (num + 1); 
       
   } 
    
   var ancho:Number = texto._width; 
   var alto:Number = texto._height; 
    
   //---Dibujar el borde 
   with(borde){ 
       
      lineStyle(1, 0x000000, 100); 
      moveTo(-2, -2); 
      lineTo(ancho + 4, -2); 
      lineTo(ancho + 4, alto + 4); 
      lineTo(-2, alto + 4); 
      lineTo(-2, -2); 
       
   } 
    
   //---Posicionar 
   obj._x = posX; 
   posX += (obj._width + 10); 
   num++;
   
   //---Deshabilitar el botón después de tres veces

   if(num > 2){
      
      _root.boton.enabled = false;
      
   }
    
}

Gracias chininet, una ves mas me has enseñado bastante.

Chininet, por cierto, se puede borrar lo hecho?, es decir, ya mostre los tres botones y quisiera borrarlos para reiniciar, se puede?, no sera mucha molestia?

Debes hacer una función que los borre utilizando MovieClip.removeMovieClip():

Código ActionScript :

//---Acción del botón de borrar
boton_delete.onPress = function():Void{
   
   deleteObjects();
   
}

//---Función de borrar todos los objetos
function deleteObjects():Void{
   
   //---Borrar los objetos
   for(var obj in this){
      
      if(this[obj] instanceof MovieClip && this[obj]._name.indexOf("obj") >= 0){
         
         this[obj].removeMovieClip();
         
      }
      
   }
   
   //---Reinicializar
   num = 0;
   posX = 10;
   boton.enabled = true;
   
}

Esta función borrará cualquier objeto que esté en la escena perteneciente a la clase MovieClip y que contenga en su nombre "obj".

Vaya, Chininet, disculpa por la demora de las gracias . Gracias broder, creo que esto deberias ponerlo como un tip o algo asi, muy buenas las explicaciones y las ayudas que me das. Gracias por todo maestro

De nada, es un placer