problemita con botones

muchachosss tengo un problemilla 1 soy diseñador y no se programar un pito pero quiero hacer unos botones y el diseño me esta asi :

son 4 botones y que cuando le de a uno de ello cambie de color pero se quede asi y que si depues quiero el otro boton haga lo mismo como si se levantara y osotros detras....graciasss

La verdad ningun programador sabe programar "un pito", bueno, un par de ellos depravados si, pero bueno, hacer eso es un poco complicado, si no sabes programar, entonces podria dejarte este codigo, y talvez no le entiendas. asi que te recomiendo estudiar.

Código ActionScript :

var botones_arr:Array = [boton1, boton2, boton3, boton4];

function desactivar( aux:MovieClip ):Void
{
   for( var i in botones_arr ) if( botones_arr[i] != aux ) botones_arr[i].unpress();
}

for( var i in botones_arr )
{
   var aux:MovieClip = botones_arr[i];
   aux.selected = false;
   aux.over = function( Void ):Void
   {
      if( !this.selected )
      {
         this.gotoAndPlay("rollover");
      }      
   };
   aux.out = function( Void ):Void
   {
      if( !this.selected )
      {
         this.gotoAndPlay("rollout"); 
      }      
   };
   aux.press = function( Void ):Void
   {
      this.selected = true;
      this.gotoAndPlay("press");
   };
   aux.unpress = function( Void ):Void
   {
      this.selected = false;
      this.gotoAndPlay("pressout");      
   };
   aux.onDragOver = aux.onRollOver = aux.over;
   aux.onDragOut = aux.onRollOut = aux.onReleaseOutside = aux.out;
   aux.onRelease = function( Void ):Void
   {
      //Si estoy presionado
      if( this.selected )
      {
         //me desactivo
         this.unpress();
      }
      else// si no estoy presionado
      {
         //desactivo a mis compadres
         this._parent.desactivar( this );
         //me activo
         this.press();         
      } 
   };   
}

El codigo atras funciona con MovieClip, OJO no funciona con "botones", cada MovieClip tiene que tener 4 fotogramas al estilo de un boton, pero tienen un "stop()" en cada fotograma y ademas el nombre de los fotogramas debe ser "rollover" "rollout" "press" "pressout", que serian los estados, "simulando un boton". cada MovieClip debe tener un nombre de instancia "boton1", "boton2", "boton3" y "boton4". Estudialo y Suerte.

voy a estudiarlo aver muchasss graciassssssssss

Hola,

Intenta tambien hacer estos cambios:

Código ActionScript :

aux.onRelease = function( Void ):Void 
   { 
      //Si estoy presionado 
      if( this.selected ) 
      { 
         //me desactivo 
         //this.unpress(); No me puedo auto desactivar
      } 
      else// si no estoy presionado 
      { 
         //desactivo a mis compadres 
         this._parent.desactivar( this ); 
         //me activo 
         this.press();          
      }  
   }; 

Suerte.

mira asi va quedando la pagina gr4aciasss

http://maderaymuebles.net/

LongeVie escribió:

se ve bien, con un par de ajustes como por ejemplo, que "Entrar" no se quede por ahi, y listo. Suerte.