Hola BlackMage...
Puedes intentar con el
MovieClipLoader, el cual te permite controlar las acciones de carga mas fácil, puedes cargar jpg(no progresivos), y swf ( no he probado con otros archivos)...
Para tener un mejor control del archivo a cargar yo uso un MC en el escenario, y dentro de el coloco el container (MC donde se cargara el archivo), tambien uso un MC con una animacion de 100 fotogramas, que me sirve como barra de progreso. Y en el primer fotograma coloco el siguiente código:
Código :
//loader es el MovieClipLoader que creo
loader = new MovieClipLoader();
//listener es donde coloco las funciones que realizara el loader durante
//el comienzo de la carga, el progreso de la carga, y cuando se termina la carga.
listener = new Object();
//******************************************
//funcion que ejecuta el MCL cuando empieza la carga
listener.onLoadStart = function(target_mc) {
//llamo a la barra de progreso y la posisiono en el medio del escenario
_root.attachMovie("barra", "barra_mc", _root.getNextHighestDepth());
_root.barra_mc._y = Stage.height/2;
_root.barra_mc._x = Stage.width/2;
};
// esta funcion es para llevar el control de la carga
listener.onLoadProgress = function(target_mc, loadedBytes, totalBytes) {
//variables y sentencias para que la barra de progreso muestre "el progreso" :)
var porcentaje:Number;
porcentaje = Math.round((loadedBytes*100)/totalBytes);
_root.barra_mc.gotoAndStop(porcentaje);
_root.barra_mc.cargado.text = "Cargando "+porcentaje+"%";
//hago que mientras se carga el archivo permanezca invisible y sin reproducir
target_mc._visible = false;
target_mc.stop();
};
//finalmente cuando la caraga se completa
listener.onLoadComplete = function(target_mc) {
//hago visible el archivo y le doy un alpha de 0
target_mc._visible = true;
target_mc._alpha = 0;
//lo siguiente es para hacer un fundido, para que no se muestre de golpe
target_mc.onEnterFrame = function() {
if (target_mc._alpha == 100) {
target_mc._alpha = 100;
} else {
target_mc._alpha += 2;
}
};
//y aqui hago que se reproduzca
target_mc.play();
//remuevo la barra de progreso
_root.barra_mc.removeMovieClip();
};
//asigno el listener a loader
loader.addListener(listener);
//aqui coloco la ruta del archivo y su destino
loader.loadClip("archivo.swf", _root.clip.container);Nota: Es mejor que cada jpg que quieras cargar, lo coloques antes dentro de un swf, y lo cargues como swf, porque es mas fácil de controlar.
Otra nota: este codigo aparece en uno de los tuto de MovieClipLoader (no recuerdo el autor)... me ha ayudado muchisimo...
espero te sirva...
Saludos...
la hice según este tuto 
pero sube los files porfa...
