Como puedo generar un evento pasados X segundos?

Hola!! estoy haciendo una pagina web en Flex en donde necesito ejecutar un evento pasados 5 segundos, pero no se como, ya intente con el evento Timer, pero no le entiendo muy bien a como manejarlo, me podrian ayudar diciendome q debo utilizar, si no es mucha molestia con un pequeño ejemplo.

de Antemano gracias y saludos.

Para usar un Timer:

Código ActionScript :

//El primer parámetro del Timer es el intervalo de tiempo en milisegundos
//El segundo parámetro es el nº de veces que se repetirá (si no pones nada se repetirá indefinidamente)
var timer:Timer = new Timer(5000, 10);
//Evento que se ejecutará cada intervalo de tiempo
timer.addEventListener(TimerEvent.TIMER, timerHandler);
//Evento que se ejecutará al completarse todas las repeticiones (salvo que hayamos hecho que se repita indefinidamente):
timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerCompleteHandler);
//Iniciamos el timer:
timer.start();

function timerHandler(event:TimerEvent):void
{
   var t:Timer = event.target as Timer;
   trace(t.currentCount);
}

function timerCompleteHandler(event:TimerEvent):void
{
   trace("El timer ha ejecutado todos los ciclos");
}

Muchas gracias!!! es lo que buscaba, pero ahora me surge un problema, no funciona como pense q podia funciona (valga la redundancia) por ejemplo al pulsar un boton, le puedo pasar el evento clic para que llame la funcion, o tengo q crear un listener que espere el evento clic y d ahi con el listener llamar la funcion. Disculpen si soy un poco ignorante, pero soy principiante en flex.

Perdona, leí demasiado rápido tu post y te puse un ejemplo para Flash en lugar de Flex. Aquí te dejo uno en el que al pulsar un botón al cabo de 5 segundos se muestra un Alert:

Código Flex :

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" xmlns:utils="flash.utils.*">
   <mx:Button id="timerButton" label="Timer" mouseDown="timerButtonMouseDown(event);"/>
   
   <mx:Script>
      <![CDATA[
         import flash.utils.Timer;
         import flash.events.TimerEvent;
         import mx.controls.Alert;
         
         private var timer:Timer = new Timer(5000, 1);
         
         private function timerButtonMouseDown(event:MouseEvent):void
         {
            timerButton.enabled = false;
            timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerCompleteHandler);
            timer.start();
         }
         
         private function timerCompleteHandler(event:TimerEvent):void
         {
            timer.removeEventListener(TimerEvent.TIMER_COMPLETE, timerCompleteHandler);
            Alert.show("Ya han pasado los 5 segundos", "TIME UP");
         }
      ]]>
   </mx:Script>
</mx:Application>

jaja!!! Muchas gracias por tu ayuda.

Saludos y d nuevo gracias.