POR FAVOR, URGENTE ESTOY ATRAPADO

POR FAVOR, URGENTE ESTOY ATRAPADO:
necesito saber como hacer que se desplace un moviclip (muy ancho) en sentido horizontal y se detenga en un lugar concreto (con efecto easing), asociado a un evento de clip sobre la panatalla. Cada vez que clico en el lado 1/2 derecho de la pantalla el clip se desplaza una posición, cuando clico en el lado izquierdo, retrocede (cada vez que clico retorna a posiciones anteriores)
gracias.
saludo y libertad. onofre

dependiendo hacia donde quieres que vaya le cambias el 78. y si lo quieres hoizontal o vertical le quitas el eje de las y o las x.

onClipEvent (load) {
_x = 0;
_y = 0;
velocidad = 20;
}
onClipEvent (enterFrame) {
posicionX = _root._x = 78;
posicionY = _root._y = 78;
_x += (posicionX - _x )/velocidad;
_y += (posicionY - _y )/velocidad;
}

saludos

Gracias barak me alegra saber que hay gente tan generosa.....he avanzado un poco, genial, el clip se me coloca donde yo quiero, aunque mi guión tiene mas necesidades....Siento abusar ti, pero además, necesito que cada vez que hago clic con el mause, el clip de película tome otra posición, te explico:
Necesito mostrar unas fotos que están montadas dentro de un clip en de forma horizontal, una al lado de la otra, me gustaría que si el usuario cliquea en el lado derecho de la ventana del navegador o de la peli, el clip tomara valores _x para ir posicionandose y mostrando la foto que está oculta por el lado derecho, y que si cliquea en el lado izquierdo, cambie el sentido y muestre las del otro lado,
no se si te he liado....
En fin que haber si me hechas una manita.
salud y libertad.
onofre

lo que debes hacer es utilizar un evento de clip y en vez de load un mouse down

Claro, el problema es determinar si el usuario cliquea en el lado derecho o izquierdo y segun haga, el mc ha de ir en sentido contrario
gracias de nuevo por tu tiempo, si me concretas esto te estaré eternamente agradecido,
salud y libertad.
onofre

buenas onefrebachiller
prueba a usar la clase Tween para mover objetos con easing por tu pantalla o rotarlos o redimensionarlos o lo que quieras.
te explico un poco como usarla

//BIBLIOTECAS IMPORTADAS
import mx.transitions.Tween;
import mx.transitions.easing.*;

//CODIGO PROPIAMENTE DICHO
btnPrueba.onRelease = function() {
moveClipPrueba: Tween = new Tween(objeto_a_mover, "propiedad_objeto", Tipo_easing, inicio_propiedad, final_propiedad, duracion, segundos/frames);
}

entonces, con este ejemplo te explico un poco. si tu quieres mover un objeto llamado rectangulo en el eje x, por ejemplo, 30 pixeles a la derecha, con un efecto de easing determinado en 3 segundos por ejemplo, podriashacerlo de esta forma

new Tween(rectangulo,"_x",Back.easeOut,rectangulo._x,rectangulo._x+30,3, true);
/*ojo, no es un error no poner la variable antes del new tween, asi tambien rula cundo no te interesa acceder a ninguna de los metodos de un objeto Tween */


rectangulo es el objeto que deseas mover
"_x" es la propiedad del obejto, da igual si quieres _width,_height,_rotate,_alpha, _x, _y o lo que sea vamos que sea propiedad
Back.easeOut es el easing, que puedes encontrar las distintas opciones que te dan si escribes Tween help en el google
rectangulo._x es la posicion inicial de tu objeto, la suya propia por ejemplo
rectangulo._x+30 es la posicion final
3 es el tiempo que quieres que dure tu animacion
true quiere decir que el tiempo lo quieres medir en segundos, si fuera false, lo medirias en frames.

busca cositas acerca de esta clase, que es la leche. tambien puedes controlar cuando acaba un movimiento de Tween con metodos propios ( rectMovimiento:Tween = new Tween(...); rectMovimiento.onMotionFinished = function() { ... } creo que era la sintaxis....pero ahora no estoy seguro) y mil cosas mas.

espero que te sirva de ayuda
nos vemos

coloca tu correo y te envio un ejemplo de click derecho

[email protected]
pero de todas formas, ¿para que quieres enviarme un ejemplo?
pega tu codigo y lo comentamos entre todos aqui

un saludo

ok aqui te coloco el codigo:

var menu_principal:ContextMenu = new ContextMenu();
var vermc:ContextMenuItem = new ContextMenuItem("Visitar cristalab", visitarmc);
var verAlerta:ContextMenuItem = new ContextMenuItem("Mensaje emergente", verMensaje);

function visitarmc():Void {
getURL("http://www.cristalab.com/foros/p320323.html", "_blank");
}

function verMensaje():Void {
getURL("Javascript:alert('Este un mensaje emergente de ejemplo')");
}

menu_principal.hideBuiltInItems();

menu_principal.customItems.push(vermc);
menu_principal.customItems.push(verAlerta);

_root.menu=menu_principal;

stop();

esto creara dos menus con el click derecho uno envia a este foro y el otro crea una pantalla emergente de javascript

Eres un angelote manga, he estado toda la tarde investigando el tema.... por fin...!!!! mil gracias, no habría llegado hasta a qui si no hubira ido de tu mano, o al menos habría sido cuando me jubilara...,
En fin que solo me queda determinar que se cumpla la acción dependiendo de donde se cliquee derecha o izquierda. y claro, que cada vez que el usuario clique tome nueva posicion...(ojo el tema no se trata de clicar con el botón derecho del mause, no se si me he explicado)
mira mi mail es: [email protected]
estoy por el rabal, si pasas por el barrio, tienes una cerve y unas patatas fritas.....
salud y libertad.
onofre

bueno, no os lo váis a creer, pero no me he dado cuenta hasta que no he revisado esta pagina que hablaba con dos personas.... bbbrrrr..... un poco lento el chico.....
QUE SEAN DOS CERVECAS Y DOBLE DE PATATAS FRITAS!!!

muy chulo el escrip, para tener el menú emergente con el mause derecho, es la bomba...., aunque no es lo que ahora necesito, .... A ver si uno de los dos se entera o me explico otra vez mejor:
me interesa que si el usuario cliquea en la parte 1/2 derecha de un clic se ejecute una acción, y si lo hace en la izquierda realize otra diferente, no se, estoy intentando con _witdh pero no se como plantearlo
gracias a los dos.
salud y libertad.
onofre

La forma más sencilla es que coloques dos botones invisibles sobre el objeto que quieres mover y que programes cada uno según convenga. La forma óptima (y un poquitín) más complicada es detectando la posición x del mouse (_mouse) y ver si es mayor o menor que la mitad del ancho del mc (_width / 2). Si es mayor que haga una cosa y si es menor que haga la otra.

bueno, para agregar diferentes click derechos debes agregar + funciones y el codigo total quedaria asi:

var menu_principal:ContextMenu = new ContextMenu();
var vermc:ContextMenuItem = new ContextMenuItem("Visitar cristalab", visitarmc);
var verAlerta:ContextMenuItem = new ContextMenuItem("Mensaje emergente", verMensaje);

function visitarmc():Void {
getURL("http://www.cristalab.com/foros/p320323.html", "_blank");
}

function verMensaje():Void {
getURL("Javascript:alert('Este un mensaje emergente de ejemplo')");
}

menu_principal.hideBuiltInItems();

menu_principal.customItems.push(vermc);
menu_principal.customItems.push(verAlerta);

_root.menu=menu_principal;

var menu_clip:ContextMenu = new ContextMenu();

var up:ContextMenuItem = new ContextMenuItem("otra vez el foro", masforo);
var down:ContextMenuItem = new ContextMenuItem("otro java", masjava);

function masforo():Void {
getURL("http://www.cristalab.com/foros/p320323.html", "_blank");
}

function masjava():Void {
getURL("Javascript:alert('Este un mensaje emergente de ejemplo')");
}

menu_clip.hideBuiltInItems();

menu_clip.customItems.push(up);
menu_clip.customItems.push(down);

mi_mc.menu = menu_clip;

stop();

recuerda que "mi_mc" es mi movie clip ya tu le agregas las funciones que quieras.

Saludos.

y lo de las cerves y las patatas nos queda dificil por que vivo en Colombia. jaja

Barak, para próximos post, por favor cooloca el código entre etiquetas [*code] [*/code] (sin los asteriscos) para que sean más legibles y para evitar que puedan dañar el diseño del foro.

buenas, despues de este agradecido puente del pilar te comento a ver si te he entendido.
lo mas intuitivo y facil es lo que comento The Fricky, colocar dos MC's o BTN's invisibles cada uno en una mitad y asociarles un evento onPress, onRelease o algo asi de la siguiente forma:
en el primer fotograma de tu aplicacion (preferiblemente en una capa especifica de acciones)

Código :

//aqui te marco varias opciones que podrias emplear para ocultar tus botones en tiempo de ejecucion para poder verlos sin problema en vista diseño
//1ª haciendolo invisible 
mcIzda.visible=false;
mcDcha.visible=false;
//2ª dandole trasparencia total
mcIzda._alpha=0;
mcDcha._alpha=0;
//3ª poniendolo por debajo del mc en cuestion (esta es la forma mas fea y no esta ejecutada de forma optima ademas
mcIzda.swapDepths(1);
mcDcha.swapDepths(2);
//aqui el comportamiento, que lo podrias hacer con muchas funciones, pero entre ellas, la de onRelease
mcIzda.onRelease = function() { getUrl....blablabla };
mcDcha.onRelease = function() { ....... };

esta seria la forma mas intuitiva y mas sencilla, pero te obliga, en vista diseño, a andar encajando botoncitos unos encima de otros, bloqueando capas para que no se te muevan y un coñazo muy serio....y si te toca hacerlo mas de dos veces, vas a perder un tiempo que nadie te va a pagar.
para no tener que crear dos botones, por si por ejemplo tienes que hacer ese compotamiento 100 veces en tu aplicacion, no vas a crear 100 MC's que necesitas y otros 200 para los comportamientos... entonces lo planteamos de la siguiente forma:

vamos a llamar a tu MC mc1 por ejemplo
el inicio de las x del movieclip evidentemente sera mc1._x y el final sera: mc1._x + mc1._width.
a nosotros nos interesa saber la mitad justa del mc...pues para saberla es asi de facil: mc1._x + (mc1._width/2)
ahi le sumamos la mitad de la anchura y listo. entonces conociendo eso, lo podriamos hacer de la segunda forma.
dentro del evento onRelease, le metemos la comprobacion de en que parte del boton esta clickeando el usuario.

Código :

mc1.onRelease = function() {
//si el puntero del raton esta antes de la mitad del mc que calculamos antes 
if (_root._xmouse < mc1._x + (mc1._width/2))
trace("primera mitad");
else if (_root._xmouse >= mc1._x + (mc1._width/2))
trace("segunda mitad");
};
mc1.onReleaseOutside = function() {
trace("debe soltar el boton del raton dentro del area del boton de la aplicacion");
};

NOTAS DE INTERES:
- para no andar metiendo el churro formula de calculo de la mitad del boton, podrias meterlo en una CONSTANTE llamada MITAD_ANCHURA_MC y asi el codigo sera mucho mas entendible. tambien si te fijas, he usado mayusculas, que es una especie de convenio para que se sepa que es una constante y no una variable (que en as es igual, pero en otros lenguajes mas optimizados no) y asi si tienes que hacer portabilidad de codigo o que otro programador lo vea, le sera de ayuda para entenderlo. tambien es importante darle nombres MUY concretos y precisos para no tener que andar subiendo cada dos por tres a la parte de declaracion de variables a ver que narices de valor tenia esa constante. ademas, en la mayor parte de los programas de generacion de codigo, tendras autocompletar (cosa que el flash en su version 8 profesional todavia no incorpora con un minimo de elegancia), asi que no importara que tengas nombres largos, porque con un tabulado, lo tendras entero sin errores tipograficos
- este ejemplo esta hecho sobre un MovieClip, pero es indiferente si lo usas sobre un boton o sobre lo que quieras, pero la nomenclatura debe ser distinta en ese caso por temas de claridad... hay distintas opiniones al respecto, pero se suele meter un apocope ("resumen") del nombre del componente antes o despues del nombre del objeto de la clase de ese componente. ese apocope suele ser de 2 ó 3 letras que sean unicas para ese componente (lbl=label, bnt=boton, txt=caja texto, mc=movieclip, etc...). asi tu codigo sera claro y facil de leer incluso meses despues de haberlo generado para ti mismo.
- si tienes muchos objetos con un mismo comportamiento, te aconsejaria que utilizaras prototipos (si no estas familiarizado con las clases y los archivos externos .as). en resumen tu creas un prototipo de plan declaracion prototipo, comportamientos (onRelease, onRollOver, etc...) fin del prototipo, asignacion del prototipo con un bucle a todos tus elementos (btn1,btn2,btnX) y comprobacion que todos los elementos del prototipo funcionan igual. para que vale esto? para no tener que escribir el mismo codigo para 100 botones que tienen comportamientos comunes, aunque no todos sus metodos sean iguales con distintos nombres., como por ejemplo, si quieres que todos los botones de tu aplicacion tuvieran un menu contextual, harias un prototipo de onRollOver sacando el menu en cuestion y luego aplicando ese prototipo a todos tus botones.
- si te fijas, en el codigo anterior todo son posiciones relativas y dependientes de los elementos de tu aplicacion, asi que funcionaran dondequiera que este tu boton. cuando programes, intenta que siempre sea asi, para poder portar tu codigo entre aplicaciones
- lo siento, pero no he probado el codigo, asi que puede que tenga errores de compilacion, pero de todas formas, recomiendo encarecidamente que escribas tu mismo el codigo una vez que hayas entendido este, aunque lo que hagas sea un copy-paste tecleado caracter a caracter, te vendra bien escribirlo para asimilarlo mejor.... cosas del cerebro

espero que te haya servido de ayuda y que sea tan facilmente entendible como lo he intentado escribir
un saludo
atentamente
maije

gracias chicos... me pongo sobre manos.
salud y libertad. onofre

bueno tios, estoy a punto de sangrar por el cerebro... llevo horas intentando desplazar el clip con el condicional, ya sabéis si pico en el lado derecho se desplaza a la derecha, si lo hago a la izquierda pues a la izquierda.
he estado intentando lo del condicional.... no hay manera...veréis es un mc que tiene un monton de mc dentro. a si es el tema
/*if (_root._xmouse<ifoto.foto1._x+(ifoto.foto1._width/2)) {
var twMove:Tween = new Tween(ifoto, "_x", None.easeInOut, ifoto._x, -855, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto1, "_alpha", None.easeInOut, this.ifoto.foto1._alpha, 20, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto2, "_alpha", None.easeInOut, this.ifoto.foto2._alpha, 100, 0.6, true);
var twescala:Tween = new Tween(imascara, "_yscale", None.easeInOut, imascara._yscale, 98, 0.6, true);
trace("primera mitad");
} else if (_root._xmouse>=ifoto.foto1._x+(ifoto.foto1._width/2)) {
var twMove:Tween = new Tween(ifoto, "_x", None.easeInOut, ifoto._x, 00, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto1, "_alpha", None.easeInOut, this.ifoto.foto1._alpha, 100, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto2, "_alpha", None.easeInOut, this.ifoto.foto2._alpha, 20, 0.6, true);
var twescala:Tween = new Tween(imascara, "_yscale", None.easeInOut, imascara._yscale, 150, 0.6, true);
trace("segunda mitad");
}
};
*/
bien, se mueve... y hace los alfas y todo... el trace me confirma que he picado en el lado izquierdo.
pero una vez que se ha desplazado el clip principal y muestra el mc.mc2 y vuelvo a picar en la parte izquierda para que vuelva a ocupar su posicion, pues ya no retrocede, y el trace me dice como si estuviera picando en el lado derecho, y no en el izquierdo. en fin un lio, no se si me he explicado,
(para cada mc de segundo nivel hago una funcion )
como es un poco lio, os lo cuelgo en esta direccion, para que lo veáis mejor, solo está programado hasta el segundo
http://www.immacle.com/pruebasnet/immacle.html

olvide daos de nuevo las gracias, os pongo el link por si no lo habéis visto...jejej

http://www.immacle.com/pruebasnet/immacle.html

a ver. asi a un prmer vistazo, lo primero que he visto ha sido la condicion del if. siempre compruebas la foto1. dices que cada clip tiene su propia funcion*. pongo asterisco porque es muy importante cuando disparas la funcion y de que funcion se trata. si es una funcion onMouseDown, es normal que falle, porque deberias asociar cada funcion a un evento propio del movieClip en plan:

Código :

tuMovieClip.onRelease = function() { 
   ... 
}

y de esta forma solo se te dispararia la funcion que tu quieres, porque ahi, una vez que has desplazado a la izquierda, cualquier zona donde presiones, va a estar a la derecha del centro del PRIMER MC, no se si me explico... aqui es cuando entra lo que te he comentado en respuestas anteriores, te comento un poco mas ilustrado.

si he entendido bien, tu tienes 'n' MC's que quieres que se muevan a la derecha o a la izquierda dependiendo de donde clickee el usuario (izda o dcha de la foto). pues bien. todos tienen un comportamiento con este "PSEUDOpseudocodigo":

cuando clickees, compruebame si es mi lado izquierdo o mi lado derecho
si es mi lado derecho
{
mueve todos los mc's (incluyendome a mi) hacia la izquierda una cantidad X
mete alpha a todos los MC's exceptuando el siguiente a mi
}
si es mi lado izquierdo
{
mueve todos los MC's (incluyendome a mi) hacia la derecha una cantidad X
mete alpha a todos los MC's exceptuando el anterior a mi
}

y a grosso modo ese seria la parte de miga del programa. que es lo bueno de todo esto? que todos los MC's se comportan de la misma forma no? ahi es donde entran los prototipos que te comente .
te voy a poner la sintaxis para que lo tengas mas claro y no tengas que buscar mucho:

Código :

MovieClip.prototype.NOMBREDETUPROTOTIPO=function()
{
   this.onRollOver=function()
   {
      trace("hola, ¿¿que tal?? estoy pasando por encima del movie clip");
   }
   this.onRollOut=function()
   {
      trace("vaya, me sali");
   }
   this.onRelease=function()
   {
      trace("acabas de soltarme, aqui deberia de hacer algo, digo yo :)");
   }
}

un vez que tienes declarado el prototipo en la PARTE SUPERIOR DE TU ZONA DE CODIGO AS. eso es muy importante, porque si el programa llega a la llamada de prototipos antes que a la declaracion, no te funcionara...y si lo tienes modularizado con funciones y tal, puede que el orden sea correcto, pero es mejor no jugarsela y no perder un tiempo precioso en andar pensando: y ahora el programa en que parte esta??

despues de la declaracion, tu puedes tener una funcion en plan init()
en esa funcion vamos a asignar el prototipo a todos los MC's que tengas en pantalla de la siguiente forma:

para esto es muy importante que todos los MC's tengan nombres en plan foto1, foto2, foto3...fotoN o mc1,mc2,mc3...mcN, porque asi podras asignarlo dentro de un bucle...
si conoces el numero de fotos, como creo que es el caso, utiliza un bucle de este estilo:

Código :

for(i=1; i<num_fotos+1;i++)
{
      _root["foto"+i].NOMBREDETUPROTOTIPO();
}

vale, asi tienes asignado el comportamiento de todos tus MC's. dentro del prototipo, mete en el onRelease el pseudocodigo traducido para que los mueva a la zida o a la dcha y el aplha y deberia de estar listo... con un par de retoques mas que detecten el principio y el final de la lista.

NOTAS DE INTERES:
esta es una forma poco elegante de hacerlo. la forma mas elegante (y optima) de hacerlo seria la siguiente:
tu no tienes nada en vista diseño. cuando arranca tu programa, despues de la declaracion de prototipo, llamas a la funcion init(). en esa funcion tu te creas 3 mc's y les cargas las 3 fotos que tu quieras (la principal y otras dos para los lados dcho e izdo) y les asignas el prototipo (que tendras declarado en la parte superior recuerda). en el onRelease del prototipo, dependiendo:
si ha clickeado en la izda. cargas la foto que deberia estar a su izquierda sobre el MC que esta a la dcha del todo y lo colocas sobre la posicion x (sin tween) del que estaba mas a la izda y mueves los otros dos hacia la derecha mc._x += mc._width;
ya te puedes imaginar como hacerlo si clickean en el lado derecho.
por que es bueno hacerlo de esta forma?
- tienes solo que cargar una foto cada vez que clickee hacia uno de los lados, por lo cual, tu pagina se cargara en un principio mucho mas rapido, al no tener que cargar nada mas empezar n fotos.
- funcionas solo con 3 elementos, cosa que simplifica enormemente el trabajo.
- no tendras problemas de fin de lista o de inicio, porque sera como un recorrido circular, de la ultima pasa a la primera y viceversa con la condicion if-else correspondiente (no te la hago, que si no te hago la web entera... )
- podrias incluso cargar tu web inicialmente con los 3 MC's ya dibujados y tal, pero realmente no hace falta porque se cargaran igual de rapido teniendolos prehechos en vista diseño que cargandolos en tiempo de ejecucion.... y asi te ahorras tener que andar pringando en modo diseño.
-el funcionamiento es mucho mas intuitivo y portable a otros editores (GRATUITOS SIN LICENCIA) de AS que en un futuro, cuando controles mas, puedas utilizar (FlashDeveloper).
- incluso en un futuro, si quieres, puedes usar un 4º MC para hacer la carga, que lo colocarias a la izda o a la dcha dependiendo de donde clickeara y asi seria aun mas rapido.
- puedes cambiar el bucle for por un while, en la zona de asignacion de prototipos, si no conoces el numero de fotos o quieres que el programa siga funcionando aunque tu cliente quiera meterle mas fotos y asi solo tienes que cambiar una linea de codigo y copiar la imagen en su carpeta con su nombre correspondiente, en vez de andar perdiendo tiempo en vista diseño.
- y si el cliente es amigo, podrias hacerle una miniaplicacion para subir nuevas fotos o eliminar las viejas y asi que el solo mantenga la web sin tocarte las narices a ti si no es amigo, no o hagas, cobrale el mantenimiento (que sera solamete cambiar las fotos) y que es el pan de cada dia de los webmasters, no el hacerlas, sino mantenerlas con el minimo esfuerzo
- muchas otras que seguro que no se me ocurren ahora sobre la marcha

ESQUEMA GENERAL DE LA FUNCION INIT() ELEGANTE
- creacion de 3 mc's (izdaMc, centerMc, dchaMc) //centerMc = createEmpetyMovieclip(...);
- cargamos las fotos sobre los 3 movieclips desde una carpeta en tu directorio llamada fotos o asi
- colocacion de los MC's centrados en pantalla con POSICIONES RELATIVAS A LA RESOLUCION:
centerMc._x = (Stage.width-centerMc._width)/2 //asi se coloca en el centro de las X's
centerMc._y = (Stage.height-centerMc._height)/2 //ai se coloca en el centro de las Y's
izdaMc._x = centerMc._x - centerMc._width; //colocamos el izda a la izda del MC del centro
izdaMc._y = centerMc._y;
//lo mismo con la dcha, pero sumando en las X's en vez de restando
- asignacion de los prototipos con el bucle a los 3-4 Mc's

bueeeeeeno.....me parece que no me puedo explicar mas sin hacerte la web...
espero que esta vez lo consigas y que te salga un programa elegante de solo AS2

un saludo
atentamente
maije[/list]

gracias maije,
Eres un regalo,
mira, estoy tan liado que estoy en una de esas situaciones en las que crees que sabes algo y ves que no sabes nada.... entiendes a que me reviero?...., empieza a sangrarme el cerebro, y total por nada, por unos vestidos de novia.....y unos cuartos para pagar el alquiler...
creo que en el anterior no te copié todas las líneas del programación, en realidad faltaba la linea 1 donde declaro la funcion con el evento.
le tema como lo tengo montado es un clip que se llama ifoto, que contine el resto de clips, sobre los que realizo el evento y tengo que determinar la _xmouse. y de ahí creo que es el conflicto:
la funcion la hago sobre MC.mc1, el condicional tiene que detectar la posicion sobre MC.mc1 pero desplazo el MC con todos sus clips dentro.... y claro, de alguna manera, (esto funciona), pero cuando se ha desplazado, es como si la propiedad de _xmouse cambiara de valor, y no entiendo por que,
Lo que propones, creo que es bastante diferente, los clips en el primer nivel, nada de anidados dentro de otro.... por otro lado el tema de: centerMc = createEmpetyMovieclip(...); bueno, no tengo ni idea de como se utiliza....., en fin que leo y releo tu magistral explicación y mis sesos se derriten.
Estoy por pasar al plan B que es el mas guarro de todos, lo de poner un boton derecho y otro izquierdo dentro de cada clip y a tomar por....
en fin, que estamos a mitad de mes y como siga a si este mes mi casero me tira a la calle... por falta de pago....
salud y libertad,
onofre
por cierto este es el código corregido y lo hago para cada clip anidado..... me gusta escribir.....

ifoto.foto1.onRelease = function() {
f (_root._xmouse<ifoto.foto1._x+(ifoto.foto1._width/2)) {
var twMove:Tween = new Tween(ifoto, "_x", None.easeInOut, ifoto._x, -855, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto1, "_alpha", None.easeInOut, this.ifoto.foto1._alpha, 20, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto2, "_alpha", None.easeInOut, this.ifoto.foto2._alpha, 100, 0.6, true);
var twescala:Tween = new Tween(imascara, "_yscale", None.easeInOut, imascara._yscale, 98, 0.6, true);
trace("primera mitad");
} else if (_root._xmouse>=ifoto.foto1._x+(ifoto.foto1._width/2)) {
var twMove:Tween = new Tween(ifoto, "_x", None.easeInOut, ifoto._x, 00, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto1, "_alpha", None.easeInOut, this.ifoto.foto1._alpha, 100, 0.6, true);
var twAlfa:Tween = new Tween(this.ifoto.foto2, "_alpha", None.easeInOut, this.ifoto.foto2._alpha, 20, 0.6, true);
var twescala:Tween = new Tween(imascara, "_yscale", None.easeInOut, imascara._yscale, 150, 0.6, true);
trace("segunda mitad");
}
};

ok onofrebachiller
no te preocupes, vamosa hacerlo de una forma un tanto chapucerilla, pero hay que pagar el alquiler y oye, tampoco hace falta que cuando empezamos con un programa hagamos cosas optimizadas, porque si fuera asi, no soltariamos una web hasta 1 año despues, y de eso no se come
vamos a hacerlo de la siguiente manera, te explico paso a paso como si fuera un tutorial, espero, lo mas sencillo posible y empezando de 0, pero de 0 eh? no te me adelantes

1º. abrimos el flash y creamos un nuevo documento.
2º. en propiedades de la pagina, dale de dimensiones 700x525 (es un tamaño proporcional a 800x600, pero mas pequeño)
3º. le damos un color de fondo neutro y coherente con tu pagina, mira a ver algun pastel, por el tema novias
4º. ahora importamos a nuestra biblioteca (arrastrando las imagenes directamente desde el explorador a la biblioteca) las imagenes que queremos que conformen el cuadro
5º. las arrastramos desde la biblioteca al escenario y las colocamos todas en linea, a la misma altura, 'y' en sus propiedades
6º. en la parte superior de la linea de tiempo tedras una lista desplegable que pone 100%, oks, cambia eso por "mostrar todo"
7º. ahora que ves todas las imagenes que tienes en el escenario, seleccionalas todas empleando la tecla shift (mayus)
8º. click derecho sobre la seleccion y en el menu contextual que te sale, elige convertir en simbolo, y luego clip de pelicula. despues de crear el elemento, dale nombre cuando lo tengas seleccionado en el panel de propiedades.

genial, ya tenemos el clip de pelicula con todas las imagenes seguidas, ahora vamos a moverlo en la capa acciones

9º. ahora, a la izda de la linea de tiempo, da doble click sobre donde pone "Capa 1". renobra esa capa como "componentes"
10º. crea una nueva capa clickeando en la misma ventana, en la parte inferior donde aparece una hoja con un simbolo de + en azul y renombrala igual que la anterior llamandola "acciones".
11º. selecciona la capa acciones y abre el panel de acciones, por defecto, sobre el panel de propiedades en la zona inferior
12º. ahora, en la capa acciones vamos a hacer lo siguiente: vamos a hacer un evento que detecte donde esta el raton:
- en la capa acciones (muy importante que estes en la capa acciones), panel de acciones, vamos a escribir lo siguiente:

Código :

nombreDelMCdeFotos.onRollOver = function() {
trace("sobre el MC");
}

- si eso funciona, todo va bien, si no funciona, revisa a ver los pasos anteriores.
- ahora vamos a anidar otro evento dentro del evento onRollOver de la siguiente forma:

Código :

cp1.onRollOver = function() {
   trace("entro en el MC");
   cp1.onMouseMove = function() {
      trace(_root._xmouse);
   }
}

de esta forma, solo tendra en cuenta el mouseMove cuando este sobre el clip de pelicula. espero no haberte perdido con el anidamiento. haz todaslas purebas que necesites

- ahora, lo que vamos a hacer va a ser detectar si el clip deberia moverse hacia la izda o la dcha de la siguiente forma:

Código :

cp1.onRollOver = function() {
   trace("entro en el MC");
   cp1.onMouseMove = function() {
      trace(_root._xmouse);
      if (_root._xmouse < Stage.width/2)
         trace("como el raton esta antes de la mitad, deberiamos moverlo hacia la izda");
      else
         trace("como el raton esta despues de la mitad, deberiamos moverlo hacia la dcha");
   }
}

- perfecto, ya sabemos cuando hay que moverlo y hacia donde, entonces ahora vamos a cambiar los traces por movimientos reales

Código :

cp1.onRollOver = function() {
   trace("entro en el MC");
   cp1.onMouseMove = function() {
      trace(_root._xmouse);
      if (_root._xmouse < Stage.width/2)
      {
         trace("como el raton esta antes de la mitad, deberiamos moverlo hacia la izda");
         cp1._x -= 5;
      }
      else
      {
         trace("como el raton esta despues de la mitad, deberiamos moverlo hacia la dcha");
         cp1._x += 5;
      }
   }
}

- ok, si has probado este codigo, ahora veras que el MC se mueve a la izda o dcha dependiendo de la posicion del raton, cuando muevas el raton y siempre que hayas pasado por encima del MC, pero todavia hay que solucionar varios problemas: que el MC siempre empiece centrado, que se detenga cuando llegue a un extrermo o a otro, que se mueva mas rapido cuando mas cerca de los extermos laterales este el raton, que no haga nada cuando salgas del MC y que se mueva solo sin mover el raton. los vamos a solucionar los 5 en un solo codigo, porque asi el mensaje no es "mas" kilometrico
luego te explico cada linea para que lo entiendas

Código :

cp1._x = (Stage.width - cp1._width)/2;
var sum:Number = 1;
var onMC:Boolean = false;
cp1.onRollOver = function() {
   trace("entro en el MC");
   onMC=true;
   cp1.onEnterFrame = function() {
      trace(_root._xmouse);
      if (onMC==true)
      {
         sum = Math.abs(((Stage.width/2) - _root._xmouse)/20)
         if (_root._xmouse < Stage.width/2)
         {
            //trace("como el raton esta antes de la mitad, deberiamos moverlo hacia la izda");
            if (cp1._x+cp1._width > Stage.width)
               cp1._x -= sum;
         }
         else
         {
            //trace("como el raton esta despues de la mitad, deberiamos moverlo hacia la dcha");
            if (cp1._x<0)
               cp1._x += sum;
         }
      }
   }
}
cp1.onRollOut = function() {
   onMC=false;
}

alla vamos
1º problema: que el movieclip siempre empiece centrado.
en la primera linea de codigo ves esto: cp1._x = (Stage.width - cp1._width)/2;
te explico. si coges la anchura total de la pantalla y le restas la anchura de lo que quieres meter, te dara los margenes laterales sumados, que es la diferencia de sus anchuras... pues si divides eso entre dos, tendras un margen, el del lado izquierdo por ejemplo...pues colocasla x de tu objto sobre ese valor y ya lo tienes centrado en la pantalla

2º problema: que el movieclip se detenga cuando llegue a un extremo o a otro
eso lo hacemos en estas dos lineas de codigo:
if (cp1._x+cp1._width > Stage.width)
si te fijas, lo que hago es decirle que si la posicion x del movieclip mas su anchura es mayor que la anchura total de la pantalla, quiere decir que todavia queda mc a la derecha que mostrar, asi que m lo mueva a la izquierda un poco mas
if (cp1._x<0)
y aqui, ves como digo, si la posicion x de mi MC es menor que 0, todavia queda por mostrar movieclip a la izquierda, asi que lo puedo mover un poco mas a la derecha

3º problema: que se mueva mas rapido cuanto mas cerca este de los extermos
eso lo solucionamos en 4 lineas:
var sum:Number = 1;
sum = Math.abs(((Stage.width/2) - _root._xmouse)/20)
cp1._x -= sum;
cp1._x += sum;
primero, declaro una variable sum, que sera el valor que quiro que inremente, es una variable porque su valor "variara" a lo lago de la ejecucion y debe ser mayor cuanto mas se acerque a los bordes...como lo soluciono? pues muy facil, le resto al valor de la mitad de la pantalla al valor de la x del mouse y luego divido el resultado por 20, porque si no moveria nuestro movieclip demasiado rapido y asi es mas lentito , pero puedes modificar el 20 o crear una variable que se llame velocidad y en vez de 20 poner ahi la variable y luego cuando quieras hacer cambios, cambias el valor de la variable y ya te va mas rapido o mas lento
todo esto tenia un problema, y es que si el raton estaba en el lado derecho, nos daba un numero negativo, asi que se puede solucionar de dos formas, hacer la formula despues de saber si el raton esta a la izquierda o a la derecha y cambiar el orden de los factores o utilizar la libreria Math incorporada en el flash, con su funcion abs, que convierte un numero en absoluto, sin signo y asi lo tenemos resuelto. biennnnnnn

4º problema: que no haga nada cuando salgas del MC
eso lo solucionamos con poquitas lineas de codigo:

var onMC:Boolean = false;
cp1.onRollOver = function() {
trace("entro en el MC");
onMC=true;
cp1.onEnterFrame = function() {
trace(_root._xmouse);
if (onMC==true)
...
cp1.onRollOut = function() {
onMC=false;
}

aqui lo que he hecho ha sido crear una variable booleana que medice cuando estoy y cuando no sobre el MC. entonces la declaro y la inicializo a false. luego, cuando este por encima, que sea true, y cuando salga, que este de nuevo a false. despues, en la zona de movimiento del MC, que no haga nada si esta en false...y ya esta

5º problema: que se mueva solo sin mover el raton
eso lo solucione en una linea
cp1.onEnterFrame = function() {
cambiando el evento onMouseMove por el onEnterFrame... oleeeee

entonces y como resumen: si usas el codigo final en una pelicula cuyo movieclip formado por fotos se llame cp1, te funcionara sin problemas, porque este codigo SI que lo he ido probando y testeando linea a linea , (aplausos del publico) gracias gracias...

en cuanto a tu respuesta: no te preocupes, no te agobies. nos pasa a todos que creemos que sabemos de algo y luego no tenemos ni p.ta idea y siempre habra cosas que no sepamos. lo importante es que no vayamos de sobradillos, porque siempre hay alguien que nos puede ayudar y enseñar; pero no ir de sobradillos, no quiere decir que tengamos que ir con la cabeza baja ni no atrevernos a dar nuestra opinion sobre cualquier tema. espero que esta linea de posts te haya abierto los ojos a ciertas cosas interesantes y utilies del flash como son los prototipos (que de momento no has utilizado, quizas por desconocimiento, quizas por vagueria ), pero que ya sabes que existen. has descubierto la clase Tween, que te vendra de pm en un futuro, ahora sabes que se pueden anidar eventos y encima has conseguido hacer tu web y conseguirte esos cuartos que necesitas para el alquiler, que en barna es una pasta curiosa...

NOTAS DE INTERES: se que quieres meterle un alpha a los elementos que no esten en el centro exacto, pues eso lo falseamos con dos clips con un alpha colocados a los laterales y asi la zona del centro esta visible perfectamente.
tambien se que quieres meter mas cosas, como una banda de informacion y cosas asi...no hay problema, con añadir otro clip con esa banda, colocarlo y moverlo a la vez (mas o menos cantidad en las x, eso como tu veas) que el clip de las imagenes.

un saludo, y por el numero de post que hemos cruzado y el tiempo invertido, es casi un abrazo ya
te agradeceria una mencion en la web si hay un hueco
PD: si algun moderador ve este tutorial y le parece bien, puede ponerlo en la seccion de tutoriales
atentamente
maije

me acabo de da cuenta de que se mueve al reves, entonces, solo tienes que cambiar el + por el - y viceversa en el codigo y funcionara en el sentido correcto.
te he puesto esta manera porque me parecio la que menos codigo y mas simplificado llevaba, al final ya ves...sin optimizarlo y menos de 30 lineas de codigo
disfrutalo

mije, realmente me gusta internet, pero lo que mas me gusta de este medio es encontrar gente como tu, no dudes que de una forma u otra te remarcaré cuando esté acabada esta web (dime que quieres que ponga, lo hare entre el codigo de html), he aprendido mucho de tu mano en muy poco tiempo, gracias,
Aunque eres genial en tu explicación, lamento decirte que no me funciona, he estado hasta la madrugada dandole vueltas al scrip, hasta sangrarme los ojos y no encuentro el fallo, tal vez hay algo estúpido que no veo por mas que lea y relea.Si todavía te queda un poco de paciencia, te Explico:
todo bien hasta el penultimo paso importante, es decir, el clip se mueve de mc._x+=5 y mc._x-=5
según muevas el mouse derecha o izquierda respectivamente....fácil.
el problema es cuando meto el otro codigo, el mc no se mueve en ningún sentido y a ninguna velocidad, y nisiquiera aparecen los traces, el fallo está... no se, en algún error que no logro ver, por que si anulo el escrip a partir del primer evento (linea 4 ) funciona las variables de posicion, y pocicionan el clip en la mitad,
te copio de nuevo el scrip tal y como lo tengo, creo que faltaba alguna } a lo mejor es donde he metido la gamba.
mira a ver si le puedes echar un vistacillo, anda.....
por cierto, de donde eres?
mc._x = (Stage.width-mc._width)/2;
var sum:Number = 1;
var onMC:Boolean = false;
mc.onRollOver = function() {
trace("entro en el MC");
onMC = true;
mc.mouseMove = function() {
trace("_root._xmouse");
if (onMC == true) {
sum = Math.abs(((Stage.width/2)-_root._xmouse)/20);
if (_root._xmouse<Stage.width/2) {
trace("como el raton esta antes de la mitad, deberiamos moverlo hacia la izda");
if (mc._x+mc._width>Stage.width) {
mc._x -= sum;
} else {
trace("como el raton esta despues de la mitad, deberiamos moverlo hacia la dcha");
if (mc._x<0) {
mc._x += sum;
}
}
}
}
};
};
*/
mc.onRollOut = function() {
onMC = false;
};

buenas
acabo de meter tu codigo en una apliacion igual, con un MC igual que el que tenia para pruebas, pero llamandolo mc como tu en tu codigo y efectivamente me ha dado un error:

**Error** Escena=Escena 1, capa=Capa 1, fotograma=1:Línea 25: Se ha detectado un '*' inesperado
*/

Total de errores de ActionScript: 1 Errores comunicados: 1

quitando esa etiqueta de fin de comentario ya no da el error, pero sigue sin funcionar

ya esta encontrado el error. habias puesto un evento como el siguiente mouseMove, como te lo puso en azulito, no sospechaste, pero ojoooo, era un fasle friend, eso no se usa asi ahi el evento que tu querias era el onMouseMove (fijate en el tuto como esta escrito ), con el on delante y la m de mouse en mayusculas. de todas formas, en el ultimo paso, te recomendaba el cambio de ese evento por el onEnterFrame, porque si no, solo se mueve cuando mueves el puntero, se mueve demasiado rapido y si el puntero del raton esta quieto, no se mueve, cosa que puede despistar facilmente al internauta en cuestion, y tu cliente no quiere que su posible comprador no encuentre su web facilmente navegable , aunque muchos de nuestros clientes no lo sepan

aqui te pego el codigo que funciona con tus nombres , asi que con un copy paste deberia valer

Código :

mc._x = (Stage.width-mc._width)/2;
var sum:Number = 1;
var onMC:Boolean = false;
mc.onRollOver = function() {
   trace("entro en el MC");
   onMC = true;
   mc.onEnterFrame = function() {
      trace("_root._xmouse");
      if (onMC == true) {
         sum = Math.abs(((Stage.width/2)-_root._xmouse)/20);
         if (_root._xmouse < Stage.width/2) {
            trace("como el raton esta antes de la mitad, deberiamos moverlo hacia la izda");
            if (mc._x+mc._width>Stage.width)
               mc._x -= sum;
         } else {
            trace("como el raton esta despues de la mitad, deberiamos moverlo hacia la dcha");
            if (mc._x<0) {
               mc._x += sum;
            }
         }
      }
   }
}
mc.onRollOut = function() {
   onMC = false;
   trace("salio del MC");
};

NOTAS DE INTERES:
- cuando tengas el programa completo, puedes quitar las trazas o cambiarlas por comentarios para una lectura posterior facilmente entendible
- cuando pegues codigo, hazlo entre las etiquetas [ c ode]...[/ c ode] correspondientes. en el primer post te aparecen por defecto en un boton sobre el editor conel nombre "Code"...copias tu codigo AS y lo pegas aqui, seleccionas el texto y le das a la etiqueta code, automaticamente te coloca al principio y al final las etiquetas de codigo. el problema es que en esta web, cuando haces una respuesta rapida, no te aparece. tienes dos soluciones: escribir a mano las etiquetas, cosa que para un programador no es muy costosa o escribes una frase y le das a vista preliminar, y asi te sale la ventanita con las opciones de etiquetas aceptadas . lo digo porque lo que mas tiempo me ha llevado ha sido andar recolocando las llaves que estaban todas en linea, funcionaba, pero no sabia que bucles estaban dentro de los otros, para eso nos vale el tabulado y si no lo pones como codigo o lo escribes directamente aqui, no es entendible para los pobrecitos que tenemos que entender codigo .
- otro consejo interesante es que cuando te bajes codigo que esta probado, lo copies exactamente igual en un nuevo documento, haciendo los pasos que te indican (en eset caso crear en MC en tu pantalla y darle un nombre como el que aparece en el codigo). lo pruebas y ves que funciona y luego sobre esa prueba, empiezas a hacer tus modificaciones. a cada modificacion, una prueba a ver si sigue funcionando, si no funciona, ctrl+z en tu codigo y a pensartelo mejor . cuando tienes el codigo que te bajaste completamente adaptado a tu aplicacion, lo copias y lo pegas o lo dejas como modulo externo (que en la mayor parte de los casos sera lo mejor para que puedas reutilizarlo ).
- me alegra muchisimo haber podido echar un cable a alguien igual que me los echaron (y echan, aunque no tan bien como me gustaria a veces ) a mi y que hayas aprendido alguno de los escasos conocimientos que poseo y encima en poco tiempo....si es que me deberia dedicar a esto... es mucho mas agradecido que el trato con los clientes. espero de verdad que entiendas el 100% del codigo que te he puesto y que asi puedas reutilizarlo para mas aplicaciones o volver a leerlo cuando necesites hacer cosas parecidas, incluso para si te animas a hacer la version elegante que te esboce unos replies mas arriba con 4 MC's (uno de precarga y tres cargados y mostrados (cosa que a nivel de la primera carga es mucho mas rapido) todo a traves de AS2 sin parte grafica (este programa tambien se podria hacer solo con AS2, pero no he querido liarte con cositas ). otro dia nos meteremos con los loaders para que el pobre internauta de turno sepa cuanto tiempo de espera y suplicio le queda
- en respuesta a tus preguntas: soy de valladolid, y por cierto, nada orgulloso de las intervenciones en "tengo una pregunta para usted" de esos dos top10 que fueron en representacion de mi provincia...asi que por eso aprovecho para decir bien alto que tambien hay gente de mi provincia, en contra de los prejuicios acerca de "fachadolid" que existen, que no es asi de obtusa e insultantemente corta de entendederas (despues de esa pequeña cuña politica, sigo respondiendo ). en cuanto a lo de los agradecimientos, eso lo dejo a tu libre eleccion, pero podria ser algo como esto:

Código :

<html>
<head>
<!--Agradecimientos a la inestimable ayuda ( :P ) blablabla Jaime Finat (maije) [email protected]-->

</head>
<body>
hola
</body>
</html>

disculpa que no ponga mi segundo apellido, ya sabes que el tema de privacidad por internet es una cosa complicada y ya me ha costado poner mi mail de curro como para encima poner mi segundo apellido...
me parece que no me dejo nada en el tintero. a final, a ver si conseguimos entre los dos tener lista tu web para finales de mes y como el casero te diga algo, me paso por ahi y le comento lo que pienso de los insultoIndefinido+"azos" que viven de las rentas y que encima quieren ser ricos y no trabajar *odiendo a los jovenes que solo necesitamos una pequeña oportunidad para vivir nuestra vida... y si eso no funciona, llevo ya bastantes año haciendo artes marciales como para saber como convencer a mucha gente de lo que les conviene
joder como me pongo de camorrista...pero es un tema que me toca de cerca, ya sabes

un saludo
espero que esta vez lo consigas. animo
atentamente
aqui tienes un acertijo que pondra a prueba tu dislexia: maije (jaime = maije => j <-> m)

no se si al final lograste terminarlo todo a tiempo (todavia te queda el dia de hoy segun entendi), espero que si. por mi parte, me gustaria ver como quedo al final la web con esas cositas... es una chorrada, pero ya sabes, me pongo tontito y me gusta ver trabajos finales en los que he intervenido o ayudado y por supuesto, hacer critica constructiva y aconsejar para futuros curreles. asi que si puedes linkearme la url de la web y asi le echo un vistazo y te comento que me parece comodo y que cosas se pueden mejorar.
bueno, pos eso. pasalo bien y ya me cuentas

un saludo
atentamente
maije