Comunidad de diseño web y desarrollo en internet online

transicion de imagenes con la clase TWEEN

Citar            
MensajeEscrito el 12 Dic 2008 05:52 pm
Gente quiero cargar imágenes a un array.. y a medida que se vallan descargando cargarlas a un movie clip.. se carga la primera y aparece asi..

Código :

 var Mostrar:Tween = new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true); 


alpha de 0 a 100; se carga la segunda y se ejecuta la transicion..

Código :

CambioAlpha = function (elClip1, elClip2) {
   var MostrarFondo:Tween = new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true);
   var MostrarFondo:Tween = new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true);
};

Cambio = function() {
//trace("clip1 es: "+_root.clip1+" // "+"clip1 es: "+_root.clip2);
if (_root.clip1<misFotos.length-1) {;
_root.clip1++;
} else {;
_root.clip1 = 0;
};

if (_root.clip2<misFotos.length) {;
_root.clip2++;
} else {;
_root.clip2 = 1;
};

CambioAlpha(misFotos[clip1],misFotos[clip2]);
};

.. ahora.. lo que tengo hecho es cargadas las imagenes en el fla y solo cambio las alpha.. para cargarlas y que se ejecute la function a medida q se van cargando.. nose me ocurre.. toy en eso. cualquier ayudita va a ser bienvenida.. gracias

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

firefox
Citar            
MensajeEscrito el 12 Dic 2008 07:30 pm
hice esto..hasta el momento. aver si a alguien le dá para tomarse un segundito.. esta todo muy claro.. pero no encunentro el error. no carga las imagenes

Código :

_root.clip1 = 0;
_root.clip2 = 1;
_root.segundos = 90;

//--------------------------------------------------------
// Creo Arrays:

var misFotos:Array = new Array("Fotos/1.jpg", "Fotos/2.jpg", "Fotos/3.jpg", "Fotos/4.jpg", "Fotos/5.jpg", "Fotos/6.jpg");
var cargoFotos:Array = new Array();

//--------------------------------------------------------
// Cargo misFotos en EmptyMovieClips:

for (i=0; i<misFotos.length; i++) {
   
   _root.createEmptyMovieClip("cargo"+i,_root.getNextiglestDepth());
   cargoFotos[i] = eval("_root.cargo"+i);
   loadMovie(misFotos[i], cargoFotos[i]);
   cargoFotos[i]._alpha = 0;
   
   trace(cargoFotos[i]);
}


//--------------------------------------------------------
// Importo clase Tween:

import mx.transitions.Tween;
import mx.transitions.easing.*;

//--------------------------------------------------------
// Función que transiciona imágenes:

CambioAlpha = function (elClip1, elClip2) {
   var MostrarFondo:Tween = new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true);
   var MostrarFondo:Tween = new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true);
};


//--------------------------------------------------------
// Recorro el array y transiciono:

Cambio = function() {;

trace("clip1 es: "+_root.clip1+" // "+"clip2 es: "+_root.clip2);

if (_root.clip1<cargoFotos.length-2) {;
_root.clip1++;
} else {;
_root.clip1 = 0;
};

if (_root.clip2<cargoFotos.length-1) {;
_root.clip2++;
} else {;
_root.clip2 = 1;
};

CambioAlpha(cargoFotos[clip1],cargoFotos[clip2]);
};

//--------------------------------------------------------
// Cuento segundos para ejecutar la funcion de transición:

_root.elClip.onEnterFrame = function() {
if (_root.segundos<100) {
_root.segundos++;
} else {
_root.segundos = 0;
}

if (_root.segundos == 100) {
_root.Cambio();
}
};


si llegaste hasta acá y no estas :zzz: :zzz: :zzz: GRACIAS!! :wink: y si esto te sierve para algo... Suerte!!

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

firefox
Citar            
MensajeEscrito el 12 Dic 2008 07:48 pm
Bueno no se si sea que estas usando el mismo objeto:clase para ambas cargas

Código PHP :

CambioAlpha = function (elClip1, elClip2) {
   var MostrarFondo1:Tween = new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true);
   var MostrarFondo2:Tween = new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true);
};


POrque al usar una sustituiriaa la otra, al menos yo tuve un problema asi. Suerte!

Por comicSans

Claber

151 de clabLevel



 

msie7
Citar            
MensajeEscrito el 12 Dic 2008 07:54 pm
hola comicSans.. no pasa nada.. si queres probá.. solo tenes que pegar ese código en el 1er frame, crear un movieClip con el nombre de instancia elCLip, y poner la url de las fotos que quieras cargar.. si te funciona decime..

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

firefox
Citar            
MensajeEscrito el 12 Dic 2008 08:25 pm
hola amigo, corregi muchos errores que tenia tu codigo y aqui este el nuevo codigo, ya no necesitas que exista elClip, para que funcione, ok? chekalo, dime que tal y hasme saber como lo tenemos que seguir modficando para que sea lo que pides:

Código :

//--------------------------------------------------------
// Importo clase Tween:
import mx.transitions.Tween;
import mx.transitions.easing.*;
//--------------------------------------------------------

var clip1:Number = 0;
var clip2:Number = 1;
var segundos:Number = 90;

//--------------------------------------------------------
// Creo Arrays:

var misFotos:Array = new Array("Fotos/1.jpg", "Fotos/2.jpg", "Fotos/3.jpg", "Fotos/4.jpg", "Fotos/5.jpg", "Fotos/6.jpg");
var cargoFotos:Array = new Array();

//--------------------------------------------------------
// Cargo misFotos en EmptyMovieClips:
for (i=0; i<misFotos.length; i++) {
   
   _root.createEmptyMovieClip("cargo"+i,_root.getNextHighestDepth());
   cargoFotos[i] = _root["cargo"+i];
   loadMovie(misFotos[i], cargoFotos[i]);
   cargoFotos[i]._alpha = 0;
   trace(cargoFotos[i]);
}


// Función que transiciona imágenes:

function CambioAlpha( elClip1:MovieClip, elClip2:MovieClip):Void {
   new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true);
   new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true);
}


//--------------------------------------------------------
// Recorro el array y transiciono:
function Cambio( Void ):Void {
   trace("clip1 es: "+_root.clip1+" // "+"clip2 es: "+_root.clip2);
   clip1 = ( clip1 < cargoFotos.length-2)? clip1 + 1: 0;
   clip2 = ( clip2 < cargoFotos.length-1)? clip2 + 1: 0;
   CambioAlpha( cargoFotos[clip1],cargoFotos[clip2] );
}

//--------------------------------------------------------
// Cuento segundos para ejecutar la funcion de transición:
function onEnterFrame( Void ):Void
{
   frames = ( frames < 20 )? frames + 1 : 0;
   if ( frames >= 20) 
   {
      Cambio();
   }
}

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino  

En un lugar, re moto.

firefox
Citar            
MensajeEscrito el 12 Dic 2008 09:00 pm
hola de nuevo, he seguido modificando tu codigo, y aqui esta la segunda parte, modifique algunas cosas, como por ejemplo, que no contamos segundo, contamos frames, y movi un poco las imagenes para que podamos apreciar el slide, solo comentamos la linea de _x = i * 100,para que esten sobrepuestas, esto utlimo, solo lo hice para probar, ok? cambie eso de clip1 clip, por un index, y bueno, aqui esta el codigo final:

Código :

import mx.transitions.Tween;
import mx.transitions.easing.*;

//--------------------------------------------------------
//Variables iniciales
var frames:Number = 0;
var framesMax:Number = 20;
var index:Number = -1;

//--------------------------------------------------------
// Creo Arrays:
var misFotos:Array = new Array("Fotos/1.jpg", "Fotos/2.jpg", "Fotos/3.jpg", "Fotos/4.jpg", "Fotos/5.jpg", "Fotos/6.jpg");
var cargoFotos:Array = new Array();

//--------------------------------------------------------
// Cargo misFotos en EmptyMovieClips:
for (i=0; i<misFotos.length; i++) {
   
   _root.createEmptyMovieClip("cargo"+i,_root.getNextHighestDepth());
   cargoFotos[i] = _root["cargo"+i];
   cargoFotos[i]._x = i * 100;//COMENTAR LINEA PARA SOBREPOSICION
   loadMovie(misFotos[i], cargoFotos[i]);
   cargoFotos[i]._alpha = 0;
   trace(cargoFotos[i]);
}

//--------------------------------------------------------
// Función que transiciona imágenes:
function CambioAlpha( elClip1:MovieClip, elClip2:MovieClip):Void 
{
   new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true);
   new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true);
}

//--------------------------------------------------------
// Recorro el array y transiciono:
function Cambio( Void ):Void 
{
   if( index == -1 )
   {
      CambioAlpha( null,cargoFotos[0] );
   }
   else if( index == cargoFotos.length - 1 )
   {
      CambioAlpha( cargoFotos[index], cargoFotos[0] )
   }
   else
   {
      CambioAlpha( cargoFotos[index],cargoFotos[index + 1] );
   }
   index = ( index + 1 < cargoFotos.length )? index + 1 : 0;
}

//--------------------------------------------------------
// Cuento frames para ejecutar la funcion de transición:
function onEnterFrame( Void ):Void
{
   frames = ( frames < framesMax )? frames + 1 : 0;   
   if ( frames >= framesMax ) 
   {
      Cambio();
   }
}


Saludos a todos.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino  

En un lugar, re moto.

firefox
Citar            
MensajeEscrito el 15 Dic 2008 01:07 pm
Hola.. recién hoy me puedo sentar en la compu.. y la verdad q me sorprendí.. no me esperaba tanto.. la verdad q te pasaste.. mil gracias.. creo q ya quedó.. ahora lo q habría que hacer es controlar el tamaño de las imágenes probé cambiandole el tamaño de los emptyMovieClip pero nada..sabes si hay otra forma de hacerlo? bue. voy a seguir vichandolo y después te cuento.. :wink:

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

firefox
Citar            
MensajeEscrito el 15 Dic 2008 05:10 pm
para cambiar tamaño a movieclips se hace con _width _height _xscale _yscale, el codigo quedaria asi:

Código :

_root.createEmptyMovieClip("cargo"+i,_root.getNextHighestDepth());
   cargoFotos[i] = _root["cargo"+i];
   cargoFotos[i]._width = 300;
   cargoFotos[i]._height = 350;
   loadMovie(misFotos[i], cargoFotos[i]);
   cargoFotos[i]._alpha = 0;
   trace(cargoFotos[i]);


si no funciona, vamos a tener que usar en lugar del loadMovie, un objeto MovieClipLoader, hay tutoriales en clab sobre dicho objeto. suerte.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino  

En un lugar, re moto.

firefox
Citar            
MensajeEscrito el 15 Dic 2008 06:07 pm
Hola Freeki, se me hizo interesante tu aportacion, y tome el arreglo de LongVie para agregarle precarga de tus imagenes y al mismo tiempo ajustarles el tamaño W,H donde los quieras mostrar ( yo use p.e. Stage.width y height)

Quizas lo de la pregcarga ya lo decidiras, yo Inicio el Tween hasta que cargo al menos la primera mitad de imagenes:

Código PHP :

//--------------------------------------------------------
// Creo Arrays:
var rutaFoto:String = './pics/';
var misFotos:Array = new Array("foto1.jpg", "foto3.jpg", "foto4.jpg", "foto2.jpg");
var cargoFotos:Array = new Array();
var totalCargas:Number = 0;
var inicia:Boolean = false;

//--------------------------------------------------------
// Cargo misFotos en EmptyMovieClips:
import mx.transitions.Tween;
import mx.transitions.easing.*;

//--------------------------------------------------------
//Variables iniciales
var frames:Number = 0;
var framesMax:Number = 80;
var index:Number = -1;

//--------------------------------------------------------
// Cargo misFotos en EmptyMovieClips:
for (i=0; i<misFotos.length; i++)
{   
   _root.createEmptyMovieClip("cargo"+i,_root.getNextHighestDepth());
   cargoFotos[i] = _root["cargo"+i];
   
   var mclListener:Object = new Object();

   var image_mcl:MovieClipLoader = new MovieClipLoader();
   image_mcl.addListener(mclListener);
   
   mclListener.onLoadStart = function(target_mc:MovieClip) { 
   // trace ('1. onLoadStart');   
   };
   mclListener.onLoadProgress = function(target_mc:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
   // trace('2. onLoadProgress'+target_mc + ".onLoadProgress with " + bytesLoaded + " bytes of " + bytesTotal);
   }
   mclListener.onLoadComplete = function(target_mc:MovieClip, httpStatus:Number):Void {
   // trace ('3. onLoadComplete');
   }
   
   // AQUI: Inicio de imagen cargada, comprobacion de cargas totales
   mclListener.onLoadInit = function(target_mc:MovieClip):Void {
   trace ('4. onLoadInit');
    var timerMS:Number = target_mc.completeTimer-target_mc.startTimer;
   //
    var w:Number = target_mc._width;
    var h:Number = target_mc._height;
    target_mc._x = 0;
    target_mc._y = 0;
   target_mc._alpha = 0;
    target_mc.lineStyle(1, 0x000000);
    target_mc.moveTo(0, 0);
    target_mc.lineTo(w, 0);
    target_mc.lineTo(w, h);
    target_mc.lineTo(0, h);
    target_mc.lineTo(0, 0);
   // Acomodo final de imagenes
   target_mc._width = Stage.width;
    target_mc._height = Stage.height;

   // Comprueba para entonces inicio Tween...
   checkProgress();
   totalCargas++;
   // 
   // if(totalCargas==cargoFotos.length)             // OPCION (1), si se requiere que esten todas las imagenes cargadas
   if((totalCargas>cargoFotos.length/2) && (inicia))    // OPCION (2), se requiere que este la mitad del total de imagenes cargadas
   {
   trace('YA ESTAN TODOS CARGADOS o YA CARGO LA PRIMERA MITAD --> '+inicia);
   // remove preloader
   // ...
   // AHORA SI... !!INICIO!!  =)
   showPics();
   } else {
   // preloader 'cargando elementos';
   // aquiopuedes atar un preloader o mostrar txt de precarga
   }
   }   

   image_mcl.loadClip(rutaFoto+misFotos[i], cargoFotos[i]);
}

//--------------------------------------------------------
// Función que checa el progreso de precarga de las imagenes:
function checkProgress () {
   inicia = true;
   for(var p=0; p<cargoFotos.length/2; p++) {
   if (cargoFotos[p].getBytesLoaded()!=cargoFotos[p].getBytesTotal())
   inicia = false;
   }
}
//--------------------------------------------------------
// Función que transiciona imágenes:
function CambioAlpha( elClip1:MovieClip, elClip2:MovieClip):Void 
{
   new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true);
   new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true);
}

//--------------------------------------------------------
// Recorro el array y transiciono:
function Cambio( Void ):Void 
{
   if( index == -1 )
      CambioAlpha( null,cargoFotos[0] );
   else if( index == cargoFotos.length - 1 )
      CambioAlpha( cargoFotos[index], cargoFotos[0] )
   else
      CambioAlpha( cargoFotos[index],cargoFotos[index + 1] );
   //
   index = ( index + 1 < cargoFotos.length )? index + 1 : 0;
}

//--------------------------------------------------------
// Cuento frames para ejecutar la funcion de transición:
function showPics ( Void ):Void {
this.onEnterFrame = function ()
{
   ( frames < framesMax )? frames++ : frames=0;   
   if ( frames >= framesMax ) 
   {
      Cambio();
   }
}
}

Por comicSans

Claber

151 de clabLevel



 

firefox
Citar            
MensajeEscrito el 16 Dic 2008 04:22 am
La solucion de ComicSans es mas que buena, es explicativa, ponle mucha atencion puedes aprender de ese codigo Freeki. Bien lo dice The Fricky! Se decente, no uses loadMovie...

Otra solucion para hacer el resize es decirle a los diseñadores que te hagan las imagenes del tamaño que lo quieras, jajaja, ske si uno quiere hacer de todo luego por eso no entrega el sistema a tiempo.

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino  

En un lugar, re moto.

firefox
Citar            
MensajeEscrito el 16 Dic 2008 03:26 pm
buenas gente.. bueno primero q nada mil gracias por la ayuda. me alegra que les halla interesado el post :wink: al final hice eso si.. q le pongan el tamaño que quieren, modifiquen el documento y listo.. q no jodan.. todavia no he podido probar tu código comic.. pero tiene toda la pinta.. bien ahi! :wink: y. pa LongeVie. gracia por la ayuda loco.. q fuiste el q me ayudó en los dos post.. yo quería recorrer la carpeta de imagenes con php y luego cargarlas y hacer las transiciones.. pero qdó asi..

Código :


//Nombre y Cantidad de fotos
var NombFotos:String = "Nombre";
var CantFotos:Number = 6;

//--------------------------------------------------------
// Creo Arrays:

var misFotos:Array = new Array();
var cargoFotos:Array = new Array();

//--------------------------------------------------------

for (var i=0; i<CantFotos; i++) {
misFotos[i]="Fotos/"+NombFotos+i+".jpg";
trace(misFotos[i]);
}

una cagada.. pero bue.. es lo q me pidieron :lol: ta luego gente!

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

msie7
Citar            
MensajeEscrito el 16 Dic 2008 08:42 pm
Hola... Tienes un ejemplo de como funciona este código?

Muchas gracias. Pica

Por Picasso

45 de clabLevel



Genero:Masculino  

Programador Web

firefox
Citar            
MensajeEscrito el 17 Dic 2008 01:06 am
Quedó bien d bien.. gracias a uds.. me gustó tu código comicSans.. le hice algunas modificaciones pa mi conveniencia.. pero practicamente es el mismo. 10 points :wink:

Para Picasso:.. si queres probar lo que estamos haciendo.. copiate este código.. o el de LongeVie o comicSans y pegalo en el primer frame.. si te copias mi código lo unico q tenes q hacer es poner una carpeta "Fotos" con las fotos que quieras del 0.jpg al q quieras siguiendo el patrón.. (0.jpg, 1.jpg, 2.jpg, 3.jpg) y en la var CantFotos pones le número de fotos que pusiste.

Código :

//-------------------------------------------------------- 
// Creo Vars y Arrays: 

var totalCargas:Number = 0; 
var inicia:Boolean = false; 
var CantFotos:Number = 4;

var cargoFotos:Array = new Array(); 
var misFotos:Array = new Array(); 

for (var i=0; i<CantFotos; i++) {
misFotos[i]="Fotos/"+i+".jpg";
}
 
 
//-------------------------------------------------------- 
// Cargo misFotos en EmptyMovieClips: 
import mx.transitions.Tween; 
import mx.transitions.easing.*; 
 
//-------------------------------------------------------- 
//Variables iniciales 
var frames:Number = 0; 
var framesMax:Number = 50; 
var index:Number = -1; 
 
//-------------------------------------------------------- 
// Cargo misFotos en EmptyMovieClips: 
for (i=0; i<misFotos.length; i++) 
{    
   _root.createEmptyMovieClip("cargo"+i,_root.getNextHighestDepth()); 
   cargoFotos[i] = _root["cargo"+i]; 
    
   var mclListener:Object = new Object(); 
 
   var image_mcl:MovieClipLoader = new MovieClipLoader(); 
   image_mcl.addListener(mclListener); 
    
   mclListener.onLoadStart = function(target_mc:MovieClip) {  
   // trace ('1. onLoadStart');    
   }; 
   mclListener.onLoadProgress = function(target_mc:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void { 
   // trace('2. onLoadProgress'+target_mc + ".onLoadProgress with " + bytesLoaded + " bytes of " + bytesTotal); 
   } 
   mclListener.onLoadComplete = function(target_mc:MovieClip, httpStatus:Number):Void { 
   // trace ('3. onLoadComplete'); 
   } 
    
   // AQUI: Inicio de imagen cargada, comprobacion de cargas totales 
   mclListener.onLoadInit = function(target_mc:MovieClip):Void { 
   trace ('4. onLoadInit'); 
    var timerMS:Number = target_mc.completeTimer-target_mc.startTimer; 
   // 
    var w:Number = target_mc._width; 
    var h:Number = target_mc._height; 
    target_mc._x = 0; 
    target_mc._y = 0; 
   target_mc._alpha = 0; 
    target_mc.lineStyle(1, 0x000000); 
    target_mc.moveTo(0, 0); 
    target_mc.lineTo(w, 0); 
    target_mc.lineTo(w, h); 
    target_mc.lineTo(0, h); 
    target_mc.lineTo(0, 0); 
   // Acomodo final de imagenes 
   target_mc._width = Stage.width; 
    target_mc._height = Stage.height; 
 
   // Comprueba para entonces inicio Tween... 
   checkProgress(); 
   totalCargas++; 
   //  
   // if(totalCargas==cargoFotos.length)             // OPCION (1), si se requiere que esten todas las imagenes cargadas 
   if((totalCargas>cargoFotos.length/2) && (inicia))    // OPCION (2), se requiere que este la mitad del total de imagenes cargadas 
   { 
   trace('YA ESTAN TODOS CARGADOS o YA CARGO LA PRIMERA MITAD --> '+inicia); 
   // remove preloader 
   // ... 
   // AHORA SI... !!INICIO!!  =) 
   showPics(); 
   } else { 
   // preloader 'cargando elementos'; 
   // aquiopuedes atar un preloader o mostrar txt de precarga 
   } 
   }    
 
   image_mcl.loadClip(misFotos[i], cargoFotos[i]); 
} 
 
//-------------------------------------------------------- 
// Función que checa el progreso de precarga de las imagenes: 
function checkProgress () { 
   inicia = true; 
   for(var p=0; p<cargoFotos.length/2; p++) { 
   if (cargoFotos[p].getBytesLoaded()!=cargoFotos[p].getBytesTotal()) 
   inicia = false; 
   } 
} 
//-------------------------------------------------------- 
// Función que transiciona imágenes: 
function CambioAlpha( elClip1:MovieClip, elClip2:MovieClip):Void  
{ 
   new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true); 
   new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true); 
} 
 
//-------------------------------------------------------- 
// Recorro el array y transiciono: 
function Cambio( Void ):Void  
{ 
   if( index == -1 ) 
      CambioAlpha( null,cargoFotos[0] ); 
   else if( index == cargoFotos.length - 1 ) 
      CambioAlpha( cargoFotos[index], cargoFotos[0] ) 
   else 
      CambioAlpha( cargoFotos[index],cargoFotos[index + 1] ); 
   // 
   index = ( index + 1 < cargoFotos.length )? index + 1 : 0; 
} 
 
//-------------------------------------------------------- 
// Cuento frames para ejecutar la funcion de transición: 
function showPics ( Void ):Void { 
this.onEnterFrame = function () 
{ 
   ( frames < framesMax )? frames++ : frames=0;    
   if ( frames >= framesMax )  
   { 
      Cambio(); 
   } 
} 
} 


Saludos terrícolas.

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

firefox
Citar            
MensajeEscrito el 17 Dic 2008 02:17 am
Y para variar un poco pueden agregar a la función que transiciona imágenes:

Código :

new Tween(elClip2, "_x", Regular.easeOut, -557 , 0, 1.5, true); 
new Tween(elClip1, "_x", Regular.easeOut, 0, 550, 1.5, true);

así:

Código :

// Función que transiciona imágenes: 

function CambioAlpha( elClip1:MovieClip, elClip2:MovieClip):Void  
{   
new Tween(elClip1, "_alpha", Regular.easeOut, 100, 0, 1.5, true); 
new Tween(elClip2, "_alpha", Regular.easeOut, 0, 100, 1.5, true); 

new Tween(elClip2, "_x", Regular.easeOut, -557 , 0, 1.5, true); 
new Tween(elClip1, "_x", Regular.easeOut, 0, 550, 1.5, true);
   } 

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

firefox
Citar            
MensajeEscrito el 18 Dic 2008 04:52 pm
Hey gente.. tengo que cargar las imagenes aleatoriamente en dos clips ya ubicados en el escenario que tienen una máscara.. la verdad se me complicó bastante para modificar el código.. :( HELP! HELP! :(

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

msie7
Citar            
MensajeEscrito el 18 Dic 2008 08:16 pm
ya resolví lo de la máscara.. ahora.. para hacer que secuencie fotos aleatoriamente como hacemos?? intenté todas las formas.. pero habria que cambiar la funcion del index no?

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

msie7
Citar            
MensajeEscrito el 19 Dic 2008 02:48 pm
var wA:Array = new Array(1,2,3,4,5,6,7,8,9,10);
trace (wA.length+' antes: '+wA.join());
// Revuelve para acomodar aleatorio los valores de wA
var fichas:Array = new Array();
for (a=0; a<num; a++)
{
rev = (random(wArray.length));
valor = wArray[rev];
fichas.splice(1, 0, valor);
wArray.splice(rev, 1);
}
wA = fichas;
trace (wA.length+' ahora: '+wA.join());

Por comicSans

Claber

151 de clabLevel



 

firefox
Citar            
MensajeEscrito el 19 Dic 2008 06:46 pm
mmm, yo pondria la modificacion en la funcion cambio, quedaria asi:

Código :

function Cambio( Void ):Void  
{ 
   if( index == -1 ) 
      CambioAlpha( null,cargoFotos[0] ); 
   else if( index == cargoFotos.length - 1 ) 
      CambioAlpha( cargoFotos[index], cargoFotos[0] ) 
   else 
      CambioAlpha( cargoFotos[index],cargoFotos[index + 1] ); 
   // 
   index = rand();
} 

function rand( Void ):Number
{
   var len:Number = cargoFotos.length;
   if( len > 1 )//Para evitar bucles infinitos
   {
      var aux:Number;
      do
      {
         aux = Math.floor(Math.random() * len) + 1;
      }
      while( aux == index );
   }
   return aux;
}

Por LongeVie

Claber

1741 de clabLevel

1 tutorial

Genero:Masculino  

En un lugar, re moto.

firefox
Citar            
MensajeEscrito el 19 Dic 2008 07:50 pm
la funcion no me funcó.. tu código comic.. todavía no lo viché.. te aviso
:D

Por Freeki

Claber

183 de clabLevel



Genero:Masculino  

Desarrollador Web Uy

msie7

 

Cristalab BabyBlue v4 + V4 © 2011 Cristalab
Powered by ClabEngines v4, HTML5, love and ponies.