OOP Clase personalizada, no funciona attachmovie

Hola, tengo la siguiente clase.

Código :

class Square {
   public var target_mc:MovieClip;
   public function Square(c:MovieClip){
      this.target_mc = c;
   }
   public function drawMask(x_mask, y_mask, w_mask, h_mask):Void{
      this.createEmptyMovieClip("mask_mc", 1);
      this.mask_mc.beginFill(0x000000, 50);
      this.mask_mc.moveTo(x_mask, y_mask);
      this.mask_mc.lineTo(x_mask + w_mask, y_mask);
      this.mask_mc.lineTo(x_mask + w_mask, y_mask + h_mask);
      this.mask_mc.lineTo(x_mask, y_mask + h_mask);
      this.mask_mc.lineTo(x_mask, y_mask);
   }
   public function addMask():Void{
      this.attachMovie("maskLib", "maskLib", 2);
   }
} 

El problema es que no me reconoce ni el attachmovie, ni el createEmptyMovieClip

Para el atachmovie tengo un clip vinculado con ese identificador.
La clase , como veran no hereda nada. asi que intente heredar de MovieClip
Intente heredar de Movieclip y esto sucedio: ( class Square extends MovieClip{ )
Para el attachmovie si ponia

Código :

   public function addMask():Void{
      attachMovie("maskLib", "maskLibclip", 2);
   }

No me da ningun error

Código :

   public function addMask():Void{
      attachMovie("maskLib", "maskLibclip", 2);
      maskLibclip._x = 0;
      maskLibclip._y = 0;
   }

Me dice: No hay ninguna propiedad que lleve por nombre 'maskLibclip'.

Con el createEmptyMovieClip me dice: No hay ningún método que lleve por nombre 'mask_mc'. y otros 5 errores en cada llamada.

Cuando compilo sin heredar de movieclip, aunado a estos errores, me dice que no hay metodos que lleven por nombre createEmptyMovieClip, o attachMovie

Ya le he buscado variaciones, usando this, y no funciona nada.
Me puse a buscar en internet, en la ayuda de flash, y di con esto, que al parecer podria ser mi solucion
Object.registerClass(”miClip”, miClase);
pero no entiendo como carajos usarlo

Ayuda de flash dice escribió:

Ya le he probado y no doy.
Espero su ayuda, y les doy la gracias de antemano

Cambia el this por target_mc

Código :

target_mc.createEmptyMovieClip("mask_mc", 1);
target_mc.attachMovie("maskLib", "maskLib", 2);

Pero mi idea no es esa Zguilles, todo se puede resumir a: (Lo que me pides funciona perfecto, pero para mis fines no me funciona)

como creo un movieclip (con createEmptyMoveiclip) desde mi clase?
como atacho un movieclip de la biblioteca, desde mi clase?

Muchas gracias.

Lo que te decia es que no puedes usar this dentro de una clase para crear o atachar un clip. (this hace referencia a la clase) Has de utilizar la ruta de la linea de tiempo en donde quieres colocar el movieclip.

Esta ruta la puedes pasar como parámetro en el constructor de la clase:

Código :

class MiClip
{
   private var ruta;
   //--------------
   public function MiClip(qRuta:MovieClip)
   {
      ruta = qRuta;
   }
   public function creaMovieClipVacio(nombre:String, prof:Number)
   {
      ruta.createEmptyMovieClip(nombre, prof);
   }
   public function atachaClip(clip:String, nombre:String, prof:Number)
   {
      ruta.attachMovie(clip, nombre, prof);
   }
}

Código :

import MiClip;
var clip:MiClip = new MiClip(this);
clip.creaMovieClipVacio("mc", 1);
clip.atachaClip("clip", "mc1", 2);

Aqui cambio un poco la cosa, no puedes pasarle parametros al constructor, pero puedes inicializar propiedades con el cuarto parametro de attachmovie que es con lo que crearas la instancia de la clase.

Código :

dynamic class Square extends MovieClip{
   static var className:String = "__Packages.Square";
   static var constructor:Function = Square;
   static var mcLinked = Object.registerClass(className, constructor);
   public var a:String;
   
   public function Square(){
      trace(this.a);
   }
   public function drawMask(x_mask, y_mask, w_mask, h_mask){
      this.createEmptyMovieClip("mask_mc", this.getNextHighestDepth());
      this.mask_mc.beginFill(0x000000, 50);
      this.mask_mc.moveTo(x_mask, y_mask);
      this.mask_mc.lineTo(x_mask + w_mask, y_mask);
      this.mask_mc.lineTo(x_mask + w_mask, y_mask + h_mask);
      this.mask_mc.lineTo(x_mask, y_mask + h_mask);
      this.mask_mc.lineTo(x_mask, y_mask);
     this.mask_mc.endFill();
   }
   public function addMask():Void{
      this.attachMovie("maskLib", "maskLib", 2);
   }
}

Código :

import Square;

attachMovie(Square.className,"nuevo",1,{a:"Inicalizada"});

nuevo.drawMask(10,10,100,100);

saludos