redimensionar imagen en movieclip

buen dia con todos kisiera saber como redimensionar un movieclip e estado intentando muchas cosas pero aun no se como hacerlo alguien em ayuda x ejemplo.

Código ActionScript :

private function CargarThumbs():void
         {
            ldr = new Loader();
            ldr.load(new URLRequest("./thumb/" + xml.foto.attributes()[leer]));
            tb.addChild(ldr);
            Click(leer);
         }

ven solo esta llmando peor como hago para redimensionarla gracias de antemano T_T;

Puedes crear una funcion que se encargue de redimensionar la imagen , algo que tambien no entiendo es por que nunca agregan los listeners al Loader, para ser mas especificos al "contentLoaderInfo", en fin.. un ejemplo sencillo:

Código ActionScript :

//contenedor para nuestra imagen
var container:MovieClip = new MovieClip();
addChild(container);

//creamos un simple cuadro blanco con las dimesiones cualquiera..
//este nos servira como un marco para nuestra foto
var shape:Shape = new Shape();
shape.graphics.beginFill(0xFFFFFF);
shape.graphics.drawRect(0, 0, 400, 300);
shape.graphics.endFill();
container.addChildAt(shape,0);

//objeto loader
var image:Loader = new Loader();
image.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);

//handler del evento complete
function onComplete(evt:Event):void
{
   //una pruba para saber las dimensiones de nuestra imagen
   trace("photo width:",image.content.width, "photo height:",image.content.height);
   /*creo un objeto Bitmap del content del Loader que es el que contiene la imagen
   este puede tambien hacerse a si photo = image.content as Bitmap.. yo lo he echo 
   de esta otra forma*/
   var photo:Bitmap = new Bitmap(Bitmap(image.content).bitmapData);
   /*llamo a la funcion , le paso como parametro el bitmap y el factor de la escala en
   ese caso 2 para redimensionarla a la mitad de su tamaño original*/
   photoResize(photo,2);
}

//cargamos la imagen
image.load(new URLRequest("photo.jpg"));

function photoResize(pObject:Bitmap,pScale:Number):void
{
   //usamos la propiedad smoothing que evita bugs,pixeleados.. y por ultimo ajustamos las
   //dimensiones de la imagen
   pObject.smoothing = true;
   pObject.scaleX = pObject.scaleY = 1 / pScale;
   
   //ajusto el tamaño del marco..solo para dar un poco de diseño.. =)
   shape.width = pObject.width + 10;
   shape.height = pObject.height + 10;
   //agrego el bitmap al contenedor 
   container.addChild(pObject);
   //ajusto posiciones
   pObject.x = (shape.width - pObject.width)/2;
   pObject.y = (shape.height - pObject.height)/2;
   container.x = (stage.stageWidth - container.width )/2;
   container.y = (stage.stageHeight - container.height )/2;
   //por ultimo una prueba para saber las dimensiones actuales de nuestra foto
   trace("photo width:",pObject.width, "photo height:",pObject.height);
}

espero te sirva, suerte.


Jonathan

gracias amigo me sirvio de mucho tu codigo, lo necesitaba, muy bien explicado, gracias por ayudarme aun soy un poco Junior en la programacion de action script T_T.

gracias x el apollo.