Reset al no mover el ratón

Hola a todos,

estoy bastante perdido y me gustaría saber si alguien podría ayudarme.

Lo único que quiero hacer es que cuándo el flash no detecte movimiento de ratón en un minuto por ejemplo, se reinicie. ¿Cómo se podría hacer esto en ActionScript 2.0?

Gracias y espero vuestras respuestas, que realmente necesito.

El código para detectar cuanto tiempo ha pasado desde que no se mueve el ratón es sencillo:

Código ActionScript :

// Esta variable guardará el momento en el
// que se ha movido el ratón por última vez
var inicio:Number = getTimer();

// Esta función se ejecutará constantemente
this.onEnterFrame = function(){

   // Si han pasado 60.000 milisegundos o más (1 minuto)...
   if(getTimer()-inicio >= 60000){

      // Se realizan las siguientes acciones
      trace("Han pasado más de 60 segundos!");

      // (Opcional) Se actualiza la variable "inicio", evitando
      // así que las acciones se repitan constantemente
      inicio = getTimer();

   }

}

// Esta función se ejecutará cada vez que se mueva el ratón
this.onMouseMove = function(){

   // Se actualiza la variable "inicio"
   inicio = getTimer();

}

La función getTimer() devuelve el los milisegundos que han pasado desde que se inició la reproducción de la película.

Donde he puesto el trace(...), tú pondrías tu código para reiniciar la película.

Muchísimas gracias nestor

Otra duda, este código, si lo incluyo en una película con varias escenas, ¿es necesario que lo introduzca en cada escena o con que este en la primera es suficiente?

Gracias de nuevo.

Sólo es necesario que lo incluyas en la primera escena.

En todo caso, si vas a poner varias escenas y deseas que se vuelva al primer fotograma, te recomiendo que le pongas un nombre al fotograma (por ejemplo, "fotogramaInicial"), quedando el código de esta forma:

Código ActionScript :

// Esta variable guardará el momento en el 
// que se ha movido el ratón por última vez 
var inicio:Number;

// Esto evitará que, si la película se repite, no se actualice "inicio" si no se ha movido el ratón
if(inicio == undefined)
   inicio = getTimer();

// Esta función se ejecutará constantemente 
this.onEnterFrame = function() {

   // Si han pasado 60.000 milisegundos o más (1 minuto)... 
   if (getTimer() - inicio >= 5000) {

      // Se realizan las siguientes acciones 
      this.gotoAndPlay("fotogramaInicial");

      // (Opcional) Se actualiza la variable "inicio", evitando 
      // así que las acciones se repitan constantemente 
      inicio = getTimer();

   }

};
// Esta función se ejecutará cada vez que se mueva el ratón 
this.onMouseMove = function() {

   // Se actualiza la variable "inicio" 
   inicio = getTimer();

};

Gracias de nuevo.