Comunidad de diseño web y desarrollo en internet online

tengo problemas con mi Arreglo en XML y AS3

Citar            
MensajeEscrito el 24 Mar 2013 01:08 am
ERROR (tengo las fotos guardadas en una carpeta imagenes) (con el nombre correcto de cada una)

Error #2044: IOErrorEvent no controlado: text=Error #2035: No se encuentra la dirección URL.
Error #2044: IOErrorEvent no controlado: text=Error #2035: No se encuentra la dirección URL.
Error #2044: IOErrorEvent no controlado: text=Error #2035: No se encuentra la dirección URL.
Error #2044: IOErrorEvent no controlado: text=Error #2035: No se encuentra la dirección URL.

aqui el arreglo XML

Código XML :

<?xml version="1.0" encoding= "utf-8"?>
<imagenes>
      <imagen>
         <titulo>Mueble Tronco</titulo>
         <archivo>foto1.jpg</archivo>
      </imagen>

      <imagen>
         <titulo>Banca Tronco</titulo>
         <archivo>foto2.jpg</archivo>
      </imagen>

      <imagen>
         <titulo>Recamara Wood</titulo>
         <archivo>foto3.jpg</archivo>
      </imagen>

      <imagen>
         <titulo> Wood</titulo>
         <archivo>foto4.jpg</archivo>
      </imagen>

</imagenes>


Código ActionScript :

import flash.display.Loader;
import flash.net.URLRequest;
import flash.events.Event;
import flash.events.MouseEvent;

var titulos:Array = new Array();// arreglo para guardar el titulo de la foto
var archivos:Array= new Array();// arreglo para guardar el nombre de las imagenes
var fotos:Array= new Array();// arreglo para guardas las imagenes cargadas
var posicion:Number=0;
var imgLoader:Loader; //cargador para las imagenes
var xmlLoader:URLLoader = new URLLoader(); //cargador para el archivo cml

//cuando termine la carga del xml que se ejecute la funcion "showXML"
xmlLoader.addEventListener(Event.COMPLETE, leerXML);

//se indica que cargue el archivo XML
xmlLoader.load(new URLRequest("galeria.xml"));
function leerXML(e:Event):void
{
   //que se ingoren los espacios en blanco entre etiquetas
   XML.ignoreWhitespace = true;
   
   //se crea una variable "imgs" y en ella se guarda toda la informacion del
   //XML que se cargo. por lo tanto a traves de esta variable se accede a la
   //informacion contenida en el XML
   var imgs:XML = new XML(e.target.data);
   //variable para manejar el ciclo for
   var i:Number;
   
   //imgs:hace referencia al XML
   //imgs.imagen: hace referencia a las etiquetas "<imagen></imagen>" que hay en el XML
   //imgs.imagen.lenght: hace referencia a la cantidad de etiquetas "<imagen></imagen>" que hay en el XML 
   for(i=0; i<imgs.imagen.length(); i++)
   {
      //se inserta en los arreglos lo que hay en las etiquetas "<titulo></titulo>"
      //y en la etoqueta "<archivo></archivo>"
      titulos.push(imgs.imagen[i].titulo.text());
      archivos.push(imgs.imagen[i].archivo.text());
   }
   
   //ciclo que va de 0 hasta la cantida de elmentos que tiene el arreglo "archivos"
   for(i=0; i<archivos.length; i++)
   {
      //se lee cada nombre de imagen que hay en el arhivo y se carga la imagen
      imgLoader= new Loader();
      imgLoader.load(new URLRequest("pics/" + archivos[i]));
      //cuando la imagen es cargada se guarda en el arreglo
      fotos.push(imgLoader);
   }
   
   btnatras.addEventListener(MouseEvent.CLICK, atras);
   btnsiguiente.addEventListener(MouseEvent.CLICK, siguiente);
   
   btnatras.buttonMode = true;
   btnsiguiente.buttonMode = true;
   muestraImagen();
}
   
   function atras(e:MouseEvent):void
   {
      //si posicion es mayor a 0 que le reste 1
      if(posicion>0)
      {
         posicion--;
      }
      else //si no que posicion sea igual al numero de elementos del arreglo menos 1
      {
         posicion =fotos.length - 1;
      }
      
      //que se muestre la imagen
      muestraImagen();
   }
   
      function siguiente(e:MouseEvent):void
   {
      //si posicion es menor a (el numero de elementos del arreglo menos 1)
      //entonces que incremente
      if(posicion<(fotos.length-1))
      {
         posicion++;
      }
      else //si no que posicion sea igual a 0
      {
         posicion = 0;
      }
      
      //que se muestre la imagen
      muestraImagen();
   }
       //funcion para mostrar la imagen
      function muestraImagen():void
      {
         //si el numero de elementos contenidos es pic es mayor a 0
         //entonces que remueva ese elemento
         if(pic.numChildren>0)
         {
            pic.removeChildAt(0);
         }
         
         pic.addChild(fotos[posicion]); // se agrega la foto en pic
         txttitulo.text = titulos[posicion]; //se agrega el titulo 
      }

Por antoniocossio

5 de clabLevel



 

chrome
Citar            
MensajeEscrito el 24 Mar 2013 05:34 pm
Dinos cual es la estructura de directorios que estas usando.

Quizás sea:
  • pics
    • foto1.jpg
    • foto2.jpg
    • foto3.jpg
    • foto4.jpg
  • galeria.xml
  • main.swf
  • index.html

Por Otaku RzO

BOFH

1890 de clabLevel

12 tutoriales
1 articulo

Genero:Masculino   Desarrollador de GAIA Bastard Operators From Hell

Lima - Perú

chrome
Citar            
MensajeEscrito el 24 Mar 2013 08:57 pm
imagenes

    foto1.jgp
    foto2.jpg
    foto3.jpg
    foto4.jpg


main.swf
galeria.xml
index.html

Por antoniocossio

5 de clabLevel



 

chrome
Citar            
MensajeEscrito el 25 Mar 2013 02:16 am
En tu código tienes:

Código ActionScript :

imgLoader.load(new URLRequest("pics/" + archivos[i]));
Debería ser:

Código ActionScript :

imgLoader.load(new URLRequest("imagenes/" + archivos[i]));

Si no te funciona, antes de esa línea agrega:

Código ActionScript :

trace(archivos[i]);
Luego pones aquí lo que te imprime para poder identificar el problema mejor.

Por Otaku RzO

BOFH

1890 de clabLevel

12 tutoriales
1 articulo

Genero:Masculino   Desarrollador de GAIA Bastard Operators From Hell

Lima - Perú

chrome
Citar            
MensajeEscrito el 25 Mar 2013 06:05 am
muchas gracias problema resuelto amigo

Por antoniocossio

5 de clabLevel



 

chrome

   Página 1 de 1

 

Cristalab BabyBlue v4 + V4 © 2011 Cristalab
Powered by ClabEngines v4, HTML5, love and ponies.