onRollOver, onPress,etc. en botones creados dinámicamente

He creado unos botones en base a elementos de un XML, de ahi tomo las etiquetas para estos.
El problema es que no sucede nada al momento de llamar a los eventos onRollOver, onRelease, onPress, etc.

Código :

var activeCountries :Array=new Array();
var paisCanal:XML = new XML();
paisCanal.ignoreWhite = true;
var posY=13;
var incY=20;
var nivel=20;

var formatoTexto:TextFormat = new TextFormat();
formatoTexto.font = "Verdana";
formatoTexto.color = 0xFFFFFF;
formatoTexto.bold = true;

paisCanal.onLoad = function(exito) {
   if (exito) {
        desactivarPaisesTodos();
      for(n in paisCanal.firstChild.childNodes){

            countryCode=paisCanal.firstChild.childNodes[n].attributes.code;
            countryName=paisCanal.firstChild.childNodes[n].attributes.name;
            
             mBotones.attachMovie("bnPais","bn" + countryCode,n);
            mBotones["bn"+countryCode]._x=5;
             mBotones["bn"+countryCode]._y=posY;           

   //  Etiquetas de los paises      
               labelsPaises.createTextField("t"+ countryCode, n, 0, posY, 150, 20);            
               labelsPaises["t"+ countryCode].text = countryName;
          labelsPaises["t"+ countryCode].setTextFormat(formatoTexto);
      labelsPaises["t"+ countryCode].selectable=false;
   
         posY+=incY;
         nivel++;   
            activeCountries.push([countryCode,countryName]); //agrega codigo del pais a lista de paises activos
      }
      activarPaises();
      
   } else {
      trace("error al cargar XML");
   }
};

                       ...
//-------------------------------------------------------------------------------------------
// AQUI ES COMO ESTOY INTENTANDO PROGRAMAR LOS EVENTOS
//------------------------------------------------------------------------------------------

//    bnMX --------- > es uno de los botones que creé dinámicamente arriba

mBotones.bnMX.onRelease=function(){
   getURL("javascript:getChannels('MX')");
}
 mBotones.bnMX.onRollOver=function(){
      trace("eitale Mexico");  //   NUNCA me ha mostrado este mensaje ni usando  mBotones["bnMX"].onRollOver=function()
}


// y lo curioso es que si puedo modificar el boton desde otros botones y/o movie clips

Mexico.onRollOver=function(){
cambiaColor(this,colorSeleccionar);
cambiaColor(mBotones.bnMX,colorSeleccionar); //si le cambia el color al boton
}

No te muestra el trace porque cuando intentas definir el evento, el botón sigue siendo undefined.
Los eventos defínelos dentro del bucle así:

Código :

 var btn:MovieClip=mBotones.attachMovie("bnPais","bn" + countryCode,n);
 btn._x=5;
 btn_y=posY;   
btn.pais=countryCode
btn.onRelease=function(){
getURL("javascript:getChannels("+this.pais+")");
}

Un gracias infinito zah , ya me tenia en jaque esto.

Código :

 var btn:MovieClip=mBotones.attachMovie("bnPais","bn" + countryCode,n);

 btn._x=5;

 btn._y=posY;    //aqui nomas se te habia pasado el punto antes del  _y  :)

btn.pais=countryCode

btn.onRelease=function(){

getURL("javascript:getChannels("+this.pais+")");

}