problema para redimensionar imagen cargada con loadMovie

como dije tengo un problema para redimensionar imagenes cargada con loadMovie, tambien intente con onData

Código :

function cargar_imagen() {
   visor.removeMovieClip();// remuevo la imagen anterior
   this.createEmptyMovieClip("visor", 1);
   visor.loadMovie("img/mini/"+img);//la imagen carga con su tamaño original 
//   visor.onData = function(){
   prueba.text = visor._width+" , "+visor._height;//esta linea imprime: 0 , 0
   if (visor._width>=300 || visor._height>=230) {
      while (visor._width>=300 || visor._height>=230) {
         visor._width *= 0.5;
         visor._height *= 0.5;
      }
   }
//   }; 

}

[/code]

utiliza un movieClipLoader en vez de loadMovie y el evento onInit del MovieClipLoader

1- onInit significa onLoadInit()
2- despues de un afortunado insomnio resolvi la galeria
3- ¡¡¡CONEJO ERES MI HEROE !!!
4- y ultimo

Lo que sucede es que cuando usas el metodo MovieClip.loadMovie() Flash reemplaza el contenido TOTAL del movie clip en cuestion, con esto se van tus MovieClip.onData, MovieClip.onLoad es por eso que debe usar otro MovieClip. La logica del MovieClipLoader es simple.

Código :

// Creas el MovieClip que va a cargar la movie/imagen.
_root.createEmptyMovieClip("targetMovieClip", _root.getNextHighestDepth());

// Creas un objeto Listener que sera quien haga las operaciones luego de la carga.
var myListener:Object = new Object();
myListener.onLoadInit =  function(mc:MovieClip):Void {
  // Aqui van tu codigo. 
  // Imprimamos el tamaño.
  trace(mc._width + " " + mc._height);
};

// Creas tu MovieClipLoader, le indicas quien va a escuchar la carga y que quieres cargar.
var myLoader:MovieClipLoader = new MovieClipLoader();
myLoader.addListener(myListener);
myLoader.loadClip("movie.swf", _root.targetMovieClip);

Tambien puedes usar los metodos de linea de tiempo en el clip.
onClipEvent (load) {} y onClipEvent (data) {}

Puede que te resulte mas facil hacer lo ultimo, pero como que yo lo veo, es desordenado tener codigo por todas partes.

Suerte.