Flash 6 A Flash9

Buenas tardes a todos , ante nada gracias por ayudarme
Tengo un archivo flash en una de mis webs que esta copilado como flash6 eso creo, el problema en si es que en los nabegadores no se puede ver
el codigo actionscript que tengo es el siguiente:

Código ActionScript :

//Action Frame 2

requiredVersion = 9;
version = getVersion();
flash_ver = version.split(" ");
if (flash_ver[1].charAt(0)-0>=requiredVersion) {
   gotoAndPlay(4);
}


//Action Frame 3 y Frame 14

stop();

//Preloader

onClipEvent (load) {
   if (_parent.getBytesTotal()<1000) {
      fileSize = Math.floor(_parent.getBytesTotal())+"bytes";
   } else if (_parent.getBytesTotal()>1000000) {
      fileSize = math.floor(_parent.getBytesTotal()/1000000)+"mb";
   } else {
      fileSize = math.floor(_parent.getBytesTotal()/1000)+"k";
   }
   message = "";
}
onClipEvent (enterFrame) {
   percent = Math.floor(_parent.getBytesLoaded()/_parent.getBytesTotal()*100);
   output = percent+"% of "+filesize+" loaded";
   Bar._xscale = percent;
   if (percent==100) {
      this._visible = 0;
   }
}

//En Bound page actions:frame1

stop();

_level0.pagesAbs = this;

var pageWi = 300;
var PageHi = 400;
var pageWiHi = pageWi+pageHi;
var pivotY = pageHi/2+pageWi;
var pageColor = 0xFFFFFF;

var dir = 1;

var flipPage = 1.5;

var curPage = .5;

var maxPages = 8;

var autoStep = .05;

var dragging = false

this.attachMovie ("cornerButton", "RButton", 11);
with (RButton) {
   _x = pageWi;
   _y = -pageWi;
}
this.attachMovie ("cornerButton", "LButton", 12);
with (LButton) {
   _x = -pageWi;
   _y = -pageWi;
   _xscale = -100;
}

pageInit (flipPage, dir);

_y+=pivotY;

function makePage (targ, xQuadrant) {
   with (targ) {
      beginFill(pageColor, 100);
      moveto(0, -pageWi);
      lineto(0, -pageWiHi);
      lineTo(xQuadrant*pageWi, -pageWiHi);
      lineTo(xQuadrant*pageWi, -pageWi);
      endFill();
   }
}


function makeShade (targ, xQuadrant) {
   with (targ) {
      // Defines gradient used as shadow overlay
      var colors = [0x000000, 0x000000, 0x000000, 0x000000, 0x000000, 0x000000, 0x000000];
      var alphas = [      40,       25,       15,        5,        0,        1,        6];
      var ratios = [       0,        1,       17,       51,       89,      132,      255];
      var matrix = { matrixType:"box", x:0, y:pageWi, w:xQuadrant*pageWi, h:pageHi, r:0};
      beginGradientFill( "linear", colors, alphas, ratios, matrix );
      moveto(0, -pageWi);
      lineto(0, -pageWiHi);
      lineTo(xQuadrant*pageWi, -pageWiHi);
      lineTo(xQuadrant*pageWi, -pageWi);
      endFill();
   }
}

function makeShadow (targ, xQuadrant) {
   with (targ) {
      
      var colors = [0x000000, 0x000000, 0x000000, 0x000000, 0x000000, 0x000000, 0x000000];
      var alphas = [      40,       25,       15,        5,        0,        1,        6];
      var ratios = [       0,        1,       17,       51,       89,      132,      255];
      var maxLength = Math.sqrt((pageWi*pageWi)+(pageWIHi*pageWiHi));
      var matrix = { matrixType:"box", x:0, y:-maxLength, w:xQuadrant*pageWi, h:maxLength-pageWi, r:0};
      beginGradientFill( "linear", colors, alphas, ratios, matrix );
      moveto(0, -pageWi);
      lineto(0, -maxLength);
      lineto(xQuadrant*pageWi, -maxLength);
      lineTo(xQuadrant*pageWi, -pageWi);
      endFill();
   }
}

function setStationary() {

createEmptyMovieClip("SLPage", 1);
   if (flipPage!=1.5) {
      makePage (SLPage, -1)
      SLPage.attachMovie("print"+(flipPage-1.5), "Print", 1);
      with (SLPage.Print) {
         _x = -pageWi/2;
         _y = -pivotY;
      }
   }
   
createEmptyMovieClip("SRPage", 2);
   if (flipPage!=maxPages-.5){
      makePage (SRPage, 1)
      SRPage.attachMovie("print"+(flipPage+1.5), "Print", 1);
      with (SRPage.Print) {
         _x = pageWi/2;
         _y = -pivotY;
      }
   }
   
   var targ = dir>0 ? SLPage : SRPage;
   targ.createEmptyMovieClip("Shade", 2);
   makeShade(targ.Shade, -dir);
}

function setFlipping() {
   var targ;
   
   createEmptyMovieClip("FTPage", 3);
   makePage (FTPage, dir)
   with (FTPage) {
      attachMovie("print"+(flipPage-dir*.5), "Print", 1);
      with (Print) {
         _x = dir*pageWi/2;
         _y = -pivotY;
      }
   }
   FTPage.createEmptyMovieClip("Shade", 2);
   makeShade(FTPage.Shade, dir);
   


   createEmptyMovieClip("FBPage", 4);
   makePage (FBPage, -dir)
   FBPage.attachMovie("print"+(flipPage+dir*.5), "Print", 1);
   with (FBPage.Print) {
      _x = -dir*pageWi/2;
      _y = -pivotY;
   }
   FBPage._rotation = dir*90;
}

function setShadows() {
   var targ;
   
   this.createEmptyMovieClip("FShadow", 5);
   makeShadow(FShadow, -dir);
   FShadow._rotation = dir*45;
   
   this.createEmptyMovieClip("SShadow", 6);
   makeShadow(SShadow, dir);
   SShadow._rotation = dir*45;
}

function makeMasks() {
   
   this.createEmptyMovieClip("FBPageMask", 7);
   with (FBPageMask) {
      beginFill(0x005500, 100);
      lineto(pageWiHi, -PageWiHi);
      curveto(0, -2*PageWiHi, -pageWiHi, -pageWiHi);
      endFill();
   }
   
   FBPageMask.duplicateMovieClip("FTPageMask", 8);

   this.createEmptyMovieClip("FShadowMask", 9);
   makePage (FShadowMask, -dir);
   FShadowMask._rotation = dir*90;
   
   this.createEmptyMovieClip("SShadowMask", 10);
   makePage(SShadowMask, dir);
   FBPage.setMask(FBPageMask);
   FTPage.setMask(FTPageMask);
   FShadow.setMask(FShadowMask);
   SShadow.setMask(SShadowMask);
}

function limitBook () {
   if (flipPage==1.5) {
      SLPage._visible = 0;
      LButton._visible = 0;
      SShadow._visible = 0;
      if (dir==1) {
         FTPage.Shade._alpha = 67;
         SShadow._visible = 1;
      }else {
         FShadow._alpha = 67;
      }         
   } else if (flipPage==maxPages-.5) {
      SRPage._visible = 0;
      RButton._visible = 0;
      SShadow._visible = 0;
      if (dir==-1) {
         FTPage.Shade._alpha = 67;
         SShadow._visible = 1;
      } else {
         FShadow._alpha = 67;
      }
   }      
}

function pageInit (cp, d) {
   flipPage = cp;
   dir = d;
   setStationary();
   setFlipping();
   setShadows();
   makeMasks();
   limitBook ();
}

function flip(curVal) {
   var rot = dir*45*curVal;
   FBPageMask._rotation = FTPageMask._rotation = -rot;
   FBPage._rotation = FShadowMask._rotation = (dir*90)-rot*2;
   FShadow._rotation = SShadow._rotation=(dir*45)-rot;
}

function getPageRatio () {
   if (dragging) {
      
      pageRatio = -dir*(_xmouse-startX-dir*20)/(2*pageWi);
   } else {
      
      pageRatio>2/3 ? pageRatio += autoStep : pageRatio -= autoStep;
   }
    
   if (pageRatio<=0) {
      pageRatio = 0;
      if (!dragging) {
         flipDone();
      }
   } else if (pageRatio>=1) {
      pageRatio = 1;
      if (!dragging) {
         flipDone();
      }
   }
   return (pageRatio);
}

function startFlip (dir) {
   pageInit (curPage+dir, dir);
   startX = dir*pageWi;
   dragging = true;
   RButton._alpha=0;
   Lbutton._alpha=0;
   this.onEnterFrame = function () {
      flip(getPageRatio());
   }
}

function flipRelease () {
   dragging = false;
   if (pageRatio>2/3) {
      curPage+=2*dir;
   }
}

function flipDone () {
   this.onEnterFrame = null;
   RButton._alpha = 100;
   LButton._alpha = 100;
   if (curPage!=.5){
      LButton._visible = 1;      
   }
   if (curPage!=maxPages+.5){
      RButton._visible = 1;
   }
   
   if (pageRatio==0) {
      FShadow.removeMovieClip();
      FShadowMask.removeMovieClip();
      SShadow.removeMovieClip();
      SShadowMask.removeMovieClip();
      FBPage.removeMovieClip();
      FBPageMask.removeMovieClip();
      if (dir==1) {
         SRPage.removeMovieClip();
      } else {
         SLPage.removeMovieClip();
      }         
   } else {
      FTPage.removeMovieClip();
      if (dir==-1) {
         SRPage.removeMovieClip();
      } else {
         SLPage.removeMovieClip();
      }
   }
   FTPageMask.removeMovieClip();
}

LButton.onPress = function() {
   startFlip (-1);
}
LButton.onReleaseOutside = function () {
   flipRelease();
}
LButton.onRelease = function () {
   flipRelease();
}
RButton.onPress = function() {
   startFlip (1);
}
RButton.onReleaseOutside = function () {
   flipRelease();
}
RButton.onRelease = function () {
   flipRelease();
}

//Por ultimo get flash click

on (release) {
   getURL("http://www.macromedia.com/shockwave/download/index.cgi?P1_Prod_Version=ShockwaveFlash", "_self");
}

Se que es muchisimo, pero necesito que alguien em diga que puedo hacer

Desde ya muchas gracias a todos!!!
Caro

[BOFH]Cuando publiques AS, ponlo entre las etiquetas [*as] [*/as] (sin los asteriscos)[/BOFH]

me salio navegador con B ,... es que es mi primer post en cristalab

Primero que nada, bienvenida. En segunda, a la próxima que quieras englobar taanto código procura utilizar las etiquetas [as] ya que nos facilitara un poco la lectura.

Ahora, en cuanto a tu problema, me parece que esta en que únicamente funcionara, si tienes Flash Player 9 instalado en el navegador. Si tienes otra versión (sin importar cual sea) te mandara al profundo frame 4. Es cuestión de cambiar las primeras lineas.

Saludos!

M@U Agradezco muchísimo tu recibimiento, estoy un poco timida, igual se que de a poco se puede
en cuanto al cambio de la primer línea // requiredVersion = 9; // anterirmente decia// requiredVersion = 6; //, en base a eso yo le cambia a 9., porque lo hice? porque desde flash cs3 quiero exportarlo como una película flash 9, ya que en la actualidad es un flash6, y mi cliente me reclama que no puede ver más su books:)..
Se entiende??

M@U escribió:

y si borras esas lineas que pasa?

gcm escribió:

A eso mismo me refería, no me parece necesario fijar una versión estricta del Player para ver un contenido, a menos de que estés utilizando alguna función/herramienta exclusiva del Player que de otra manera no se reproduciría.

Pongo un ejemplo; la rotación de un objeto en su eje Z solo esta disponible para Flash Player 10+, por lo que el manejo en otra versión seria inadecuada.

Excelente chico!!!
Muchisimas gracias M@U y GCM!!

La lienea del del del actions frame 2 quedo asi:

caro escribió:

Ya esta arriba, lo estuve probando hasta recien con todo los navegadores y funciona muy bien!!!
me salvaron la vida!!!

-Ahora, por que cuando se hizo esta película hubo necesidad de hacer esta limitación??, recuerden que la pelicula original, fue adoptada de un diseño de un compañero que ya no está mas con nosotros.
-Como comente anteriormente, el cliente nos llamo para decirnos que la película swf no podía ser reproducida sin que se tuviese el flash player6...pero ahora si
MUCHISIMAS GRACIAS NUEVAMENTE!
Saludos Carolina..muy contenta!!!

Saberlo con exactitud es dificil, ya que pudo haber sido por alguna falta de incompatibilidad del Player 5 y/o anteriores con las funciones que utilizaste (quizá beginGradientFill)... O por el otro lado las pudo haber agregado para que el código asemejara mas complejidad, por que lo vio en algún lado sin saber bien por que, una orden del jefe, etc. Razones pueden ser muchas.


Lo que importa es que te funciono como esperabas, enhorabuena y otra vez bienvenida.

M@U muchas gracias por todas tus respuestas

Saludines Caro