cuadricula con actionscript

estimados flasheros...

una consulta...

como puedo crear una cuadricula con actionscript, pero que se genere con solo una linea. O sea... yo pincho con el mouse en un punto, luego en otro, y desde la linea que se genera, crear una cuadricula.



Ayuda pleaaase!

Aquí tienes, la función que crea las cuadrículas es crearCuadricula y las crea con la cantidad de columnas y filas que están definidas en las primeras variables, solamente tienes que enviarle a la función las _x y las _y de los dos puntos y creará una cuadrícula entre estos dos puntos:

Código :

var columnas:Number = 5;
var filas:Number = 5;

var sumador:Number = 1;
var contador:Number = 1;
var corners:Array = new Array();

function crearCuadricula(x1, y1, x2, y2){
   
   var cuadricula:MovieClip = this.createEmptyMovieClip("cuad" + sumador, sumador);
   
   var ancho:Number = Math.abs(Math.abs(x1) - Math.abs(x2));
   var alto:Number = Math.abs(Math.abs(y1) - Math.abs(y2));
   
   var anchoCuadro:Number = ancho/columnas;
   var altoCuadro:Number = alto/filas;
   
   var cuadroNum:Number = 1;
   var cuadro:MovieClip;
   
   for(var i:Number = 0; i < filas; i++){
      
      for(var j:Number = 0; j < columnas; j++){
         
         cuadro = cuadricula.createEmptyMovieClip("cuadro" + cuadroNum, cuadricula.getNextHighestDepth());
      
         with(cuadro){
            
            lineStyle(1, 0xCCCCCC, 100);
            moveTo(0, 0);
            lineTo(anchoCuadro, 0);
            lineTo(anchoCuadro, altoCuadro);
            lineTo(0, altoCuadro);
            lineTo(0, 0);
            
         }
         
         cuadro._x = j*anchoCuadro;
         cuadro._y = i*altoCuadro;
         
         cuadroNum++;
         
      }
      
   }
   
   sumador++;
   
   if(x1 < x2){
      
      if(y1 < y2){
      
         cuadricula._x = x1;
         cuadricula._y = y1;
      
      }else{
         
         cuadricula._x = x1;
         cuadricula._y = y2;
         
      }
      
   }else{
      
      if(y1 < y2){
         
         cuadricula._x = x2;
         cuadricula._y = y1;
         
      }else{
         
         cuadricula._x = x2;
         cuadricula._y = y2;
         
      }      
      
   }
   
}

this.onMouseDown = function():Void{
   
   if(contador == 1){
      
      corners[0] = [this._xmouse, this._ymouse];
      
      contador++;
      
   }else{
      
      corners[1] = [this._xmouse, this._ymouse];
      
      contador = 1;
      
      crearCuadricula(corners[0][0], corners[0][1], corners[1][0], corners[1][1]);
      
      corners.splice(0);
      
   }
   
}

muy bueno!

gracias te pasaste...!

un 10!

=)

una pregunta mas... como puedo hacer k despues de k se genera la cuadricula, se pueda modificar su forma desde las cuatro esquinas?

Situando pequeños movies en las esquinas que cuando los presiones creen un onEnterFrame que modifique el tamaño (_width y _height) del movieClip que contiene a la cuadrícula depende de la posición donde se encuentre y a la vez actualizar la posición (_x e _y) a los 2 movies que sean contínuos con él.