Problema con mp3 en Flash MX 2004 usando MediaPlayBack

Hice todo el procedimiento que indicaba el tutorial, pero no se como hacer para que ejecute automaticamente y que las canciones siguan su curso automatico, por favor que alguen me ayude.

Un saludo

Gracias

a que tutorial te refieres, y que deseas hacer concretamente

El tutorial es "Reproductor mp3 en Flash MX 2004 usando MediaPlayBack y List ", que esta aqui en cristalab y la idea es que cuando el usuario ingrese a la pagina automaticamente empiece a reproducirse la primera cancion, y que no tenga la necesidad de estar clickeando el titulo de cada una de las canciones si no que todas suenen automaticamente.

Un saludo

Gracias

Creo que alguien del foro hizo eso, usa la búsqueda a ver si lo encuentras.

Deu!!

bueno si te lo dice elcash...

pero si lo que quieres una reproducion automatica y aletoria sin posibilidades de seleccion..
aqui tienes este tutorial el codigo es muy sencillo, ya que no usa xml, ni componentes, ni na de na.

carga_aleatoria_controlada_de_mp3_en_flash

ya se que se puede mejorar este tutorial, estoy en ello..

No obstante, ojeare el tutorial...
haber que aprendemos...
...con el permiso de elcash

una pregunta silvestre: el codigo para que has puesto para la reproduccion automatica y aleatoria en que parte lo tengo que poner, ya que quise colocar el codigo en el archivo que figura en el tutorial "Reproductor mp3 en Flash MX 2004 usando MediaPlayBack y List" y nada. espero que me ayuden conesto please

vale, debes comprender que son dos codigos diferentes, pero aun asi se podrian implementar, lo que ocurre es que yo no se mucho de componentes, y por tanto no sabria como hacerlo.

No obstante si que podria usar la lista de canciones ya que estas se contienen en un array, y por tanto estraer de las canciones de ahí.

lo que no se, es si se podria crear un boton en el componente que fuera el que ejecutara la reproduccion automatica. Eso seria lo ideal.

otra solucion casera seria crear un boton externo al componente que ejecutara la accion.

Bueno, veré a ver si consigo hacer eso que pides, de todas formas es algo que seguro pide más gente en un futuro, así que por implementarlo no pasa nada

Deu!!

Mira, ya lo tengo, la verdad que era bastante mas facil de lo que me pensaba, jeje.

Pruebalo y me dices a ver si te da algún error, simplemente cambia tu codigo actual por este y listos.

Código :

import mx.controls.List;
import mx.controls.MediaPlayback;

//Cargamos el XML
canciones = new XML();
canciones.ignoreWhite = true;
canciones.onLoad = function(success){
   if (success){
      //Shortcuts
      nCancion = 0;
      cancion = canciones.firstChild;
      num_total = canciones.firstChild.childNodes.length;
      
      //Creamos y llenamos la lista
      crearLista();
      //Creamos el reproductor
      crearPlayer();
      //Comenzamos a reproducir por la primera canción
      iniciar();
   }
   else{
      trace("No se pudo cargar la lista de canciones");
   }
}
canciones.load("lista.xml");

///////////////////////////////////////////////////////////////////
///////////////////////////  LISTENERS  ///////////////////////////
///////////////////////////////////////////////////////////////////

lista.addEventListener("change", alCambiar);
player.addEventListener("complete", alTerminar);


///////////////////////////////////////////////////////////////////
///////////////////////////  FUNCIONES  ///////////////////////////
///////////////////////////////////////////////////////////////////

function iniciar(){
   //Seleccionamos la primera canción y ejecutamos
   lista.selectedIndex = nCancion;
   player.setMedia("musica/"+lista.selectedItem.data, "MP3");
   player.play();
}


function crearLista(){
   //Posicionamos la lista de las canciones
   lista.setSize(180,200);
   lista._x = 220;
   lista._y = 0;
   
   //Llenamos la lista con las canciones
   misDatos = new Array();
   lista.dataProvider = misDatos;
   
   for (var i=0; i<num_total; i++) {
      misDatos.addItem({label: cancion.childNodes[i].firstChild, data: cancion.childNodes[i].firstChild}); 
   }
}

function crearPlayer(){
   //Posicionamos el reproductor
   player.setSize(200,200);
   player._x = 0;
   player._y = 0;
   
   //Propiedades del reproductor
   player.controllerPolicy = "on";
   player.mediaType = "MP3";
}

//Cuando cambiamos la canción seleccionada en la lista... cargamos la nueva canción, y ejecutamos
function alCambiar (objeto){
   if (objeto.type == "change"){
      player.setMedia("musica/"+lista.selectedItem.data, "MP3");
      player.play();
   }
};

function alTerminar(objeto){
   //Pasamos a la siguiente canción
   nCancion++;
   lista.selectedIndex = nCancion;
   
   //Si hemos llegado a la última pasamos a la primera
   if (nCancion == num_total){
      lista.selectedIndex = 0;
   }
   
   player.setMedia("musica/"+lista.selectedItem.data, "MP3");
   player.play();
}

Deu!!

PD: Qué código tan viejo y feo, no parece ni mío