Problemas al cargar imagenes con efectos en un diseño liquid

Buenas, explico mi problema. Tengo una pelicula que se adapta a la resolucion de la pantalla esto me funciona bien el problema es cuando kiero cargar unas imagenes en forma dinamica no ma aparecen hasta que cambio el tamaño de la pelicula .

este es mi codigo

Código ActionScript :

import ImgLoop;

var fondoLoop:ImgLoop = new ImgLoop(this);

fondoLoop.push("imagen/principal/1.jpg");
fondoLoop.push("imagen/principal/2.jpg");
fondoLoop.push("imagen/principal/3.jpg");
fondoLoop.push("imagen/principal/4.jpg");


fondoLoop.setPosicion(0,0);
fondoLoop.setTiempo(4000);//3 segundo
fondoLoop.start();

_root.fondo_mc.contenedor1._width = Stage.width;
_root.fondo_mc.contenedor1._height = Stage.width*0.75;


Stage.align = "TL";
Stage.scaleMode = "noScale";
var miListener:Object = new Object();
miListener.onResize = function() {

   
   
   
      _root.fondo_mc.contenedor1._width = Stage.width;
      _root.fondo_mc.contenedor1._height = Stage.width*0.75;

};
Stage.addListener(miListener);
miListener.onResize();

y esta es la clase la encontre en este mismo foro la que ocupando para el efecto de las imagenes y cargarlas.

Código ActionScript :

/*****************************************************************************
CLASE ImgLoop v.1.5 - 21/10/06
package img
funcion: loop de fotos.
autor: [email protected] || http://www.zguillez.com

uso: var fondoLoop:ImgLoop = new ImgLoop(this);

guia:
-La clase trabaja con un Array(). Este array contiene las URLS de las fotografias.
-Cuatro diferentes tipos de añadir fotos al Array():
1. Una a una: fondoLoop.push("http://www.cristalab.zguillez.com/LoopIMG/foto1.jpg");
2. Por xml: fondoLoop.pushXML("http://www.cristalab.zguillez.com/LoopIMG/fotos.xml");
3. Por secuencia de archivos: fondoLoop.loadSec("foto", ".jpg", 1, 5);
4. Por secuencia indefinida (busca en el servidos hasta encontrar la última foto)
   fondoLoop.loadSec("foto", ".jpg", 1);

funciones publicas:
setTiempo(queTiempo)
setPosicion(queX, queY)
start()
stop()
pause()
push(queURL)
pushXML(queXML:String) 
pop(queURL) 
shift(queURL)
unshift(queURL)
trace()
clear() 
exit()
loadSec(queRaiz:String, queExtension:String, queNum:Number, queFin:Number)

ejemplo:
import img.ImgLoop
var fondoLoop = new ImgLoop(this);
fondoLoop.pushXML("fotos.xml");
fondoLoop.setPosicion(0, 0);
fondoLoop.setTiempo(3000);
fondoLoop.start();
******************************************************************************/
class ImgLoop
{
   private var ruta:MovieClip;
   private var listaFotos:Array;
   private var tiempo:Number;
   private var isPaused:Boolean;
   private var contenedor:MovieClip;
   private var paseDeFotos:Number;
   private var foto:Number;
   private var i:Number = 0;
   public var onLoadComplete:Function;
   //-------------------------
   public function ImgLoop(queRuta)
   {
      
      ruta = (queRuta == undefined) ?  _root.fondo_mc : queRuta;
      contenedor = _root.fondo_mc.createEmptyMovieClip("contenedor1",_root.fondo_mc.getNextHighestDepth());
      contenedor.createEmptyMovieClip("contenedor1",contenedor.getNextHighestDepth());
      contenedor.createEmptyMovieClip("contenedor2",contenedor.getNextHighestDepth());
        
      listaFotos = new Array();
      setTiempo(2000);
      foto = 0;
      
      contenedor.precarga = new MovieClipLoader();
      contenedor.precarga.onLoadComplete = function(cont:MovieClip)
      {
         cont.onEnterFrame = function()
         {
            if (this._alpha < 100)
            {
               this._alpha += 10;
            }
            else
            {
               delete this.onEnterFrame;
            }
         };
      };
   }
   public function setTiempo(queTiempo)
   {
      tiempo = queTiempo;
   }
   public function setPosicion(queX, queY)
   {
      contenedor._x = queX;
      contenedor._y = queY;
   }
   public function start()
   {
      contenedor.contenedor2._alpha = 0;
      contenedor.precarga.loadClip(listaFotos[foto],contenedor.contenedor2);
      paseDeFotos = setInterval(this, "SiguienteImagen", tiempo);
   }
   public function stop()
   {
      clearInterval(paseDeFotos);
   }
   public function pause()
   {
      isPaused = !isPaused;
      isPaused == true ? this.stop() : this.start();
   }
   public function push(queDato)
   {
      switch (typeof (queDato))
      {
         case "string" :
            var extension:String = queDato.substr(queDato.length - 3, 3);
            switch (extension)
            {
               case "xml" :
                  var ruta = this;
                  var xmlFotos:XML = new XML();
                  xmlFotos.ignoreWhite = true;
                  xmlFotos.load(queDato);
                  xmlFotos.onLoad = function(success:Boolean)
                  {
                     if (success)
                     {
                        var xmlNodo:XML = this.firstChild;
                        var total:Number = xmlNodo.childNodes.length;
                        for (var i:Number = 0; i < total; i++)
                        {
                           ruta.listaFotos.push(xmlNodo.childNodes[i].firstChild.nodeValue);
                        }
                     }
                  };
                  break;
               default :
                  listaFotos.push(queDato);
                  break;
            }
            break;
         case "object" :
            listaFotos = queDato;
            break;
      }
   }
   public function pop(queURL)
   {
      listaFotos.pop(queURL);
   }
   public function shift(queURL)
   {
      listaFotos.shift(queURL);
   }
   public function unshift(queURL)
   {
      listaFotos.unshift(queURL);
   }
   public function trace()
   {
      trace(listaFotos);
   }
   public function remove(queDato)
   {
      switch (typeof (queDato))
      {
         case "number" :
            var temp1:Array = listaFotos.slice(0, queDato - 1);
            var temp2:Array = listaFotos.slice(queDato, listaFotos.length);
            listaFotos = temp1.concat(temp2);
            break;
         case "string" :
            for (var num in listaFotos)
            {
               if (listaFotos[num] == queDato)
               {
                  remove(Number(num) + 1);
               }
            }
            break;
      }
   }
   public function clear()
   {
      clearInterval(paseDeFotos);
      listaFotos = [];
      SiguienteImagen();
      SiguienteImagen();
   }
   public function exit()
   {
      removeMovieClip(ruta.contenedor1);
      removeMovieClip(ruta.contenedor2);
      clearInterval(paseDeFotos);
      listaFotos = [];
   }
   public function loadSec(queRaiz:String, queExtension:String, queNum:Number, queFin:Number)
   {
      var num = queNum;
      var raiz = queRaiz;
      var ext = queExtension;
      if (queFin == undefined)
      {
         var scope = this;
         var url:String = raiz + num + ext;
         contenedor.precarga.loadClip(url,contenedor.contenedor2);
         contenedor.precarga.onLoadStart = function(mc:MovieClip)
         {
            contenedor.precarga.unloadClip(mc);
            num++;
            scope.loadSec(raiz,ext,num);
            scope.listaFotos.push(url);
         };
         contenedor.precarga.onLoadError = function(mc:MovieClip, error:String)
         {
            if (error == "URLNotFound")
            {
               scope.contenedor.precarga.onLoadStart = null;
               scope.onLoadComplete();
            }
         };
      }
      else
      {
         for (var i:Number = queNum; i <= queFin; i++)
         {
            var url:String = raiz + i + ext;
            listaFotos.push(url);
         }
         this.onLoadComplete();
      }
   }
   //--------------------
   private function SiguienteImagen()
   {
      (foto < (listaFotos.length - 1)) ? foto++ : foto = 0;
      var cont:MovieClip = contenedor.getInstanceAtDepth(contenedor.getNextHighestDepth() - 2);
      cont.swapDepths(contenedor.getInstanceAtDepth(contenedor.getNextHighestDepth() - 1));
      cont._alpha = 0;
      contenedor.precarga.loadClip(listaFotos[foto],cont);
   }
}

y aca les dejo el codigo para la descarga http://www.rmksoluciones.com/fotos.rar

desde ya les agradesco por su tiempo y ayuda gracias

haaaa se me olvidava las imagenes se muestran como fondo y van cambiando estas tambien se adecuan al tamaño de la ventana