Hola eso solo lo se realizar con el flash pero he visto que unas web si te impiden utilizar el boton derecho en la pagina html por que no pones este mismo ensaje en el foro de html.
Yo te entrego aqui el codigo de como se hace en flash solo que no se como se hace en html asi que haz lo que te digo ojala alguien te pueda ayudar con eso.
Aqui lo tienes:
Código ActionScript :
// Menú del _root --------------------------------------------------------------------------
// Defino el objeto menu_principal que será el menú contextual de la película
var menu_principal:ContextMenu = new ContextMenu();
// Defino los elementos del menú. El primer parámetro es el texto
// que se verá en el elemento de menú. El segundo es la función que
// se ejecuta al pulsarlo.
var verIVI:ContextMenuItem = new ContextMenuItem("Visitar website iVi CONCEPT", visitarIVI);
var verAlerta:ContextMenuItem = new ContextMenuItem("Mensaje emergente", verMensaje);
// esta es la función que se ejecuta al pulsar en "Visitar website iVi CONCEPT"
function visitarIVI():Void {
getURL("http://www.ivi-concept.com", "_blank");
}
// esta es la función que se ejecuta al pulsar en "Mensaje emergente"
function verMensaje():Void {
getURL("Javascript:alert('Este un mensaje emergente')");
}
// oculto los elementos predeterminados
menu_principal.hideBuiltInItems();
// incluyo los dos elementos del menú dentro de éste
menu_principal.customItems.push(verIVI);
menu_principal.customItems.push(verAlerta);
// asocio el menu que hemos creado al _root
_root.menu=menu_principal;
// Menú del _root --------------------------------------------------------------------------
// Menú del clip --------------------------------------------------------------------------
// Defino el objeto menu_clip que será el menú contextual del clip
var menu_clip:ContextMenu = new ContextMenu();
// Defino los elementos del menú. El primer parámetro es el texto
// que se verá en el elemento de menú. El segundo es la función que
// se ejecuta al pulsarlo.
var up:ContextMenuItem = new ContextMenuItem("Más grande", masGrande);
var down:ContextMenuItem = new ContextMenuItem("Más pequeño", masPq);
// esta es la función que se ejecuta al pulsar en "Visitar website iVi CONCEPT"
function masGrande():Void {
ivi_mc._xscale += 10;
ivi_mc._yscale = ivi_mc._xscale;
}
// esta es la función que se ejecuta al pulsar en "Mensaje emergente"
function masPq():Void {
ivi_mc._xscale -= 10;
ivi_mc._yscale = ivi_mc._xscale;
}
// oculto los elementos predeterminados
menu_clip.hideBuiltInItems();
// incluyo los dos elementos del menú dentro de éste
menu_clip.customItems.push(up);
menu_clip.customItems.push(down);
// asocio el menu que hemos creado al _root
ivi_mc.menu = menu_clip;
// Menú del clip --------------------------------------------------------------------------
stop();
Este codigo lo insertas en un Frame vacio que llames AS al principio de la pelicula y recuerda que si vas a usar escenas debes de ponerlo siempre en cada una de ellas ya que sino solo te sevira en una sola escena.
A por cierto puedes cambiar lo que dice borrando la seccion Visitar website iVi CONCEPT y Mensaje emergente o quitando esas lineas ya lo he probado y si funciona este se encuentra en un tip de cristalab pero se me olvido donde lo vi asi que para que no estes buscando aqui esta ya hecho.
Espero haberte ayudado......
